From: Mekeor Melire <mekeor@posteo.de>
To: 67615@debbugs.gnu.org
Cc: Eli Zaretskii <eliz@gnu.org>
Subject: bug#67615: [PATCH v7] Add option Info-url-alist
Date: Sun, 21 Jan 2024 01:43:04 +0000 [thread overview]
Message-ID: <87a5oz30om.fsf@posteo.de> (raw)
In-Reply-To: <835xzov57b.fsf@gnu.org>
[-- Attachment #1: Type: text/plain, Size: 1482 bytes --]
2024-01-20 09:23 eliz@gnu.org:
> What about the case where the HTML docs are produced with one file per
> node? doesn't Texinfo create in that case directories that are named
> like the manual, but without the .html extension?
I tested this and found out that Texinfo does not create directories for
each node in that case.
The reason why after omitting the .html-suffix gnu.org still serves the
html-manual is its web-server configuration. This was confirmed to me
via IRC in the #gnu channel on libera.chat server.
Attached is a new version of that patch with following changes:
- Let Info-url-for-node skip whitespace and newlines between closing
parenthesis and node-name. This mimics Texinfo as can be traced here:
https://git.savannah.gnu.org/cgit/texinfo.git/tree/info/info.h?h=114e10b2a1cb5ee07ae6b9d1228d6d016c9f86e6#n44
https://git.savannah.gnu.org/cgit/texinfo.git/tree/info/scan.c?h=114e10b2a1cb5ee07ae6b9d1228d6d016c9f86e6#n123
It also makes Info-url-for-node work with the string that is put into
kill-ring with the Info-copy-current-node-name command which uses a
whitespace.
- Do not use a .html suffix, neither in the default value for the new
Info-url-alist, nor in the %e format-thing that can be in user-defined
values of it. Users still can add a ".html" suffix themselves, if the
respective web-server does not support omitting it.
- More tests, including manuals in all relevant directories and formats
and "special" characters.
[-- Warning: decoded text below may be mangled, UTF-8 assumed --]
[-- Attachment #2: 0001-Add-option-Info-url-alist.patch --]
[-- Type: text/x-patch, Size: 9077 bytes --]
From 856ea96868c54af8649cd604b5f92cf5cab4ca3c Mon Sep 17 00:00:00 2001
From: Mekeor Melire <mekeor@posteo.de>
Date: Mon, 4 Dec 2023 16:37:37 +0100
Subject: [PATCH] Add option Info-url-alist
* lisp/info.el (Info-url-alist): New option mapping manuals to URLs.
(Info-url-for-node): Use it.
* test/lisp/info-tests.el (test-info-urls): Add more tests. In
particular, Info-url-for-node should error when manual-name is not
handled in Info-url-alist.
* etc/NEWS: Announce the change.
---
etc/NEWS | 9 ++++
lisp/info.el | 108 ++++++++++++++++++++++++++++++++--------
test/lisp/info-tests.el | 14 ++++--
3 files changed, 105 insertions(+), 26 deletions(-)
diff --git a/etc/NEWS b/etc/NEWS
index a6b0beb6ee5..f0540df95f7 100644
--- a/etc/NEWS
+++ b/etc/NEWS
@@ -402,6 +402,15 @@ respectively, in addition to the existing translations 'C-x 8 / e' and
\f
* Changes in Specialized Modes and Packages in Emacs 30.1
+** Info
+
+---
+*** New user option 'Info-url-alist'.
+This user option associates manual-names with URLs. It affects the
+'Info-goto-node-web' command. By default, associations for all
+Emacs-included manuals are set. Further associations can be added for
+arbitrary Info manuals.
+
+++
** New command 'lldb'.
Run the LLDB debugger, analogous to the 'gud-gdb' command.
diff --git a/lisp/info.el b/lisp/info.el
index 39ca88c358c..4b3df1b98a1 100644
--- a/lisp/info.el
+++ b/lisp/info.el
@@ -213,6 +213,53 @@ Info-additional-directory-list
These directories are searched after those in `Info-directory-list'."
:type '(repeat directory))
+(defcustom Info-url-alist
+ '((("auth" "autotype" "bovine" "calc" "ccmode" "cl" "dbus" "dired-x"
+ "ebrowse" "ede" "ediff" "edt" "efaq" "efaq-w32" "eglot" "eieio"
+ "eintr" "elisp" "emacs" "emacs-gnutls" "emacs-mime" "epa" "erc"
+ "ert" "eshell" "eudc" "eww" "flymake" "forms" "gnus"
+ "htmlfontify" "idlwave" "ido" "info" "mairix-el" "message"
+ "mh-e" "modus-themes" "newsticker" "nxml-mode" "octave-mode"
+ "org" "pcl-cvs" "pgg" "rcirc" "reftex" "remember" "sasl" "sc"
+ "semantic" "ses" "sieve" "smtpmail" "speedbar" "srecode"
+ "todo-mode" "tramp" "transient" "url" "use-package" "vhdl-mode"
+ "vip" "viper" "vtable" "widget" "wisent" "woman") .
+ "https://www.gnu.org/software/emacs/manual/html_node/%m/%e"))
+ "Alist telling `Info-mode' where manuals are accessible online.
+
+Each element of this list has the form (MANUALs . URL-SPEC).
+MANUALs represents the name of one or more manuals. It can
+either be a string or a list of strings. URL-SPEC can be a
+string in which the substring \"%m\" will be expanded to the
+manual-name, \"%n\" to the node-name, and \"%e\" to the
+URL-encoded node-name (without a `.html' suffix). (The
+URL-encoding of the node-name mimics GNU Texinfo, as documented
+at Info node `(texinfo)HTML Xref Node Name Expansion'.)
+Alternatively, URL-SPEC can be a function which is given
+manual-name, node-name and URL-encoded node-name as arguments,
+and is expected to return the corresponding URL as a string.
+
+This variable particularly affects the command
+`Info-goto-node-web', which see.
+
+The default value of this variable refers to the official,
+HTTPS-accessible HTML-representations of all manuals that Emacs
+includes. These URLs refer to the most recently released version
+of Emacs, disregarding the version of the running Emacs. In
+other words, the content of your local Info node and the
+associated online node may differ. The resource represented by
+the generated URL may even be not found by the gnu.org server."
+ :version "30.1"
+ :type '(alist
+ :tag "Mapping from manual-name(s) to URL-specification"
+ :key-type (choice
+ (string :tag "A single manual-name")
+ (repeat :tag "List of manual-names" string))
+ :value-type (choice
+ (string :tag "URL-specification string")
+ (function
+ :tag "URL-specification function"))))
+
(defcustom Info-scroll-prefer-subnodes nil
"If non-nil, \\<Info-mode-map>\\[Info-scroll-up] in a menu visits subnodes.
@@ -1807,33 +1854,50 @@ Info-goto-node-web
(Info-url-for-node (format "(%s)%s" filename node)))))
(defun Info-url-for-node (node)
- "Return a URL for NODE, a node in the GNU Emacs or Elisp manual.
-NODE should be a string on the form \"(manual)Node\". Only emacs
-and elisp manuals are supported."
- (unless (string-match "\\`(\\(.+\\))\\(.+\\)\\'" node)
- (error "Invalid node name %s" node))
- (let ((manual (match-string 1 node))
- (node (match-string 2 node)))
- (unless (member manual '("emacs" "elisp"))
- (error "Only emacs/elisp manuals are supported"))
- ;; Encode a bunch of characters the way that makeinfo does.
- (setq node
- (mapconcat (lambda (ch)
- (if (or (< ch 32) ; ^@^A-^Z^[^\^]^^^-
+ "Return the URL corresponding to NODE.
+
+NODE should be a string of the form \"(manual)Node\"."
+ ;; GNU Texinfo skips whitespaces and newlines between the closing
+ ;; parenthesis and the node-name, i.e. space, tab, line feed and
+ ;; carriage return.
+ (unless (string-match "\\`(\\(.+\\))[ \t\n\r]*\\(.+\\)\\'" node)
+ (error "Invalid node-name %s" node))
+ ;; Use `if-let*' instead of `let*' so we check if an association was
+ ;; found.
+ (if-let* ((manual (match-string 1 node))
+ (node (match-string 2 node))
+ (association (seq-find
+ (lambda (pair)
+ (seq-contains-p (ensure-list (car pair))
+ manual #'string-equal-ignore-case))
+ Info-url-alist))
+ (url-spec (cdr association))
+ (encoded-node
+ ;; Reproduce GNU Texinfo's way of URL-encoding.
+ ;; (info "(texinfo) HTML Xref Node Name Expansion")
+ (if (equal node "Top")
+ ""
+ (url-hexify-string
+ (string-replace " " "-"
+ (mapconcat
+ (lambda (ch)
+ (if (or (< ch 32) ; ^@^A-^Z^[^\^]^^^-
(<= 33 ch 47) ; !"#$%&'()*+,-./
(<= 58 ch 64) ; :;<=>?@
(<= 91 ch 96) ; [\]_`
(<= 123 ch 127)) ; {|}~ DEL
(format "_00%x" ch)
- (char-to-string ch)))
- node
- ""))
- (concat "https://www.gnu.org/software/emacs/manual/html_node/"
- manual "/"
- (and (not (equal node "Top"))
- (concat
- (url-hexify-string (string-replace " " "-" node))
- ".html")))))
+ (char-to-string ch)))
+ node ""))))))
+ (cond
+ ((stringp url-spec)
+ (format-spec url-spec
+ `((?m . ,manual) (?n . ,node) (?e . ,encoded-node))))
+ ((functionp url-spec)
+ (funcall url-spec manual node encoded-node))
+ (t (error "URL-specification neither string nor function")))
+ (error "No URL-specification associated with manual-name `%s'"
+ manual)))
(defvar Info-read-node-completion-table)
diff --git a/test/lisp/info-tests.el b/test/lisp/info-tests.el
index ebe718167bf..0dfdbf417e8 100644
--- a/test/lisp/info-tests.el
+++ b/test/lisp/info-tests.el
@@ -29,11 +29,17 @@
(ert-deftest test-info-urls ()
(should (equal (Info-url-for-node "(emacs)Minibuffer")
- "https://www.gnu.org/software/emacs/manual/html_node/emacs/Minibuffer.html"))
+ "https://www.gnu.org/software/emacs/manual/html_node/emacs/Minibuffer"))
(should (equal (Info-url-for-node "(emacs)Minibuffer File")
- "https://www.gnu.org/software/emacs/manual/html_node/emacs/Minibuffer-File.html"))
+ "https://www.gnu.org/software/emacs/manual/html_node/emacs/Minibuffer-File"))
(should (equal (Info-url-for-node "(elisp)Backups and Auto-Saving")
- "https://www.gnu.org/software/emacs/manual/html_node/elisp/Backups-and-Auto_002dSaving.html"))
- (should-error (Info-url-for-node "(gnus)Minibuffer File")))
+ "https://www.gnu.org/software/emacs/manual/html_node/elisp/Backups-and-Auto_002dSaving"))
+ (should (equal (Info-url-for-node "(eintr)car & cdr")
+ "https://www.gnu.org/software/emacs/manual/html_node/eintr/car-_0026-cdr"))
+ (should (equal (Info-url-for-node "(emacs-mime)\tIndex")
+ "https://www.gnu.org/software/emacs/manual/html_node/emacs-mime/Index"))
+ (should (equal (Info-url-for-node "(gnus) Don't Panic")
+ "https://www.gnu.org/software/emacs/manual/html_node/gnus/Don_0027t-Panic"))
+ (should-error (Info-url-for-node "(nonexistent)Example")))
;;; info-tests.el ends here
--
2.41.0
next prev parent reply other threads:[~2024-01-21 1:43 UTC|newest]
Thread overview: 23+ messages / expand[flat|nested] mbox.gz Atom feed top
2023-12-04 0:04 bug#67615: [PATCH] * lisp/info.el (Info-url-for-node): Support all Emacs info manuals Mekeor Melire
2023-12-04 0:30 ` Mekeor Melire
2023-12-04 10:02 ` bug#67615: [PATCH v2] " Mekeor Melire
2023-12-04 15:51 ` Mekeor Melire
2023-12-04 16:24 ` Eli Zaretskii
2023-12-05 1:06 ` bug#67615: Org-Mode story on how I gathered the list of Emacs-contained online-manuals Mekeor Melire
2023-12-07 2:48 ` bug#67615: [PATCH v2] * lisp/info.el (Info-url-for-node): Support all Emacs info manuals Richard Stallman
2023-12-07 7:19 ` Eli Zaretskii
2023-12-07 11:56 ` Mekeor Melire
2023-12-07 17:02 ` Eli Zaretskii
2023-12-09 4:05 ` Richard Stallman
2023-12-08 0:15 ` bug#67615: [PATCH v3] * lisp/info.el (Info-url-alist): New option mapping manuals to URLs Mekeor Melire
2023-12-09 9:42 ` Eli Zaretskii
2023-12-09 11:21 ` Mekeor Melire
2023-12-19 23:08 ` bug#67615: [PATCH v4] " Mekeor Melire
2023-12-23 10:05 ` Eli Zaretskii
2024-01-08 21:56 ` bug#67615: [PATCH v5] " Mekeor Melire
2024-01-13 9:51 ` Eli Zaretskii
2024-01-20 0:50 ` bug#67615: [PATCH v6] Add option Info-url-alist Mekeor Melire
2024-01-20 1:41 ` Orhan Kemal Yüksel
2024-01-20 7:23 ` Eli Zaretskii
2024-01-21 1:43 ` Mekeor Melire [this message]
2024-01-27 10:21 ` bug#67615: [PATCH v7] " Eli Zaretskii
Reply instructions:
You may reply publicly to this message via plain-text email
using any one of the following methods:
* Save the following mbox file, import it into your mail client,
and reply-to-all from there: mbox
Avoid top-posting and favor interleaved quoting:
https://en.wikipedia.org/wiki/Posting_style#Interleaved_style
* Reply using the --to, --cc, and --in-reply-to
switches of git-send-email(1):
git send-email \
--in-reply-to=87a5oz30om.fsf@posteo.de \
--to=mekeor@posteo.de \
--cc=67615@debbugs.gnu.org \
--cc=eliz@gnu.org \
/path/to/YOUR_REPLY
https://kernel.org/pub/software/scm/git/docs/git-send-email.html
* If your mail client supports setting the In-Reply-To header
via mailto: links, try the mailto: link
Be sure your reply has a Subject: header at the top and a blank line
before the message body.
Code repositories for project(s) associated with this external index
https://git.savannah.gnu.org/cgit/emacs.git
https://git.savannah.gnu.org/cgit/emacs/org-mode.git
This is an external index of several public inboxes,
see mirroring instructions on how to clone and mirror
all data and code used by this external index.