elisp issues on (cond ((when ...) t) ((when) t))

elisp issues on (cond ((when ...) t) ((when) t))

[Sebastian Meisel]

Hallo,

I'm trying to enhance my flyspell a little bit for german usage and succeeded 
in some aspects, but now come again to the shortcomings of my knowledge of 
elisp. I tried the following code:
------->
(add-hook 'flyspell-incorrect-hook 'flyspell-zusammen())

(defun flyspell-zusammen (beg end poss)
"Better spell-checking for german combined words."
(cond (
       (when (re-search-backward "\"-" (- beg 2) t) 
	 (when (consp poss)
	   (setq temp-buffer (get-buffer-create " *flyspell-temp*"))
	   (save-excursion
	     (copy-to-buffer temp-buffer beg end)
	     (set-buffer temp-buffer)
	     (goto-char (point-min))
	     (setq word (capitalize (buffer-string)))
	     (message word)
	     (when (member word (nth 2 poss)) t) 
	     ))) t)  ;;(when (re-search
      ((when (and (re-search-forward "-" (+ end 2) t) (re-search-backward 
"s" (1- end) t))
	 (when (consp poss)
	   (setq temp-buffer (get-buffer-create " *flyspell-temp*"))
	   (save-excursion
	     (copy-to-buffer temp-buffer beg (1- end))
	     (set-buffer temp-buffer)
	     (goto-char (point-min))
	     (setq word (capitalize (buffer-string)))
	     (message word)
	     (when (member word (nth 2 poss)) t)
	     ))) t) ;; (when (and (re-search
      ))
<------------

When I try the function without (cond) and with only one  (when 
(re-search ...) it works, but (cond ((when ...) t) ((when ...) t)) seems not 
to return nil as aspected, when both conditions fail. So no word are 
considered incorrect. 

What is the error I made?

-- 
Sebastian Meisel

(P.S. I apologize, that I incidently used german language in on mail before -- 
switching mailing lists need some concentration.) 

Re: elisp issues on (cond ((when ...) t) ((when) t))

[Kevin Rodgers]

Sebastian Meisel wrote:
 > I'm trying to enhance my flyspell a little bit for german usage and
 > succeeded in some aspects, but now come again to the shortcomings of
 > my knowledge of elisp. I tried the following code:
 > ------->
 > (add-hook 'flyspell-incorrect-hook 'flyspell-zusammen())

The () probably does not do what you think -- it's equivalent to the
following, so just get rid of it:

(add-hook 'flyspell-incorrect-hook 'flyspell-zusammen nil)

 > (defun flyspell-zusammen (beg end poss)
 > "Better spell-checking for german combined words."
 > (cond (
 >        (when (re-search-backward "\"-" (- beg 2) t)
 > 	 (when (consp poss)
 > 	   (setq temp-buffer (get-buffer-create " *flyspell-temp*"))
 > 	   (save-excursion
 > 	     (copy-to-buffer temp-buffer beg end)
 > 	     (set-buffer temp-buffer)
 > 	     (goto-char (point-min))
 > 	     (setq word (capitalize (buffer-string)))
 > 	     (message word)
 > 	     (when (member word (nth 2 poss)) t)
 > 	     ))) t)  ;;(when (re-search
 >       ((when (and (re-search-forward "-" (+ end 2) t) 
(re-search-backward
 > "s" (1- end) t))
 > 	 (when (consp poss)
 > 	   (setq temp-buffer (get-buffer-create " *flyspell-temp*"))
 > 	   (save-excursion
 > 	     (copy-to-buffer temp-buffer beg (1- end))
 > 	     (set-buffer temp-buffer)
 > 	     (goto-char (point-min))
 > 	     (setq word (capitalize (buffer-string)))
 > 	     (message word)
 > 	     (when (member word (nth 2 poss)) t)
 > 	     ))) t) ;; (when (and (re-search
 >       ))
 > <------------
 >
 > When I try the function without (cond) and with only one (when
 > (re-search ...) it works, but (cond ((when ...) t) ((when ...) t))
 > seems not to return nil as aspected, when both conditions fail. So no
 > word are considered incorrect.
 >
 > What is the error I made?

Do not use when.  Do not create global variables like temp-buffer and
word unnecessarily.  Remember that when re-search-* succeeds it moves
point, so if you want subsequent searches to start from the same point,
you need to wrap it in save-excursion.

Here's an attempt to clean up your code, without really understanding
it:

(defun flyspell-zusammen (beg end poss)
   "Better spell-checking for german combined words."
   ;; Where is point in relation to beg and end?
   (cond ((and (save-excursion (re-search-backward "\"-" (- beg 2) t))
               (consp poss)
               (let ((word (capitalize (buffer-substring beg end))))
                 (message word)
                 (member word (nth 2 poss)))))
         ((and (save-excursion (and (re-search-forward "-" (+ end 2) t)
                                    (re-search-backward "s" (1- end) t)))
               (consp poss)
               (let ((word (capitalize (buffer-substring beg (1- end)))))
                 (message word)
                 (member word (nth 2 poss)))))))

-- 
Kevin Rodgers

Re: elisp issues on (cond ((when ...) t) ((when) t))

[Thien-Thi Nguyen]

Sebastian Meisel <sebastianmeisel@web.de> writes:

> What is the error I made?

are you sure both branches fail?  did you check *Messages*?

are you sure your code behaves as if it were:

  (cond (nil t) (nil t))

?  eval that in *scratch* -- what do you see?  how about:

  (cond (nil t) (nil t) (t))
  (cond (nil t) (nil t) (nil))
  (cond (nil t) (nil t) (42))
  (cond (nil t) (nil t) (t 42))
  (cond (nil t) (nil t) (t nil))
  (cond (nil t) (nil t) (42 t))
  (cond (nil t) (nil t) (42 nil))
  (cond (nil t) (nil t) (42 42))
  (cond (nil t) (nil t) (42 42 42))

why stop with one error?  life's too short to be perfect...

thi