Re: apply function

[Emanuel Berg <incal@dataswamp.org>]

Karan Ahlawat wrote:

>> What might be the reasons for doing so ?
>
> The most common use case I've seen for this is that apply
> can take in a list as the arguments to the function, where
> a list would not work, and then spread the elements of the
> list as individual arguments. So
>
>     (+ (list 1 2 3))
>
> doesn't work, but doing
>
>     (apply #'+ (list 1 2 3)) ; outputs 6
>
> does work

The other use case is when one has the function stored in
a variable or provided as an argument, i.e. it is not known
from the static code perspective what function will be
executed. Observe:

(require 'cl-lib)

(defun test-final-line-f (fun pos-list)
  (cl-loop for p in pos-list do
    (goto-char p)
    (apply fun nil) ))

Here is a better example, maybe, where the function is either
`re-search-backward' or `re-search-forward' depending on the
argument REV (as in "reverse").

;;; -*- lexical-binding: t -*-
;;
;; this file:
;;   https://dataswamp.org/~incal/emacs-init/regexp.el

(require 'cl-lib)
(require 'dwim)

(defun replace-regexp-1 (re rep &optional beg end rev)
  (interactive
   `(,(read-string "regexp: ")
     ,(read-string "replace: ")
     ,@(use-region t)
     ,current-prefix-arg))
  (or beg (setq beg (point-min)))
  (or end (setq end (point-max)))
  (pcase-let ((`(,start ,sfun ,stop)
               (if rev
                   (list end #'re-search-backward beg)
                 (list beg #'re-search-forward end) )))
    (save-excursion
      (goto-char start)
      (let ((c 0))
        (while (apply sfun re stop '(t))
          (cl-incf c)
          (replace-match rep) )
        (message "matches replaced: %d" c) ))))

(defalias 'rr #'replace-regexp-1)

(provide 'regexp)

Source:
  https://dataswamp.org/~incal/emacs-init/dwim.el
  https://dataswamp.org/~incal/emacs-init/measure.el
  https://dataswamp.org/~incal/emacs-init/regexp.el

-- 
underground experts united
https://dataswamp.org/~incal