Re: Is vc-diff-mergebase broken on master?

[Matthias Meulien <orontee@gmail.com>]

[-- Attachment #1: Type: text/plain, Size: 120 bytes --]

Matthias Meulien <orontee@gmail.com> writes:

> (...) I'll work on an updated patch fixing RCS/CVS tests.

Here it is:


[-- Warning: decoded text below may be mangled, UTF-8 assumed --]
[-- Attachment #2: 0001-Test-vc-version-diff.patch --]
[-- Type: text/x-diff, Size: 3800 bytes --]

From b9f8b097701a78d4e11b1e85699ba8070b98f163 Mon Sep 17 00:00:00 2001
From: Matthias Meulien <orontee@gmail.com>
Date: Fri, 3 Sep 2021 00:42:29 +0200
Subject: [PATCH] Test vc-version-diff

* test/lisp/vc/vc-tests.el (vc-test--version-diff): Test vc-version-diff
---
 test/lisp/vc/vc-tests.el | 78 ++++++++++++++++++++++++++++++++++++++++
 1 file changed, 78 insertions(+)

diff --git a/test/lisp/vc/vc-tests.el b/test/lisp/vc/vc-tests.el
index dfe89c519b..f8c843ff50 100644
--- a/test/lisp/vc/vc-tests.el
+++ b/test/lisp/vc/vc-tests.el
@@ -547,6 +547,72 @@ vc-test--checkout-model
         (if tempdir (delete-directory tempdir t))
         (run-hooks 'vc-test--cleanup-hook)))))
 
+(defun vc-test--version-diff (backend)
+  "Check the diff version of a repository."
+
+  (let ((vc-handled-backends `(,backend))
+	(default-directory
+	  (file-name-as-directory
+	   (expand-file-name
+	    (make-temp-name "vc-test") temporary-file-directory)))
+	(process-environment process-environment)
+	tempdir
+	vc-test--cleanup-hook)
+    (when (eq backend 'Bzr)
+      (setq tempdir (make-temp-file "vc-test--version-diff" t)
+	    process-environment (cons (format "BZR_HOME=%s" tempdir)
+				      process-environment)))
+
+    (unwind-protect
+	(progn
+	  ;; Cleanup.
+	  (add-hook
+	   'vc-test--cleanup-hook
+	   `(lambda () (delete-directory ,default-directory 'recursive)))
+
+	  ;; Create empty repository.  Check repository checkout model.
+	  (make-directory default-directory)
+	  (vc-test--create-repo-function backend)
+
+	  (let* ((tmp-name (expand-file-name "foo" default-directory))
+                 (files (list (file-name-nondirectory tmp-name))))
+	    ;; Write and register a new file.
+	    (write-region "originaltext" nil tmp-name nil 'nomessage)
+	    (vc-register (list backend files))
+
+            (let ((buff (find-file tmp-name)))
+              (with-current-buffer buff
+                (progn
+                  ;; Optionally checkout file.
+                  (when (or (eq backend 'RCS) (eq backend 'CVS))
+                    (vc-checkout tmp-name))
+
+                  ;; Checkin file.
+                  (vc-checkin files backend)
+                  (insert "Testing vc-version-diff")
+                  (log-edit-done))))
+
+            ;; Modify file content.
+            (when (or (eq backend 'RCS) (eq backend 'CVS))
+              (vc-checkout tmp-name))
+            (write-region "updatedtext" nil tmp-name nil 'nomessage)
+
+	    ;; Check version diff.
+            (vc-version-diff files nil nil)
+            (should (bufferp (get-buffer "*vc-diff*")))
+
+            (with-current-buffer "*vc-diff*"
+              (progn
+                (let ((rawtext (buffer-substring-no-properties (point-min)
+                                                               (point-max))))
+                  (should (string-search "-originaltext" rawtext))
+                  (should (string-search "+updatedtext" rawtext)))))))
+
+      ;; Save exit.
+      (ignore-errors
+        (if tempdir (delete-directory tempdir t))
+        (run-hooks 'vc-test--cleanup-hook)))))
+
 (defun vc-test--rename-file (backend)
   "Check the rename-file action."
 
@@ -715,6 +781,18 @@ vc-test--arch-enabled
           ;; "Really want to delete ...?"
           (skip-unless (not (eq 'CVS ',backend)))
           (vc-test--rename-file ',backend))
+
+        (ert-deftest
+	    ,(intern (format "vc-test-%s06-version-diff" backend-string)) ()
+	  ,(format "Check `vc-version-diff' for the %s backend."
+		   backend-string)
+	  (skip-unless
+	   (ert-test-passed-p
+	    (ert-test-most-recent-result
+	     (ert-get-test
+	      ',(intern
+		 (format "vc-test-%s01-register" backend-string))))))
+	  (vc-test--version-diff ',backend))
         ))))
 
 (provide 'vc-tests)
-- 
2.30.2


[-- Attachment #3: Type: text/plain, Size: 13 bytes --]

-- 
Matthias