Break from a dolist

Break from a dolist

[Cecil Westerhof]

I have the following code to fetch the email address belonging to a
mailing list. I use it to automatically fill the to address when
posting to a newsgroup.

    (defun dcbl-gnus-get-mailing-list-address ()
      "Get gnus-newsgroup-name mailing list address (if it has one);"
      (let ((to-address nil))
        (when gnus-newsgroup-name
          (dolist (item dcbl-gnus-mailing-lists)
            (when (string-match (car item) gnus-newsgroup-name)
              (setq to-address (cdr item)))))
        to-address))

But when the address is found, it would be better to leave the loop.
Is this possible?

-- 
Cecil Westerhof
Senior Software Engineer
LinkedIn: http://www.linkedin.com/in/cecilwesterhof

Re: Break from a dolist

[Jambunathan K]

Cecil Westerhof <Cecil@decebal.nl> writes:

> I have the following code to fetch the email address belonging to a
> mailing list. I use it to automatically fill the to address when
> posting to a newsgroup.
>
>     (defun dcbl-gnus-get-mailing-list-address ()
>       "Get gnus-newsgroup-name mailing list address (if it has one);"
>       (let ((to-address nil))
>         (when gnus-newsgroup-name
>           (dolist (item dcbl-gnus-mailing-lists)
>             (when (string-match (car item) gnus-newsgroup-name)
>               (setq to-address (cdr item)))))
>         to-address))
>
> But when the address is found, it would be better to leave the loop.
> Is this possible?


    (info "(elisp) Examples of Catch")

-- 

Re: Break from a dolist

[Cecil Westerhof]

Op zondag 9 sep 2012 11:25 CEST schreef Jambunathan K.:

>> I have the following code to fetch the email address belonging to a
>> mailing list. I use it to automatically fill the to address when
>> posting to a newsgroup.
>>
>> (defun dcbl-gnus-get-mailing-list-address ()
>> "Get gnus-newsgroup-name mailing list address (if it has one);"
>> (let ((to-address nil))
>> (when gnus-newsgroup-name
>> (dolist (item dcbl-gnus-mailing-lists)
>> (when (string-match (car item) gnus-newsgroup-name)
>> (setq to-address (cdr item)))))
>> to-address))
>>
>> But when the address is found, it would be better to leave the loop.
>> Is this possible?
>
>
> (info "(elisp) Examples of Catch")

Thanks. That makes for better code. I now have the following code,
that I am going to call from dcbl-gnus-get-mailing-list-address. Much
more clear code and I have now a generic function that I can call from
other places also.

    (defun dcbl-get-tuple-value (tuple index)
      "Get value from tuple indexed by index (if it exist);"
        (when index
          (catch 'loop
            (dolist (item tuple)
              (when (string-match (car item) index)
                  (throw 'loop (cdr item)))))))

The proof is in:
    (dcbl-get-tuple-value dcbl-gnus-mailing-lists "nnimap+gmail:INBOX\\.Info\\.bbdb")
and that does what it should.

There is one problem. First my 'tuple' was like:

    (setq dcbl-gnus-mailing-lists '(
                                    (":INBOX\\.Info\\.bbdb$"          . "bbdb-info@lists.sourceforge.net")
                                    .
                                    .
                                    .
                                    (":bedrijf/organisatie/org-mode$" . "emacs-orgmode@gnu.org")
                                    ))

But now it is like:

    (setq dcbl-gnus-mailing-lists '(
                                    (":INBOX\\\\.Info\\\\.bbdb$"      . "bbdb-info@lists.sourceforge.net")
                                    .
                                    .
                                    .
                                    (":bedrijf/organisatie/org-mode$" . "emacs-orgmode@gnu.org")
                                    ))

The backslashes for escaping the . have gone from two to four. Why is this?

-- 
Cecil Westerhof
Senior Software Engineer
LinkedIn: http://www.linkedin.com/in/cecilwesterhof

Re: Break from a dolist

[Le Wang]

On Sun, Sep 9, 2012 at 8:49 PM, Cecil Westerhof <Cecil@decebal.nl> wrote:
>
> Thanks. That makes for better code. I now have the following code,
> that I am going to call from dcbl-gnus-get-mailing-list-address. Much
> more clear code and I have now a generic function that I can call from
> other places also.
>
>     (defun dcbl-get-tuple-value (tuple index)
>       "Get value from tuple indexed by index (if it exist);"
>         (when index
>           (catch 'loop
>             (dolist (item tuple)
>               (when (string-match (car item) index)
>                   (throw 'loop (cdr item)))))))


`dolist' (like all cl looping mechanisms) runs within an implicit anonymous
local return.  So you can simply use

    (defun dcbl-get-tuple-value (tuple index)
      "Get value from tuple indexed by index (if it exist);"
        (when index
          (dolist (item tuple)
            (when (string-match (car item) index)
              (return (cdr item))))))


--
Le

Re: Break from a dolist

[Jambunathan K]

Le Wang <l26wang@gmail.com> writes:

> On Sun, Sep 9, 2012 at 8:49 PM, Cecil Westerhof <Cecil@decebal.nl> wrote:
>>
>> Thanks. That makes for better code. I now have the following code,
>> that I am going to call from dcbl-gnus-get-mailing-list-address. Much
>> more clear code and I have now a generic function that I can call from
>> other places also.
>>
>>     (defun dcbl-get-tuple-value (tuple index)
>>       "Get value from tuple indexed by index (if it exist);"
>>         (when index
>>           (catch 'loop
>>             (dolist (item tuple)
>>               (when (string-match (car item) index)
>>                   (throw 'loop (cdr item)))))))
>
>
> `dolist' (like all cl looping mechanisms) runs within an implicit anonymous
> local return.  So you can simply use
>
>     (defun dcbl-get-tuple-value (tuple index)
>       "Get value from tuple indexed by index (if it exist);"
>         (when index
>           (dolist (item tuple)
>             (when (string-match (car item) index)
>               (return (cdr item))))))
>

If you look at what the dolist does it is very similar to 

    (assoc-default    )

probably with an non-default test param.

So a dolist is not even needed :-).

> --
> Le
>
>

-- 

Re: Break from a dolist

[Cecil Westerhof]

Op zondag 9 sep 2012 16:13 CEST schreef Jambunathan K.:

>>> Thanks. That makes for better code. I now have the following code,
>>> that I am going to call from dcbl-gnus-get-mailing-list-address. Much
>>> more clear code and I have now a generic function that I can call from
>>> other places also.
>>>
>>> (defun dcbl-get-tuple-value (tuple index)
>>> "Get value from tuple indexed by index (if it exist);"
>>> (when index
>>> (catch 'loop
>>> (dolist (item tuple)
>>> (when (string-match (car item) index)
>>> (throw 'loop (cdr item)))))))
>>
>>
>> `dolist' (like all cl looping mechanisms) runs within an implicit anonymous
>> local return.  So you can simply use
>>
>> (defun dcbl-get-tuple-value (tuple index)
>> "Get value from tuple indexed by index (if it exist);"
>> (when index
>> (dolist (item tuple)
>> (when (string-match (car item) index)
>> (return (cdr item))))))
>>
>
> If you look at what the dolist does it is very similar to 
>
> (assoc-default    )
>
> probably with an non-default test param.
>
> So a dolist is not even needed :-).

In this case it can, but it is not the same. In my function I work
with a regular expression. For example the newsgroup is:
    nnimap+gmail:bedrijf/ontwikkeling/scala
and the 'key' is:
    :bedrijf/ontwikkeling/scala$


I solved it in the following way:

    (defun dcbl-get-tuple-value (tuple index)
      "Get value from tuple indexed by index (if it exist);"
      (assoc-default index tuple))

    (defun dcbl-gnus-get-mailing-list-address ()
      "Get gnus-newsgroup-name mailing list address (if it has one);"
      (string-match "[^:]*$" gnus-newsgroup-name)
      (dcbl-get-tuple-value dcbl-gnus-mailing-lists (match-string 0 gnus-newsgroup-name)))

And removed the : and the $ from the keys.

On other places I can not do it like this, but here it resulted it
very nice code.

-- 
Cecil Westerhof
Senior Software Engineer
LinkedIn: http://www.linkedin.com/in/cecilwesterhof