bug#33595: [PATCH] RE: bug#33595: 26; Have `try-completion' or `completion--done' run abnormal hook if sole completion

[Drew Adams <drew.adams@oracle.com>]

[-- Attachment #1: Type: text/plain, Size: 3484 bytes --]

The attached patch implements this enhancement.

Simple example use cases:

(defun my-find-file-other-window (filename &optional wildcards)
  "`find-file-other-window', but show file info if only one completion matches."
  (interactive
   (unwind-protect
       (progn
         (add-hook 'completion-sole-match-functions 'describe-file)
         (find-file-read-args "Find file in other window: "
                              (confirm-nonexistent-file-or-buffer)))
     (remove-hook 'completion-sole-match-functions 'describe-file)))
  (find-file-other-window filename wildcards))

(defun my-describe-function (function)
  "`describe-function', but show output if only one completion matches."
  (interactive
   (unwind-protect
       (progn
         (add-hook 'completion-sole-match-functions
                   (lambda (fn) (describe-function (intern fn))))
         (let* ((fn (function-called-at-point))
                (enable-recursive-minibuffers t)
                (val (completing-read
                      (if fn
                          (format "Describe function (default %s): " fn)
                        "Describe function: ")
                      #'help--symbol-completion-table
                      (lambda (f)
                        (or (fboundp f) (get f 'function-documentation)))
                      t nil nil
                      (and fn (symbol-name fn)))))
           (unless (equal val "")
             (setq fn (intern val)))
           (unless (and fn (symbolp fn))
             (user-error "You didn't specify a function symbol"))
           (unless (or (fboundp fn) (get fn 'function-documentation))
             (user-error "Symbol's function definition is void: %s" fn))
           (list fn))))
   (remove-hook 'completion-sole-match-functions
                (lambda (fn) (describe-function (intern fn)))))
  (describe-function function))

----

Or, using macro `with-hook-added' (see bug #33601):

(defun my-find-file-other-window (filename &optional wildcards)
  "`find-file-other-window', but show file info if only one completion matches."
  (interactive
   (with-hook-added completion-sole-match-functions
     describe-file
     (find-file-read-args "Find file in other window: "
                          (confirm-nonexistent-file-or-buffer))))
  (find-file-other-window filename wildcards))

(defun my-describe-function (function)
  "`describe-function', but show output if only one completion matches."
  (interactive
   (with-hook-added completion-sole-match-functions
     (lambda (fn) (describe-function (intern fn)))
     (let* ((fn (function-called-at-point))
            (enable-recursive-minibuffers t)
            (val (completing-read
                  (if fn
                      (format "Describe function (default %s): " fn)
                    "Describe function: ")
                  #'help--symbol-completion-table
                  (lambda (f)
                    (or (fboundp f) (get f 'function-documentation)))
                  t nil nil
                  (and fn (symbol-name fn)))))
       (unless (equal val "")
         (setq fn (intern val)))
       (unless (and fn (symbolp fn))
         (user-error "You didn't specify a function symbol"))
       (unless (or (fboundp fn) (get fn 'function-documentation))
         (user-error "Symbol's function definition is void: %s" fn))
       (list fn))))
  (describe-function function))

[-- Attachment #2: minibuffer-2018-12-03a.patch --]
[-- Type: application/octet-stream, Size: 1003 bytes --]

diff -u minibuffer.el minibuffer-2018-12-03a-patched.el
--- minibuffer.el	2018-12-03 09:23:45.858608200 -0800
+++ minibuffer-2018-12-03a-patched.el	2018-12-03 09:27:17.862397300 -0800
@@ -753,6 +753,10 @@
 the second failed attempt to complete."
   :type '(choice (const nil) (const t) (const lazy)))
 
+(defvar completion-sole-match-functions ()
+  "Functions to be run when completion results in only one match.
+Each function must accept that completion as its first arg.")
+
 (defconst completion-styles-alist
   '((emacs21
      completion-emacs21-try-completion completion-emacs21-all-completions
@@ -1769,6 +1773,8 @@
   (let* ((exit-fun (plist-get completion-extra-properties :exit-function))
          (pre-msg (and exit-fun (current-message))))
     (cl-assert (memq finished '(exact sole finished unknown)))
+    (when (eq finished 'finished)
+      (run-hook-with-args 'completion-sole-match-functions string))
     (when exit-fun
       (when (eq finished 'unknown)
         (setq finished