[Feature request] I suggest delete-frame command can prompt user for confirmation

[Feature request] I suggest delete-frame command can prompt user for confirmation

[Christopher M. Miles]

[-- Attachment #1: Type: text/plain, Size: 949 bytes --]


I found I always accidentally confused [C-x 5 0] and [C-x 5 o] keybindings. I hope Emacs can add add
prompt confirmation to avoid user accidentally delete frame. Because it can't undo with winner
package etc.

#+begin_src emacs-lisp
(defun my/delete-frame-confirm (origin-func &optional args)
  "Ask user to confirm whether really delete frame.
To avoid accidentally [C-x 5 0] delete frame which confused with keybinding [C-x 5 o]."
  (if (yes-or-no-p "Are you sure to delete current frame? ")
      (apply origin-func args)
    (message "I don't want to delete frame accidently!")))

(advice-add 'delete-frame :around #'my/delete-frame-confirm)
#+end_src

What do you think?

-- 
[ stardiviner ]
       I try to make every word tell the meaning that I want to express.

       Blog: https://stardiviner.github.io/
       IRC(freenode): stardiviner, Matrix: stardiviner
       GPG: F09F650D7D674819892591401B5DF1C95AE89AC3

[-- Attachment #2: signature.asc --]
[-- Type: application/pgp-signature, Size: 488 bytes --]

Re: [Feature request] I suggest delete-frame command can prompt user for confirmation

[Michael Heerdegen]

"Christopher M. Miles" <numbchild@gmail.com> writes:

> #+begin_src emacs-lisp
> (defun my/delete-frame-confirm (origin-func &optional args)
>   "Ask user to confirm whether really delete frame.
> To avoid accidentally [C-x 5 0] delete frame which confused with keybinding [C-x 5 o]."
>   (if (yes-or-no-p "Are you sure to delete current frame? ")
>       (apply origin-func args)
>     (message "I don't want to delete frame accidently!")))
>
> (advice-add 'delete-frame :around #'my/delete-frame-confirm)
> #+end_src
>
> What do you think?

I think it would be annoying and soon you would as often accidentally
say "yes" as you accidentally close frames now.  At least I can say that
it would not work for me.

Wouldn't it be much more useful to be able to restore a killed frame?

Michael.

Re: [Feature request] I suggest delete-frame command can prompt user for confirmation

[Michael Heerdegen]

Michael Heerdegen <michael_heerdegen@web.de> writes:

> Wouldn't it be much more useful to be able to restore a killed frame?

Like this maybe?

#+begin_src emacs-lisp
(require 'frameset)
(require 'cl-lib)

(defvar my-killed-frame-ring-size 10)
(defvar my-killed-frames (make-ring my-killed-frame-ring-size))

(advice-add 'delete-frame :before #'my-remember-deleted-frame)

(defun my-remember-deleted-frame (&optional frame _force)
  (ring-insert my-killed-frames
               (frameset-save (list (or frame (selected-frame))))))

(defun my-restore-killed-frame (&optional n)
  (interactive "p")
  (let ((frames-before (frame-list)))
    (frameset-restore (ring-ref my-killed-frames (- (or n 1) 1)))
    (let ((restored (cl-set-difference (frame-list) frames-before)))
      (when (and restored (not (cdr restored)))
        (select-frame-set-input-focus (car restored))))))

(global-set-key [?\C-x ?5 ?t] #'my-restore-killed-frame)
#+end_src

Michael.

RE: [External] : Re: [Feature request] I suggest delete-frame command can prompt user for confirmation

[Drew Adams]

Depending on what's really needed, you can also
just make a frame invisible (and later make it
visible).  You do this by changing the value of
frame parameter `visibility'.

Re: [Feature request] I suggest delete-frame command can prompt user for confirmation

[Lars Ingebrigtsen]

Michael Heerdegen <michael_heerdegen@web.de> writes:

> Michael Heerdegen <michael_heerdegen@web.de> writes:
>
>> Wouldn't it be much more useful to be able to restore a killed frame?
>
> Like this maybe?

[...]

> (defun my-restore-killed-frame (&optional n)
>   (interactive "p")
>   (let ((frames-before (frame-list)))

Perhaps Emacs should have this command built-in?  Sounds generally
useful to me.

-- 
(domestic pets only, the antidote for overdose, milk.)
   bloggy blog: http://lars.ingebrigtsen.no

Vote for a Emacs built-in command to undo/restore killed frame

[Christopher M. Miles]

[-- Attachment #1: Type: text/plain, Size: 799 bytes --]


Lars Ingebrigtsen <larsi@gnus.org> writes:

> Michael Heerdegen <michael_heerdegen@web.de> writes:
>
>> Michael Heerdegen <michael_heerdegen@web.de> writes:
>>
>>> Wouldn't it be much more useful to be able to restore a killed frame?
>>
>> Like this maybe?
>
> [...]
>
>> (defun my-restore-killed-frame (&optional n)
>>   (interactive "p")
>>   (let ((frames-before (frame-list)))
>
> Perhaps Emacs should have this command built-in?  Sounds generally
> useful to me.

I agree, this might deserve a vote for this command.

-- 
[ stardiviner ]
       I try to make every word tell the meaning that I want to express.

       Blog: https://stardiviner.github.io/
       IRC(freenode): stardiviner, Matrix: stardiviner
       GPG: F09F650D7D674819892591401B5DF1C95AE89AC3

[-- Attachment #2: signature.asc --]
[-- Type: application/pgp-signature, Size: 488 bytes --]

Re: [Feature request] I suggest delete-frame command can prompt user for confirmation

[Michael Heerdegen]

Lars Ingebrigtsen <larsi@gnus.org> writes:

> Perhaps Emacs should have this command built-in?  Sounds generally
> useful to me.

Yeah - we really don't have a solution for this problem built in, right?

Ok, I submitted feature request Bug#51883 raising that question.

Michael.

Re: [Feature request] I suggest delete-frame command can prompt user for confirmation

[Christopher M. Miles]

[-- Attachment #1: Type: text/plain, Size: 641 bytes --]


Michael Heerdegen <michael_heerdegen@web.de> writes:

> Lars Ingebrigtsen <larsi@gnus.org> writes:
>
>> Perhaps Emacs should have this command built-in?  Sounds generally
>> useful to me.
>
> Yeah - we really don't have a solution for this problem built in, right?
>
> Ok, I submitted feature request Bug#51883 raising that question.
>
> Michael.

Thanks for your work.

-- 
[ stardiviner ]
       I try to make every word tell the meaning that I want to express.

       Blog: https://stardiviner.github.io/
       IRC(freenode): stardiviner, Matrix: stardiviner
       GPG: F09F650D7D674819892591401B5DF1C95AE89AC3

[-- Attachment #2: signature.asc --]
[-- Type: application/pgp-signature, Size: 488 bytes --]

[SOLVED] Re: [Feature request] I suggest delete-frame command can prompt user for confirmation

[Christopher M. Miles]

[-- Attachment #1: Type: text/plain, Size: 1487 bytes --]


This is great. Have a way to restore killed frame will be a good replacement for my suggestion.
Thanks for your sharing. Michael.

Michael Heerdegen <michael_heerdegen@web.de> writes:

> Michael Heerdegen <michael_heerdegen@web.de> writes:
>
>> Wouldn't it be much more useful to be able to restore a killed frame?
>
> Like this maybe?
>
> #+begin_src emacs-lisp
> (require 'frameset)
> (require 'cl-lib)
>
> (defvar my-killed-frame-ring-size 10)
> (defvar my-killed-frames (make-ring my-killed-frame-ring-size))
>
> (advice-add 'delete-frame :before #'my-remember-deleted-frame)
>
> (defun my-remember-deleted-frame (&optional frame _force)
>   (ring-insert my-killed-frames
>                (frameset-save (list (or frame (selected-frame))))))
>
> (defun my-restore-killed-frame (&optional n)
>   (interactive "p")
>   (let ((frames-before (frame-list)))
>     (frameset-restore (ring-ref my-killed-frames (- (or n 1) 1)))
>     (let ((restored (cl-set-difference (frame-list) frames-before)))
>       (when (and restored (not (cdr restored)))
>         (select-frame-set-input-focus (car restored))))))
>
> (global-set-key [?\C-x ?5 ?t] #'my-restore-killed-frame)
> #+end_src
>
> Michael.


-- 
[ stardiviner ]
       I try to make every word tell the meaning that I want to express.

       Blog: https://stardiviner.github.io/
       IRC(freenode): stardiviner, Matrix: stardiviner
       GPG: F09F650D7D674819892591401B5DF1C95AE89AC3

[-- Attachment #2: signature.asc --]
[-- Type: application/pgp-signature, Size: 488 bytes --]