How to switch paragraph-indent-minor-mode off?

How to switch paragraph-indent-minor-mode off?

[Rodolfo Medina]

Hi.

In text mode, when I want to enable paragraph-indent-minor-mode, I simply do:
`M-x paragraph-indent-minor-mode RET'; but then if I want to disable it again I
must exit emacs and restart it.  Can anyone suggest how to switch on and off at
pleasure the paragraph-indent-minor-mode within the same buffer?

Thanks,
Rodolfo

Re: How to switch paragraph-indent-minor-mode off?

[Amy Templeton]

Rudolfo Medina wrote:
> then if I want to disable it again I must exit emacs and
> restart it.

You don't actually need to restart all of Emacs; if you just
kill the buffer (C-x k RET will kill the current buffer) and
then find the file (C-x C-f filename or path/to/file) it
will find the file in default text mode, without
paragraph-indent-minor-mode enabled. 

If you don't want to kill the buffer, however, you could
always put together a simple function such as this:

(defun parindent-off ()
  (interactive)
  (paragraph-indent-text-mode)
  (text-mode))

...in your .emacs file. Turning on
paragraph-indent-text-mode seems to turn off
paragraph-indent-minor-mode, so by going from there to text
mode you turn off the minor mode. There are doubtless more
graceful solutions out there, but this works as a quick fix.

Hope that helps.

Amy

Re: How to switch paragraph-indent-minor-mode off?

[Stefan Monnier]

> In text mode, when I want to enable paragraph-indent-minor-mode, I simply
> do: `M-x paragraph-indent-minor-mode RET'; but then if I want to disable
> it again I must exit Emacs and restart it.  Can anyone suggest how to
> switch on and off at pleasure the paragraph-indent-minor-mode within the
> same buffer?

You can try using the following definition which fixes
paragraph-indent-minor-mode to really be a minor mode as the name implies.


        Stefan


(define-minor-mode paragraph-indent-minor-mode
  "Minor mode for editing text, with leading spaces starting a paragraph.
In this mode, you do not need blank lines between paragraphs when the
first line of the following paragraph starts with whitespace, as with
`paragraph-indent-text-mode'.
Turning on Paragraph-Indent minor mode runs the normal hook
`paragraph-indent-text-mode-hook'."
  ;; Change the definition of a paragraph start.
  (let ((ps-re "[ \t\n\f]\\|"))
    (if (eq t (compare-strings ps-re nil nil
                               paragraph-start nil (length ps-re)))
        (if (not paragraph-indent-minor-mode)
            (set (make-local-variable 'paragraph-start)
                 (substring paragraph-start (length ps-re))))
      (if paragraph-indent-minor-mode
          (set (make-local-variable 'paragraph-start)
               (concat ps-re paragraph-start)))))
  ;; Change the indentation function.
  (if paragraph-indent-minor-mode
      (set (make-local-variable 'indent-line-function) 'indent-to-left-margin)
    (if (eq indent-line-function 'indent-to-left-margin)
        (set (make-local-variable 'indent-line-function) 'indent-region))))

Re: How to switch paragraph-indent-minor-mode off?

[Stefan Monnier]

> (define-minor-mode paragraph-indent-minor-mode
>   "Minor mode for editing text, with leading spaces starting a paragraph.
> In this mode, you do not need blank lines between paragraphs when the
> first line of the following paragraph starts with whitespace, as with
> `paragraph-indent-text-mode'.
> Turning on Paragraph-Indent minor mode runs the normal hook
> `paragraph-indent-text-mode-hook'."

And here I forgot the following line:

  nil nil nil

>   ;; Change the definition of a paragraph start.
>   (let ((ps-re "[ \t\n\f]\\|"))
>     (if (eq t (compare-strings ps-re nil nil
>                                paragraph-start nil (length ps-re)))
>         (if (not paragraph-indent-minor-mode)
>             (set (make-local-variable 'paragraph-start)
>                  (substring paragraph-start (length ps-re))))
>       (if paragraph-indent-minor-mode
>           (set (make-local-variable 'paragraph-start)
>                (concat ps-re paragraph-start)))))
>   ;; Change the indentation function.
>   (if paragraph-indent-minor-mode
>       (set (make-local-variable 'indent-line-function) 'indent-to-left-margin)
>     (if (eq indent-line-function 'indent-to-left-margin)
>         (set (make-local-variable 'indent-line-function) 'indent-region))))

Sorry,


        Stefan