default-toplevel-value and set-default-toplevel-value

default-toplevel-value and set-default-toplevel-value

[Eli Zaretskii]

These functions were evidently introduced in Emacs 24.4, but they are
not documented, neither in NEWS nor in the ELisp manual.  The doc
strings are minimal, and leave me confused about how these are
different from default-value and set-default.  Is this just about a
possible let-binding of a localized variable, or is there something
else involved?

And why did the commit that added these functions also made changes in
Custom functions?

TIA

Re: default-toplevel-value and set-default-toplevel-value

[Stefan Monnier]

> These functions were evidently introduced in Emacs 24.4, but they are
> not documented, neither in NEWS nor in the ELisp manual.  The doc
> strings are minimal, and leave me confused about how these are
> different from default-value and set-default.  Is this just about a
> possible let-binding of a localized variable,

Yes.

> or is there something else involved?

No, that's it.

> And why did the commit that added these functions also made changes in
> Custom functions?

Because this was introduced to make defvar (and defcustom) operate on
the default-toplevel-value rather than on the default-value, to avoid
problems when loading, from within a let-binding of foo-bar, a file `foo`
which defines foo-bar.  E.g. this happens when `foo-operate` is
autoloaded in code like:

   (let ((foo-bar t))
     (foo-operate ...))


-- Stefan

Re: default-toplevel-value and set-default-toplevel-value

[Eli Zaretskii]

> From: Stefan Monnier <monnier@iro.umontreal.ca>
> Cc: emacs-devel@gnu.org
> Date: Mon, 12 Dec 2016 11:57:09 -0500
> 
> > These functions were evidently introduced in Emacs 24.4, but they are
> > not documented, neither in NEWS nor in the ELisp manual.  The doc
> > strings are minimal, and leave me confused about how these are
> > different from default-value and set-default.  Is this just about a
> > possible let-binding of a localized variable,
> 
> Yes.
> 
> > or is there something else involved?
> 
> No, that's it.

It seems there is:

    (defvar bufferlocal 'value-default)
     => bufferlocal

    (setq-default bufferlocal 'value-default)
     => value-default

    (setq-local bufferlocal 'value-in-foo)
     => value-in-foo

    (let ((bufferlocal 'let-bound-value))
      (default-value 'bufferlocal))
     => value-default

Based on what you said, I expected the last expression to yield
let-bound-value.  What am I missing?

Re: default-toplevel-value and set-default-toplevel-value

[Eli Zaretskii]

> From: Stefan Monnier <monnier@iro.umontreal.ca>
> Cc: emacs-devel@gnu.org
> Date: Mon, 12 Dec 2016 11:57:09 -0500
> 
> > These functions were evidently introduced in Emacs 24.4, but they are
> > not documented, neither in NEWS nor in the ELisp manual.  The doc
> > strings are minimal, and leave me confused about how these are
> > different from default-value and set-default.  Is this just about a
> > possible let-binding of a localized variable,
> 
> Yes.
> 
> > or is there something else involved?
> 
> No, that's it.

I seem to see there's more to this than meets the eye, see
http://lists.gnu.org/archive/html/emacs-devel/2016-12/msg00924.html.
Could you please help me understand it?  I'd like to document this for
Emacs 25.2.

TIA

Re: default-toplevel-value and set-default-toplevel-value

[Stefan Monnier]

> I seem to see there's more to this than meets the eye, see
> http://lists.gnu.org/archive/html/emacs-devel/2016-12/msg00924.html.
> Could you please help me understand it?  I'd like to document this for
> Emacs 25.2.

I don't understand: there's no use of default-toplevel-value in your
example, AFAICT.


        Stefan

Re: default-toplevel-value and set-default-toplevel-value

[Eli Zaretskii]

> From: Stefan Monnier <monnier@IRO.UMontreal.CA>
> Cc: emacs-devel@gnu.org
> Date: Sun, 25 Dec 2016 23:09:37 -0500
> 
> > I seem to see there's more to this than meets the eye, see
> > http://lists.gnu.org/archive/html/emacs-devel/2016-12/msg00924.html.
> > Could you please help me understand it?  I'd like to document this for
> > Emacs 25.2.
> 
> I don't understand: there's no use of default-toplevel-value in your
> example, AFAICT.

Yes, because there doesn't seem to be any need for using it, as
default-value is unaffected by the let-binding.  I expected
default-value to return the value from let-binding, and
default-toplevel-value to return the global value, otherwise I don't
see why the latter is needed.  I guess I misunderstood something that
you and/or the doc string were trying to tell.

Thanks.

Re: default-toplevel-value and set-default-toplevel-value

[Stefan Monnier]

> Yes, because there doesn't seem to be any need for using it, as
> default-value is unaffected by the let-binding.

That's because the let-binding was in a buffer which had a buffer-local
value, so the let-binding only affects the buffer-local value.

    (defun get-A ()
      (with-current-buffer "A" myvar))
    (defun get-B ()
      (with-current-buffer "B" myvar))

    (defun get-test ()
      (setq myvar 'global)
      (with-current-buffer (get-buffer-create "A")
        (setq-local myvar 'local-A))
      (with-current-buffer (get-buffer-create "B")
        (setq-local myvar 'local-B))
      (list (list (get-A) (get-B) (default-value 'myvar))
            (with-current-buffer "*scratch*"
              (let ((myvar 'let-bound))
                (list (get-A) (get-B) (default-value 'myvar))))
            (with-current-buffer "A"
              (let ((myvar 'let-bound))
                (list (get-A) (get-B) (default-value 'myvar))))
            (with-current-buffer "B"
              (let ((myvar 'let-bound))
                (list (get-A) (get-B) (default-value 'myvar))))))


-- Stefan

Re: default-toplevel-value and set-default-toplevel-value

[Eli Zaretskii]

> From: Stefan Monnier <monnier@iro.umontreal.ca>
> Cc: emacs-devel@gnu.org
> Date: Mon, 26 Dec 2016 11:45:55 -0500
> 
> > Yes, because there doesn't seem to be any need for using it, as
> > default-value is unaffected by the let-binding.
> 
> That's because the let-binding was in a buffer which had a buffer-local
> value, so the let-binding only affects the buffer-local value.

So this is only for when Lisp code runs in a buffer that doesn't have
a localized binding?

Thanks, I think I've got it.  Please see if the documentation I just
pushed to the emacs-25 branch looks okay.

Re: default-toplevel-value and set-default-toplevel-value

[Stefan Monnier]

>> That's because the let-binding was in a buffer which had a buffer-local
>> value, so the let-binding only affects the buffer-local value.
> So this is only for when Lisp code runs in a buffer that doesn't have
> a localized binding?

Right, which is also "any buffer" if the buffer doesn't have any
buffer-local settings in any buffer.


        Stefan