Re: Inserting org-mode heading links the org-refile way

[Ihor Radchenko <yantar92@gmail.com>]

If I understand you correctly, the following code should achieve what
you want. The code reuses org-refile interface to complete id: links.  

(defun org-id-prompt-id ()
  "Prompt for the id during completion of id: link."
  (let ((org-refile-history nil)
	(org-refile-cache nil)
	(org-refile-target-verify-function nil))
    (let ((prompt-ans (org-refile-get-location "Select org entry")))
      (prog1
	  (or (org-id-get (seq-find #'markerp
				    prompt-ans)
			  'create)
              (user-error "Cannot find ID of the entry: %s" prompt-ans))
	(setq org-id-history org-refile-history)
	(setq org-id-cache org-refile-cache)))))


(defun org-id-link-complete (&optional arg)
  "Completion function for id: link."
  (let* ((id (org-id-prompt-id)))
    (format "id:%s" id)))

(defun org-id-link-desk (link desk)
  "Description function for id: link."
  (or desk
      (let ((id (cadr (split-string link ":"))))
	(org-with-point-at (org-id-find id 'marker)
	  (org-get-heading 'strip 'all 'the 'extra)))))

(org-link-set-parameters "id"
			 :complete #'org-id-link-complete
                         :desk #'org-id-link-desk)



Daryl Manning <dwm+orgmode@wakatara.com> writes:

> I use ivy and org-refile to process my inbox.org file hyper-efficiently and
> get things into my GTD system.
>
> In a recent discussion on org-roam (which nicely links to files in a nice
> wiki-like manner) it occurred to me if I had a similar interface to search
> for headlines in the manner of org-refile and then insert them effortlessly
> without having to switch to a doc and copy/store them and then switching
> back to my doc and inserting them, I'd be a happy camper.
>
> Is there a package/functions that does/do that in some fashion (say
> configurable to avoid link sprawl so say, like 3 heading levels down and to
> files in specific directories like deft). Googling did not give joy, though
> I noticed someone had used a similar approach for addressing link *within*
> a document, but not quite there (swiper and worf combo and an ivy-org-ref
> package looked interesting).
>
> (I always worry when I post these questions that someone is going to just
> say "but did you not know about M-x org-insert-link-like-ivy-with-refile"
> so go gentle on me if I've missed something obvious. It seems I often do.
> This weekend in particular I've added on a whole bunch of small but in the
> aggregate, large productivity improvements to my emacs setup which I
> approached solving the wrong way until I asked and someone mentioned
> another way to do things, so.... ).
>
> thanks,
> Daryl.

-- 
Ihor Radchenko,
PhD,
Center for Advancing Materials Performance from the Nanoscale (CAMP-nano)
State Key Laboratory for Mechanical Behavior of Materials, Xi'an Jiaotong University, Xi'an, China
Email: yantar92@gmail.com, ihor_radchenko@alumni.sutd.edu.sg