org-agenda-insert-diary-make-new-entry adds entry as first child?

org-agenda-insert-diary-make-new-entry adds entry as first child?

[Nikolai Weibull]

Hi!

The documentation for org-agenda-insert-diary-make-new-entry says that
it adds the entry as the last child, but it seems that it’s adding it
as the first child instead.  (My org-agenda-insert-diary-strategy is
'date-tree.)

Re: org-agenda-insert-diary-make-new-entry adds entry as first child?

[Bastien]

Hi Nikolai,

Nikolai Weibull <now@disu.se> writes:

> The documentation for org-agenda-insert-diary-make-new-entry says that
> it adds the entry as the last child, but it seems that it’s adding it
> as the first child instead.  (My org-agenda-insert-diary-strategy is
> 'date-tree.)

I fixed the docstring, thanks.

-- 
 Bastien

Re: org-agenda-insert-diary-make-new-entry adds entry as first child?

[Nikolai Weibull]

On Fri, May 30, 2014 at 2:10 PM, Bastien <bzg@gnu.org> wrote:

> Nikolai Weibull <now@disu.se> writes:
>
>> The documentation for org-agenda-insert-diary-make-new-entry says that
>> it adds the entry as the last child, but it seems that it’s adding it
>> as the first child instead.  (My org-agenda-insert-diary-strategy is
>> 'date-tree.)
>
> I fixed the docstring, thanks.

Wouldn’t it be better to fix the function?  I’m thinking that you
probably want entries added later during the day to appear later in
the file, right?  (I’m asking before I consider writing a patch.)

Thanks!

Re: org-agenda-insert-diary-make-new-entry adds entry as first child?

[Bastien]

Hi Nikolai,

Nikolai Weibull <now@disu.se> writes:

> Wouldn’t it be better to fix the function?  I’m thinking that you
> probably want entries added later during the day to appear later in
> the file, right?

Personally, I prefer to have recent entries added at the top.

> (I’m asking before I consider writing a patch.)

The thing to check is whether the current behavior is consistent
across possible values of `org-agenda-insert-diary-strategy'.  Can
you do this?

Thanks,

-- 
 Bastien

Re: org-agenda-insert-diary-make-new-entry adds entry as first child?

[Nikolai Weibull]

On Fri, May 30, 2014 at 4:04 PM, Bastien <bzg@gnu.org> wrote:

> Nikolai Weibull <now@disu.se> writes:
>
>> Wouldn’t it be better to fix the function?  I’m thinking that you
>> probably want entries added later during the day to appear later in
>> the file, right?
>
> Personally, I prefer to have recent entries added at the top.
>
>> (I’m asking before I consider writing a patch.)
>
> The thing to check is whether the current behavior is consistent
> across possible values of `org-agenda-insert-diary-strategy'.  Can
> you do this?

When set to 'top-level, the documentation mentions that it adds it to
the end of the file and testing confirms this.  It thus seems more
consistent to always add entries towards the end of the file.

Re: org-agenda-insert-diary-make-new-entry adds entry as first child?

[Bastien]

Hi Nikolai,

Nikolai Weibull <now@disu.se> writes:

> When set to 'top-level, the documentation mentions that it adds it to
> the end of the file and testing confirms this.  It thus seems more
> consistent to always add entries towards the end of the file.

Okay -- please go ahead with a patch if you have time.

Thanks,

-- 
 Bastien

Re: org-agenda-insert-diary-make-new-entry adds entry as first child?

[Nikolai Weibull]

On Fri, May 30, 2014 at 5:24 PM, Bastien <bzg@altern.org> wrote:
> Hi Nikolai,
>
> Nikolai Weibull <now@disu.se> writes:
>
>> When set to 'top-level, the documentation mentions that it adds it to
>> the end of the file and testing confirms this.  It thus seems more
>> consistent to always add entries towards the end of the file.
>
> Okay -- please go ahead with a patch if you have time.

Here’s a suggested solution.  We keep track of whether the parent
entry already has any children, then we call org-insert-heading with
two universal arguments to add an entry at the end of the current
subtree.  Finally, if there weren’t any children already, we demote
the entry we added so that it becomes a child of the parent entry.
Please note that this was written while eating dinner with my kid.

(defun org-agenda-insert-diary-make-new-entry (text)
  "Make new entry as last child of current entry.
Add TEXT as headline, and position the cursor in the second line so that
a timestamp can be added there."
  (let ((org-show-following-heading t)
    (org-show-siblings t)
    (org-show-hierarchy-above t)
    (org-show-entry-below t)
    (has-children (save-excursion (org-goto-first-child)))
    col)
    (org-back-over-empty-lines)
    (or (looking-at "[ \t]*$")
    (progn (insert "\n") (backward-char 1)))
    (org-insert-heading 16 t)
    (unless has-children
      (org-do-demote))
    (setq col (current-column))
    (insert text "\n")
    (if org-adapt-indentation (org-indent-to-column col))
    (let ((org-show-following-heading t)
      (org-show-siblings t)
      (org-show-hierarchy-above t)
      (org-show-entry-below t))
      (org-show-context))))
      (org-show-context))))

Re: org-agenda-insert-diary-make-new-entry adds entry as first child?

[Bastien]

Hi Nikolai,

Nikolai Weibull <now@disu.se> writes:

> Here’s a suggested solution.  We keep track of whether the parent
> entry already has any children, then we call org-insert-heading with
> two universal arguments to add an entry at the end of the current
> subtree.  Finally, if there weren’t any children already, we demote
> the entry we added so that it becomes a child of the parent entry.

Finally applied in master, thanks,

> Please note that this was written while eating dinner with my kid.

Bon appétit !

-- 
 Bastien

Re: org-agenda-insert-diary-make-new-entry adds entry as first child?

[Nikolai Weibull]

On Mon, Jul 28, 2014 at 4:20 PM, Bastien <bzg@gnu.org> wrote:

> Nikolai Weibull <now@disu.se> writes:
>
>> Here’s a suggested solution.  We keep track of whether the parent
>> entry already has any children, then we call org-insert-heading with
>> two universal arguments to add an entry at the end of the current
>> subtree.  Finally, if there weren’t any children already, we demote
>> the entry we added so that it becomes a child of the parent entry.
>
> Finally applied in master, thanks,

Hi!

It seems that this was reverted in
3e01c7ff1b37f1f548cc6c959160ff11302a25c7, but the log doesn’t say why.
Was there a specific reason?  That is, was the original behavior
desired but the patch was fine or was there a problem with the patch?

Should I write a patch that adds another
org-agenda-insert-diary-strategy called 'date-entry-last or something
like that?

Thanks!

Re: org-agenda-insert-diary-make-new-entry adds entry as first child?

[Nicolas Goaziou]

Hello,

Nikolai Weibull <now@disu.se> writes:

> Should I write a patch that adds another
> org-agenda-insert-diary-strategy called 'date-entry-last or something
> like that?

I think it would be nice. Thank you.

Regards,

-- 
Nicolas Goaziou

Re: org-agenda-insert-diary-make-new-entry adds entry as first child?

[Nikolai Weibull]

Here’s a patch that I hope I managed to compile correctly via git-send-email.

[PATCH 2/2] Allow inserting diary entries last in date tree

[Nikolai Weibull]

* org-agenda.el (org-agenda-insert-diary-strategy): Add new value
  'date-tree-last.
  (org-agenda-insert-diary-make-new-entry): Handle
  `org-agenda-insert-diary-strategy' set to 'date-tree-last.

To allow for diary entries to be entered in time order in the date tree,
add a new value to `org-agenda-insert-diary-strategy' that allows for
this.  The code for handling this value, 'date-tree-last, is a bit
tricky, as we need to keep track of whether the date-tree already had
one or more entries for the given date.
---
 lisp/org-agenda.el | 26 +++++++++++++++++---------
 1 file changed, 17 insertions(+), 9 deletions(-)

diff --git a/lisp/org-agenda.el b/lisp/org-agenda.el
index 5fd1cd4..22a4ad9 100644
--- a/lisp/org-agenda.el
+++ b/lisp/org-agenda.el
@@ -9417,11 +9417,13 @@ buffer, display it in another window."
   "Where in `org-agenda-diary-file' should new entries be added?
 Valid values:
 
-date-tree    in the date tree, as child of the date
-top-level    as top-level entries at the end of the file."
+date-tree         in the date tree, as first child of the date
+date-tree-last    in the date tree, as last child of the date
+top-level         as top-level entries at the end of the file."
   :group 'org-agenda
   :type '(choice
-	  (const :tag "in a date tree" date-tree)
+	  (const :tag "first in a date tree" date-tree)
+	  (const :tag "last in a date tree" date-tree-last)
 	  (const :tag "as top level at end of file" top-level)))
 
 (defcustom org-agenda-insert-diary-extract-time nil
@@ -9525,14 +9527,20 @@ a timestamp can be added there."
   (when org-adapt-indentation (org-indent-to-column 2)))
 
 (defun org-agenda-insert-diary-make-new-entry (text)
-  "Make a new entry with TEXT as the first child of the current subtree.
+  "Make a new entry with TEXT as a child of the current subtree.
 Position the point in the heading's first body line so that
 a timestamp can be added there."
-  (outline-next-heading)
-  (org-back-over-empty-lines)
-  (unless (looking-at "[ \t]*$") (save-excursion (insert "\n")))
-  (org-insert-heading nil t)
-  (org-do-demote)
+  (let ((last (eq org-agenda-insert-diary-strategy 'date-tree-last))
+	(has-children (save-excursion (org-goto-first-child))))
+    (if (not (and last has-children))
+	(outline-next-heading)
+      (org-goto-first-child)
+      (while (org-get-next-sibling)))
+    (org-back-over-empty-lines)
+    (unless (looking-at "[ \t]*$") (save-excursion (insert "\n")))
+    (org-insert-heading nil t)
+    (unless has-children
+      (org-do-demote)))
   (let ((col (current-column)))
     (insert text)
     (org-end-of-meta-data)
-- 
2.5.0

Re: [PATCH 2/2] Allow inserting diary entries last in date tree

[Nicolas Goaziou]

Hello,

Nikolai Weibull <now@disu.se> writes:

> * org-agenda.el (org-agenda-insert-diary-strategy): Add new value
>   'date-tree-last.
>   (org-agenda-insert-diary-make-new-entry): Handle
>   `org-agenda-insert-diary-strategy' set to 'date-tree-last.
>
> To allow for diary entries to be entered in time order in the date tree,
> add a new value to `org-agenda-insert-diary-strategy' that allows for
> this.  The code for handling this value, 'date-tree-last, is a bit
> tricky, as we need to keep track of whether the date-tree already had
> one or more entries for the given date.

Thank you.

> +  (let ((last (eq org-agenda-insert-diary-strategy 'date-tree-last))
> +	(has-children (save-excursion (org-goto-first-child))))
> +    (if (not (and last has-children))
> +	(outline-next-heading)
> +      (org-goto-first-child)
> +      (while (org-get-next-sibling)))
> +    (org-back-over-empty-lines)
> +    (unless (looking-at "[ \t]*$") (save-excursion (insert "\n")))
> +    (org-insert-heading nil t)
> +    (unless has-children
> +      (org-do-demote)))

This part is incorrect, when tree is ill-formed, and slightly
inefficient when there are many children.

Assuming point is on the parent headline, I think a faster way to do
this would be

  (org-end-of-subtree t t)
  (org-insert-heading nil t)
  (org-do-demote)

You don't need `has-children' binding at all.


Regards,

-- 
Nicolas Goaziou

Re: [PATCH 2/2] Allow inserting diary entries last in date tree

[Nikolai Weibull]

On Sun, Aug 23, 2015 at 9:40 AM, Nicolas Goaziou <mail@nicolasgoaziou.fr> wrote:

>> +  (let ((last (eq org-agenda-insert-diary-strategy 'date-tree-last))
>> +     (has-children (save-excursion (org-goto-first-child))))
>> +    (if (not (and last has-children))
>> +     (outline-next-heading)
>> +      (org-goto-first-child)
>> +      (while (org-get-next-sibling)))
>> +    (org-back-over-empty-lines)
>> +    (unless (looking-at "[ \t]*$") (save-excursion (insert "\n")))
>> +    (org-insert-heading nil t)
>> +    (unless has-children
>> +      (org-do-demote)))
>
> This part is incorrect, when tree is ill-formed, and slightly
> inefficient when there are many children.
>
> Assuming point is on the parent headline, I think a faster way to do
> this would be
>
>   (org-end-of-subtree t t)
>   (org-insert-heading nil t)
>   (org-do-demote)

That’s what I used first, but that doesn’t work if the subtree has
children that has children.

Re: [PATCH 2/2] Allow inserting diary entries last in date tree

[Nicolas Goaziou]

Nikolai Weibull <now@disu.se> writes:

> That’s what I used first, but that doesn’t work if the subtree has
> children that has children.

Indeed. I realized it was wrong a short time after sending it. What
about:

  (end-of-line)
  (org-insert-heading '(4) t)
  (org-do-demote)

?

Regards,

[PATCH] Allow inserting diary entries last in date tree

[Nikolai Weibull]

* org-agenda.el (org-agenda-insert-diary-strategy): Add new value
  'date-tree-last.
  (org-agenda-insert-diary-make-new-entry): Handle
  `org-agenda-insert-diary-strategy' set to 'date-tree-last.

To allow for diary entries to be entered in time order in the date tree,
add a new value to `org-agenda-insert-diary-strategy' that allows for
this.  The code for handling this value, 'date-tree-last, is a bit
tricky, as we need to keep track of whether the date-tree already had
one or more entries for the given date.
---
 lisp/org-agenda.el | 26 +++++++++++++++++---------
 1 file changed, 17 insertions(+), 9 deletions(-)

diff --git a/lisp/org-agenda.el b/lisp/org-agenda.el
index 5fd1cd4..d97b3a9 100644
--- a/lisp/org-agenda.el
+++ b/lisp/org-agenda.el
@@ -9417,11 +9417,13 @@ buffer, display it in another window."
   "Where in `org-agenda-diary-file' should new entries be added?
 Valid values:
 
-date-tree    in the date tree, as child of the date
-top-level    as top-level entries at the end of the file."
+date-tree         in the date tree, as first child of the date
+date-tree-last    in the date tree, as last child of the date
+top-level         as top-level entries at the end of the file."
   :group 'org-agenda
   :type '(choice
-	  (const :tag "in a date tree" date-tree)
+	  (const :tag "first in a date tree" date-tree)
+	  (const :tag "last in a date tree" date-tree-last)
 	  (const :tag "as top level at end of file" top-level)))
 
 (defcustom org-agenda-insert-diary-extract-time nil
@@ -9525,14 +9527,20 @@ a timestamp can be added there."
   (when org-adapt-indentation (org-indent-to-column 2)))
 
 (defun org-agenda-insert-diary-make-new-entry (text)
-  "Make a new entry with TEXT as the first child of the current subtree.
+  "Make a new entry with TEXT as a child of the current subtree.
 Position the point in the heading's first body line so that
 a timestamp can be added there."
-  (outline-next-heading)
-  (org-back-over-empty-lines)
-  (unless (looking-at "[ \t]*$") (save-excursion (insert "\n")))
-  (org-insert-heading nil t)
-  (org-do-demote)
+  (cond
+   ((eq org-agenda-insert-diary-strategy 'date-tree-last)
+    (end-of-line)
+    (org-insert-heading '(4) t)
+    (org-do-demote))
+   (t
+    (outline-next-heading)
+    (org-back-over-empty-lines)
+    (unless (looking-at "[ \t]*$") (save-excursion (insert "\n")))
+    (org-insert-heading nil t)
+    (org-do-demote)))
   (let ((col (current-column)))
     (insert text)
     (org-end-of-meta-data)
-- 
2.5.0

Re: [PATCH] Allow inserting diary entries last in date tree

[Nicolas Goaziou]

Nikolai Weibull <now@disu.se> writes:

> * org-agenda.el (org-agenda-insert-diary-strategy): Add new value
>   'date-tree-last.
>   (org-agenda-insert-diary-make-new-entry): Handle
>   `org-agenda-insert-diary-strategy' set to 'date-tree-last.
>
> To allow for diary entries to be entered in time order in the date tree,
> add a new value to `org-agenda-insert-diary-strategy' that allows for
> this.  The code for handling this value, 'date-tree-last, is a bit
> tricky, as we need to keep track of whether the date-tree already had
> one or more entries for the given date.

Applied. Thank you.

Regards,

Re: [PATCH] Allow inserting diary entries last in date tree

[Nicolas Goaziou]

Completing myself,

Nicolas Goaziou <mail@nicolasgoaziou.fr> writes:

> Nikolai Weibull <now@disu.se> writes:
>
>> * org-agenda.el (org-agenda-insert-diary-strategy): Add new value
>>   'date-tree-last.
>>   (org-agenda-insert-diary-make-new-entry): Handle
>>   `org-agenda-insert-diary-strategy' set to 'date-tree-last.
>>
>> To allow for diary entries to be entered in time order in the date tree,
>> add a new value to `org-agenda-insert-diary-strategy' that allows for
>> this.  The code for handling this value, 'date-tree-last, is a bit
>> tricky, as we need to keep track of whether the date-tree already had
>> one or more entries for the given date.
>
> Applied. Thank you.

BTW, would you mind providing an entry about it ORG-NEWS?

Thank you.

[PATCH] Add news about org-agenda-insert-diary-strategy

[Nikolai Weibull]

---
 etc/ORG-NEWS | 3 +++
 1 file changed, 3 insertions(+)

diff --git a/etc/ORG-NEWS b/etc/ORG-NEWS
index f1d85c1..dc0d8b1 100644
--- a/etc/ORG-NEWS
+++ b/etc/ORG-NEWS
@@ -12,6 +12,9 @@ Please send Org bug reports to emacs-orgmode@gnu.org.
 ** New features
 *** Org linter
 ~org-lint~ can check syntax and report common issues in Org documents.
+*** New option ~date-tree-last~ for ~org-agenda-insert-diary-strategy~
+When ~org-agenda-insert-diary-strategy~ is set to ~date-tree-last~, diary
+entries are added to last in the date tree.
 ** New functions
 ~org-show-children~ is a faster implementation of
 ~outline-show-children~.
-- 
2.5.0

Re: [PATCH] Add news about org-agenda-insert-diary-strategy

[Bastien]

Applied, thanks!

-- 
 Bastien