Java mixed case deletion

Java mixed case deletion

[Mahesh Padmanabhan]

Hi,

I currently have the following set up as part of my java mode hook:

(add-hook 'java-mode-hook
           (function (lambda ()
                       (c-set-style              "stroustrup")
                       (c-set-offset 'inline-open 0)
                       (define-key java-mode-map  "\C-c\C-d" 'insert-date)
                       (make-local-variable      'comment-multi-line)
                       (define-key java-mode-map
                         [C-right] 'c-forward-into-nomenclature)
                       (define-key java-mode-map
                         [C-left] 'c-backward-into-nomenclature)
                       (setq comment-multi-line  t))))

The functions c-forward-into-nomenclature and 
c-backward-into-nomenclature take care of negotiating mixed case words 
but i could not find anything that allows me to delete while keeping 
mixed case in mind.

For example - if there is a word like this: SomeClass then a backward 
delete word deletes the whole word. What I want is to delete just Class 
in SomeClass.

Is it possible?

Thanks,
Mahesh

Re: Java mixed case deletion

[Benjamin Rutt]

Mahesh Padmanabhan <mahesh@privacy.net> writes:

> The functions c-forward-into-nomenclature and
> c-backward-into-nomenclature take care of negotiating mixed case words
> but i could not find anything that allows me to delete while keeping
> mixed case in mind.
>
> For example - if there is a word like this: SomeClass then a backward
> delete word deletes the whole word. What I want is to delete just
> Class in SomeClass.

(defun my-c-kill-forward-into-nomenclature (&optional arg)
  "Kill forward to the end of a nomenclature section or word.  With
arg, do it arg times."
  (interactive "p")
  (save-excursion
    (set-mark (point))
    (c-forward-into-nomenclature arg)
    (kill-region (mark) (point))))

(defun my-c-kill-backward-into-nomenclature (&optional arg)
  "Kill backward to the beginning of a nomenclature section or word.
th arg, do it arg times."
  (interactive "p")
  (save-excursion
    (set-mark (point))
    (c-backward-into-nomenclature arg)
    (kill-region (mark) (point))))

Add those to your keys of choice in the hook and you're all set.  I
use 

  (local-set-key [(control backspace)] 'my-c-kill-backward-into-nomenclature)
  (local-set-key [(meta d)] 'my-c-kill-forward-into-nomenclature)

inside my c-mode-common-hook, personally.
-- 
Benjamin Rutt

Re: Java mixed case deletion

[Mahesh Padmanabhan]

Benjamin Rutt wrote:
> Mahesh Padmanabhan <mahesh@privacy.net> writes:
> 
> 
>>The functions c-forward-into-nomenclature and
>>c-backward-into-nomenclature take care of negotiating mixed case words
>>but i could not find anything that allows me to delete while keeping
>>mixed case in mind.
>>
>>For example - if there is a word like this: SomeClass then a backward
>>delete word deletes the whole word. What I want is to delete just
>>Class in SomeClass.
> 
> 
> (defun my-c-kill-forward-into-nomenclature (&optional arg)
>   "Kill forward to the end of a nomenclature section or word.  With
> arg, do it arg times."
>   (interactive "p")
>   (save-excursion
>     (set-mark (point))
>     (c-forward-into-nomenclature arg)
>     (kill-region (mark) (point))))
> 
> (defun my-c-kill-backward-into-nomenclature (&optional arg)
>   "Kill backward to the beginning of a nomenclature section or word.
> th arg, do it arg times."
>   (interactive "p")
>   (save-excursion
>     (set-mark (point))
>     (c-backward-into-nomenclature arg)
>     (kill-region (mark) (point))))
> 
> Add those to your keys of choice in the hook and you're all set.  I
> use 
> 
>   (local-set-key [(control backspace)] 'my-c-kill-backward-into-nomenclature)
>   (local-set-key [(meta d)] 'my-c-kill-forward-into-nomenclature)
> 
> inside my c-mode-common-hook, personally.

Thanks!

Re: Java mixed case deletion

[Kevin Rodgers]

Benjamin Rutt wrote:
 > (defun my-c-kill-forward-into-nomenclature (&optional arg)
 >   "Kill forward to the end of a nomenclature section or word.  With
 > arg, do it arg times."
 >   (interactive "p")
 >   (save-excursion
 >     (set-mark (point))
 >     (c-forward-into-nomenclature arg)
 >     (kill-region (mark) (point))))
 >
 > (defun my-c-kill-backward-into-nomenclature (&optional arg)
 >   "Kill backward to the beginning of a nomenclature section or word.
 > th arg, do it arg times."
 >   (interactive "p")
 >   (save-excursion
 >     (set-mark (point))
 >     (c-backward-into-nomenclature arg)
 >     (kill-region (mark) (point))))

I think you can avoid the (save-excursion (set-mark ...) ...) construction:

(defun my-c-kill-forward-into-nomenclature (&optional n)
   "Kill forward to the end of a nomenclature section or word.
With a prefix arg, kill N names."
   (interactive "p")
   (kill-region (point)
                (progn
                  (c-forward-into-nomenclature n)
                  (point))))

(defun my-c-kill-backward-into-nomenclature (&optional n)
   "Kill backward to the beginning of a nomenclature section or word.
With a prefix arg, kill N names."
   (interactive "p")
   (kill-region (point)
                (progn
                  (c-backward-into-nomenclature n)
                  (point))))

-- 
Kevin Rodgers