;;; dired-aux-tests.el --- Test suite for dired-aux. -*- lexical-binding: t -*-

;; Copyright (C) 2017 Free Software Foundation, Inc.

;; This file is part of GNU Emacs.

;; GNU Emacs is free software: you can redistribute it and/or modify
;; it under the terms of the GNU General Public License as published by
;; the Free Software Foundation, either version 3 of the License, or
;; (at your option) any later version.

;; GNU Emacs is distributed in the hope that it will be useful,
;; but WITHOUT ANY WARRANTY; without even the implied warranty of
;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
;; GNU General Public License for more details.

;; You should have received a copy of the GNU General Public License
;; along with GNU Emacs.  If not, see <https://www.gnu.org/licenses/>.

;;; Code:
(require 'ert)
(require 'dired-aux)


(ert-deftest dired-test-bug27496 ()
  "Test for https://debbugs.gnu.org/27496 ."
  (skip-unless (executable-find shell-file-name))
  (let* ((foo (make-temp-file "foo"))
         (files (list foo)))
    (unwind-protect
        (cl-letf (((symbol-function 'y-or-n-p) 'error))
          (dired temporary-file-directory)
          (dired-goto-file foo)
          ;; `dired-do-shell-command' returns nil on success.
          (should-error (dired-do-shell-command "ls ? ./?" nil files))
          (should-error (dired-do-shell-command "ls ./? ?" nil files))
          (should-not (dired-do-shell-command "ls ? ?" nil files))
          (should-error (dired-do-shell-command "ls * ./*" nil files))
          (should-not (dired-do-shell-command "ls * *" nil files))
          (should-not (dired-do-shell-command "ls ? ./`?`" nil files)))
      (delete-file foo))))

(ert-deftest dired-test-bug28834 ()
  "test for https://debbugs.gnu.org/28834 ."
  (let* ((from (make-temp-file "from"))
         (foo (make-temp-file "foo" 'dir))
         (bar (file-name-as-directory (expand-file-name "bar" foo)))
         (qux (file-name-as-directory (expand-file-name "qux" foo)))
         (tmpdir temporary-file-directory)
         (to-cp (expand-file-name "foo-cp" bar))
         (to-mv (expand-file-name "foo-mv" qux))
         (dired-create-destination-dirs 'always))
    (unwind-protect
        (progn
          (dired-copy-file-recursive from to-cp nil)
          (should (file-exists-p to-cp))
          (dired-rename-file from to-mv nil)
          (should (file-exists-p to-mv))
          ;; Repeat the same with `dired-create-destination-dirs' set to 'never.
          (dired-rename-file to-mv from nil)
          (delete-file to-cp)
          (delete-directory bar)
          (delete-directory qux)
          (let ((dired-create-destination-dirs 'never))
            (should-error (dired-copy-file-recursive from to-cp nil))
            (should-error (dired-rename-file from to-mv nil))))
      ;; clean up
      (delete-directory foo 'recursive)
      (delete-file from))))


(provide 'dired-aux-tests)
;; dired-aux-tests.el ends here