From: Mario Lang <mlang@delysid.org>
Subject: [PATCH#2] View differences before saving
Date: Wed, 21 Aug 2002 11:21:54 +0200 [thread overview]
Message-ID: <874rdoy3bh.fsf@lexx.delysid.org> (raw)
OK, I rewrote the function diff-buffer-with-file
using the function `diff' from diff.el.
Following is the patch, the same ChangeLog entry as previously
posted applies:
Index: lisp/files.el
===================================================================
RCS file: /cvsroot/emacs/emacs/lisp/files.el,v
retrieving revision 1.601
diff -u -r1.601 files.el
--- lisp/files.el 15 Aug 2002 20:08:24 -0000 1.601
+++ lisp/files.el 21 Aug 2002 09:18:20 -0000
@@ -2992,17 +2992,55 @@
(rename-file (cdr setmodes) buffer-file-name))))))
setmodes))
+(defun diff-buffer-with-file (&optional buffer)
+ "View the differences between BUFFER and its associated file.
+This requires the external program \"diff\" to be in your `exec-path'."
+ (interactive "bBuffer: ")
+ (setq buffer (get-buffer (or buffer (current-buffer))))
+ (let ((buf-filename (buffer-file-name buffer)))
+ (unless buf-filename
+ (error "Buffer %s has no associated file" buffer))
+ (let ((tempfile (make-temp-file "buffer-content-")))
+ (unwind-protect
+ (progn
+ (with-current-buffer buffer
+ (save-restriction
+ (widen)
+ (write-region (point-min) (point-max) tempfile nil 'nomessage)))
+ (diff buf-filename tempfile))
+ (when (file-exists-p tempfile)
+ (delete-file tempfile)))
+ nil)))
+
+(defvar save-some-buffers-action-alist
+ '((?\C-r
+ (lambda (buf)
+ (view-buffer buf
+ (lambda (ignore)
+ (exit-recursive-edit)))
+ (recursive-edit)
+ ;; Return nil to ask about BUF again.
+ nil)
+ "display the current buffer")
+ (?d diff-buffer-with-file
+ "Show difference to last saved version"))
+ "ACTION-ALIST argument used in call to `map-y-or-n-p'.")
+
(defun save-some-buffers (&optional arg pred)
"Save some modified file-visiting buffers. Asks user about each one.
-You can answer `y' to save, `n' not to save, or `C-r' to look at the
-buffer in question with `view-buffer' before deciding.
+You can answer `y' to save, `n' not to save, `C-r' to look at the
+buffer in question with `view-buffer' before deciding or `d' to
+view the differences using `diff-buffer-to-file'.
Optional argument (the prefix) non-nil means save all with no questions.
Optional second argument PRED determines which buffers are considered:
If PRED is nil, all the file-visiting buffers are considered.
If PRED is t, then certain non-file buffers will also be considered.
If PRED is a zero-argument function, it indicates for each buffer whether
-to consider it or not when called with that buffer current."
+to consider it or not when called with that buffer current.
+
+See `save-some-buffers-action-alist' if you want to
+change the additional actions you can take on files."
(interactive "P")
(save-window-excursion
(let* ((queried nil)
@@ -3034,15 +3072,7 @@
(save-buffer)))
(buffer-list)
'("buffer" "buffers" "save")
- (list (list ?\C-r (lambda (buf)
- (view-buffer buf
- (function
- (lambda (ignore)
- (exit-recursive-edit))))
- (recursive-edit)
- ;; Return nil to ask about BUF again.
- nil)
- "display the current buffer"))))
+ save-some-buffers-action-alist))
(abbrevs-done
(and save-abbrevs abbrevs-changed
(progn
--
CYa,
Mario
next reply other threads:[~2002-08-21 9:21 UTC|newest]
Thread overview: 4+ messages / expand[flat|nested] mbox.gz Atom feed top
2002-08-21 9:21 Mario Lang [this message]
2002-08-22 1:57 ` [PATCH#2] View differences before saving Richard Stallman
2002-09-01 18:23 ` Colin Walters
2002-09-01 18:46 ` Mario Lang
Reply instructions:
You may reply publicly to this message via plain-text email
using any one of the following methods:
* Save the following mbox file, import it into your mail client,
and reply-to-all from there: mbox
Avoid top-posting and favor interleaved quoting:
https://en.wikipedia.org/wiki/Posting_style#Interleaved_style
* Reply using the --to, --cc, and --in-reply-to
switches of git-send-email(1):
git send-email \
--in-reply-to=874rdoy3bh.fsf@lexx.delysid.org \
--to=mlang@delysid.org \
/path/to/YOUR_REPLY
https://kernel.org/pub/software/scm/git/docs/git-send-email.html
* If your mail client supports setting the In-Reply-To header
via mailto: links, try the mailto: link
Be sure your reply has a Subject: header at the top and a blank line
before the message body.
Code repositories for project(s) associated with this external index
https://git.savannah.gnu.org/cgit/emacs.git
https://git.savannah.gnu.org/cgit/emacs/org-mode.git
This is an external index of several public inboxes,
see mirroring instructions on how to clone and mirror
all data and code used by this external index.