bug#36494: 27.0.50; [Proposition] New option to scroll up regardless of eob

[Marco Wahl <marcowahlsoft@gmail.com>]

[-- Attachment #1: Type: text/plain, Size: 901 bytes --]

Eli Zaretskii <eliz@gnu.org> writes:

>> From: Marco Wahl <marcowahlsoft@gmail.com>
>> Cc: Marco Wahl <marcowahlsoft@gmail.com>,  36494@debbugs.gnu.org
>> Date: Thu, 04 Jul 2019 23:07:15 +0200
>> 
>> Ok, sorry for the patch missing.  Here is the patch.
>
> Thanks.
>
> This seems to work well, but when there's only the single last line
> visible in the window, and the cursor is at EOB, S-DOWN scrolls back,
> i.e. after pressing it Emacs now shows 2 last lines.  I don't think
> this is intended, is it?

No.

Thanks for your review and your finding.

The scroll back behavior was due to a counting issue.  With the new
patch the counting has gone away entirely.

> Also, this is a user-visible change, so it needs to be called out in
> NEWS.
>
> Could you please resubmit with these minor nits fixed?

Okay.  Find a respective proposition in the attachment section, please.


Best regards,  Marco


[-- Warning: decoded text below may be mangled, UTF-8 assumed --]
[-- Attachment #2: 0001-New-function-for-scroll-lock-to-almost-always-scroll.patch --]
[-- Type: text/x-patch, Size: 5101 bytes --]

From e8d3ee812716daa932a62c1ae40e37b3cb326a77 Mon Sep 17 00:00:00 2001
From: Marco Wahl <marcowahlsoft@gmail.com>
Date: Thu, 4 Jul 2019 22:32:44 +0200
Subject: [PATCH] New function for scroll-lock to almost always scroll

* lisp/scroll-lock.el (scroll-lock-next-line-always-scroll): New
  function.  Opposed to scroll-lock-next-line it does not switch to
  forward-line at eob.  S-down is the default key binding for this
  function.
* test/lisp/scroll-lock-tests.el: A few tests for
  scroll-lock-next-line-always-scroll.
* etc/NEWS: Add a respective note.
---
 etc/NEWS                       |  7 ++++
 lisp/scroll-lock.el            | 11 ++++++
 test/lisp/scroll-lock-tests.el | 68 ++++++++++++++++++++++++++++++++++
 3 files changed, 86 insertions(+)
 create mode 100644 test/lisp/scroll-lock-tests.el

diff --git a/etc/NEWS b/etc/NEWS
index abbece374a..efa76fe356 100644
--- a/etc/NEWS
+++ b/etc/NEWS
@@ -1644,6 +1644,13 @@ This runs after changing the dictionary and could be used to
 automatically spellcheck a buffer when changing language without
 needing to advice 'ispell-change-dictionary'.
 
+** scroll-lock
+
+---
+*** New command 'scroll-lock-next-line-always-scroll'.
+This command is bound to 'S-down' and scrolls the buffer up in
+particular when the end of the buffer is visible in the window.
+
 \f
 * New Modes and Packages in Emacs 27.1
 
diff --git a/lisp/scroll-lock.el b/lisp/scroll-lock.el
index 8281edb172..3a74c11b7a 100644
--- a/lisp/scroll-lock.el
+++ b/lisp/scroll-lock.el
@@ -36,6 +36,7 @@ scroll-lock-mode-map
     (define-key map [remap previous-line] 'scroll-lock-previous-line)
     (define-key map [remap forward-paragraph] 'scroll-lock-forward-paragraph)
     (define-key map [remap backward-paragraph] 'scroll-lock-backward-paragraph)
+    (define-key map [S-down] 'scroll-lock-next-line-always-scroll)
     map)
   "Keymap for Scroll Lock mode.")
 
@@ -81,6 +82,16 @@ scroll-lock-move-to-column
       (move-to-column column)
     (forward-char (min column (- (line-end-position) (point))))))
 
+(defun scroll-lock-next-line-always-scroll (&optional arg)
+  "Scroll up ARG lines keeping point fixed."
+  (interactive "p")
+  (or arg (setq arg 1))
+  (scroll-lock-update-goal-column)
+  (condition-case nil
+      (scroll-up arg)
+    (end-of-buffer (goto-char (point-max)) (recenter 1)))
+  (scroll-lock-move-to-column scroll-lock-temporary-goal-column))
+
 (defun scroll-lock-next-line (&optional arg)
   "Scroll up ARG lines keeping point fixed."
   (interactive "p")
diff --git a/test/lisp/scroll-lock-tests.el b/test/lisp/scroll-lock-tests.el
new file mode 100644
index 0000000000..f1ffeed265
--- /dev/null
+++ b/test/lisp/scroll-lock-tests.el
@@ -0,0 +1,68 @@
+;;; scroll-lock-tests.el --- Test suite for scroll-lock -*- lexical-binding: t -*-
+
+;; Copyright (C) 2019 Free Software Foundation, Inc.
+
+;; This file is part of GNU Emacs.
+
+;; GNU Emacs is free software: you can redistribute it and/or modify
+;; it under the terms of the GNU General Public License as published by
+;; the Free Software Foundation, either version 3 of the License, or
+;; (at your option) any later version.
+
+;; GNU Emacs is distributed in the hope that it will be useful,
+;; but WITHOUT ANY WARRANTY; without even the implied warranty of
+;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
+;; GNU General Public License for more details.
+
+;; You should have received a copy of the GNU General Public License
+;; along with GNU Emacs.  If not, see <https://www.gnu.org/licenses/>.
+
+;;; Code:
+
+(require 'ert)
+(require 'scroll-lock)
+
+\f
+(defun point-in-window-line-p (n)
+  "Return if point is in window line N.
+Meaning of N as in `move-to-window-line'.
+Precondition: the line N must be available in the window."
+  (save-excursion
+    (let ((point (progn (beginning-of-line) (point))))
+      (let ((moved-to-line (move-to-window-line n)))
+        (cl-assert (= n moved-to-line) t "precondition violation"))
+      (= point (progn (beginning-of-line) (point))))))
+
+\f
+(ert-deftest scroll-lock-next-line-always-scroll-1 ()
+  "Point stays in top line."
+  (with-temp-buffer
+    (insert "\n\n\n")
+    (goto-char (point-min))
+    (switch-to-buffer (current-buffer))
+    (scroll-lock-next-line-always-scroll)
+    (should (point-in-window-line-p 0))))
+
+(ert-deftest scroll-lock-next-line-always-scroll-2 ()
+  "Point stays in second line."
+  (with-temp-buffer
+    (scroll-lock-mode)
+    (insert "\n\n\n")
+    (goto-char (1+ (point-min)))
+    (switch-to-buffer (current-buffer))
+    (scroll-lock-next-line-always-scroll)
+    (should (point-in-window-line-p 1))))
+
+(ert-deftest scroll-lock-next-line-always-scroll-3 ()
+  "Point stays in second line when scrolling beyond the number of buffer lines."
+  (with-temp-buffer
+    (scroll-lock-mode)
+    (insert (make-string 1000 ?\n))
+    (goto-char (1+ (point-min)))
+    (switch-to-buffer (current-buffer))
+    (scroll-lock-next-line-always-scroll 1234)
+    (should (point-in-window-line-p 1))))
+
+(provide 'scroll-lock-tests)
+
+;;; scroll-lock-tests.el ends here
-- 
2.22.0