* bug#26355: 26.0.50; find-library doesn't handle load-history entries with nil FILE-NAME
@ 2017-04-04 1:27 npostavs
2017-04-18 12:07 ` npostavs
0 siblings, 1 reply; 2+ messages in thread
From: npostavs @ 2017-04-04 1:27 UTC (permalink / raw)
To: 26355
[-- Attachment #1: Type: text/plain, Size: 231 bytes --]
Severiy: minor
Tags: patch
emacs -Q
Insert (defun foo ()) and C-M-x on it.
M-x find-library blah RET gives "Wrong type argument: stringp, nil"
Expected "find-library-name: Can’t find library blah"
Here is a patch.
[-- Warning: decoded text below may be mangled, UTF-8 assumed --]
[-- Attachment #2: pathc --]
[-- Type: text/x-diff, Size: 3308 bytes --]
From bbd991199206e9d23170d47e0ae2bfb616ba6fff Mon Sep 17 00:00:00 2001
From: Noam Postavsky <npostavs@gmail.com>
Date: Sat, 25 Mar 2017 22:41:34 -0400
Subject: [PATCH v1] Let find-library-name handle load-history entries with nil
file-name
* lisp/emacs-lisp/find-func.el (find-library--from-load-history):
Rename from find-library--from-load-path. Check for `load-history'
entries with nil FILE-NAMEs. Simplify by not double checking for
suffixes and making use of `locate-file'.
---
lisp/emacs-lisp/find-func.el | 48 ++++++++++++--------------------------------
1 file changed, 13 insertions(+), 35 deletions(-)
diff --git a/lisp/emacs-lisp/find-func.el b/lisp/emacs-lisp/find-func.el
index 6699e3fd2b..d0acc14775 100644
--- a/lisp/emacs-lisp/find-func.el
+++ b/lisp/emacs-lisp/find-func.el
@@ -43,7 +43,7 @@
;;; Code:
-(require 'seq)
+(eval-when-compile (require 'cl-lib))
;;; User variables:
@@ -203,43 +203,21 @@ find-library-name
(locate-file rel
(or find-function-source-path load-path)
load-file-rep-suffixes)))))
- (find-library--from-load-path library)
+ (find-library--from-load-history library)
(error "Can't find library %s" library)))
-(defun find-library--from-load-path (library)
+(defun find-library--from-load-history (library)
;; In `load-history', the file may be ".elc", ".el", ".el.gz", and
- ;; LIBRARY may be "foo.el" or "foo", so make sure that we get all
- ;; potential matches, and then see whether any of them lead us to an
- ;; ".el" or an ".el.gz" file.
- (let* ((elc-regexp "\\.el\\(c\\(\\..*\\)?\\)\\'")
- (suffix-regexp
- (concat "\\("
- (mapconcat 'regexp-quote (find-library-suffixes) "\\'\\|")
- "\\|" elc-regexp "\\)\\'"))
- (potentials
- (mapcar
- (lambda (entry)
- (if (string-match suffix-regexp (car entry))
- (replace-match "" t t (car entry))
- (car entry)))
- (seq-filter
- (lambda (entry)
- (string-match
- (concat "\\`"
- (regexp-quote
- (replace-regexp-in-string suffix-regexp "" library))
- suffix-regexp)
- (file-name-nondirectory (car entry))))
- load-history)))
- result)
- (dolist (file potentials)
- (dolist (suffix (find-library-suffixes))
- (when (not result)
- (cond ((file-exists-p file)
- (setq result file))
- ((file-exists-p (concat file suffix))
- (setq result (concat file suffix)))))))
- result))
+ ;; LIBRARY may be "foo.el" or "foo".
+ (let ((load-re
+ (concat "\\(" (regexp-quote (file-name-sans-extension library)) "\\)"
+ (regexp-opt (get-load-suffixes)) "\\'")))
+ (cl-loop
+ for (file . _) in load-history thereis
+ (and (stringp file) (string-match load-re file)
+ (let ((dir (substring file 0 (match-beginning 1)))
+ (basename (match-string 1 file)))
+ (locate-file basename (list dir) (find-library-suffixes)))))))
(defvar find-function-C-source-directory
(let ((dir (expand-file-name "src" source-directory)))
--
2.11.1
^ permalink raw reply related [flat|nested] 2+ messages in thread
* bug#26355: 26.0.50; find-library doesn't handle load-history entries with nil FILE-NAME
2017-04-04 1:27 bug#26355: 26.0.50; find-library doesn't handle load-history entries with nil FILE-NAME npostavs
@ 2017-04-18 12:07 ` npostavs
0 siblings, 0 replies; 2+ messages in thread
From: npostavs @ 2017-04-18 12:07 UTC (permalink / raw)
To: 26355
tags 26355 fixed
close 26355
quit
npostavs@users.sourceforge.net writes:
> emacs -Q
>
> Insert (defun foo ()) and C-M-x on it.
> M-x find-library blah RET gives "Wrong type argument: stringp, nil"
> Expected "find-library-name: Can’t find library blah"
>
> Here is a patch.
Pushed to master [1: 861824dbec].
1: 2017-04-18 07:54:28 -0400 861824dbecc96339c68b1e15008a21c31e04721b
Fix find-library-name for load-history entries with nil FILE-NAME (Bug#26355)
^ permalink raw reply [flat|nested] 2+ messages in thread
end of thread, other threads:[~2017-04-18 12:07 UTC | newest]
Thread overview: 2+ messages (download: mbox.gz follow: Atom feed
-- links below jump to the message on this page --
2017-04-04 1:27 bug#26355: 26.0.50; find-library doesn't handle load-history entries with nil FILE-NAME npostavs
2017-04-18 12:07 ` npostavs
Code repositories for project(s) associated with this external index
https://git.savannah.gnu.org/cgit/emacs.git
https://git.savannah.gnu.org/cgit/emacs/org-mode.git
This is an external index of several public inboxes,
see mirroring instructions on how to clone and mirror
all data and code used by this external index.