Re: How to restore the layout?

[martin rudalics <rudalics@gmx.at>]

 > I don't know whether minibuffer-less frames are unusual
 > (frequency-wise), but they are documented on the manual, and have
 > built-in support, so they should work (wrt saving&restoring) out of
 > the box.

The problem is what to do when we initially have a minibuffer-equipped
frame and the state we restore contains only minibuffer-less and
minibuffer-only frames.  In that case we'd have to delete the initial
frame :-(

 > We can add desktop-* frame parameters easily with all kind of
 > information we need (as long as it can be read back).

A first, untested stab is below: Frames get a desktop-mini parameter
which is a cons.  The car is t if the frame has a minibuffer and nil if
not.  For a t-car frame the cdr is its number.  For a nil-car frame cdr
t means use the default minibuffer frame and a number use the minibuffer
frame whose desktop-mini cdr has that number.

Now restoring the desktop has to scan the dekstop-mini parameters first:
If a t-car one is found, make the frame.  Next process the nil-car ones
and make them.  If it's got a number-cdr, find the frame with that
number in its desktop-mini cdr and set the minibuffer-window parameter
of the frame we just process to the minibuffer window of the frame we
have found.

But I'm not sure how to do handle the problem sketched above so I didn't
write the restoration part.

martin


(defun desktop--save-minibuffer-frames ()
   "Save window/frame state, as a global variable.
Intended to be called from `desktop-save'.
Internal use only."
   (let ((frame-list (frame-list))
	(count 0)
	minibuffer-window minibuffer-frame)
     (dolist (frame frame-list)
       ;; For all frames reset desktop-mini parameter if set.
       (when (frame-parameter frame 'desktop-mini)
	(set-frame-parameter frame 'desktop-mini nil)))

     (dolist (frame frame-list)
       ;; Set minibuffer-frame to this frame's minibuffer frame.
       (let ((minibuffer-frame (window-frame (minibuffer-window frame))))
	(cond
	 ;; Process minibuffer-window frame parameter if present.
	 ((and (setq minibuffer-window
		     (frame-parameter frame 'minibuffer-window))
	       (window-minibuffer-p minibuffer-window))
	  (setq minibuffer-frame (window-frame minibuffer-window))
	  (let ((default (eq minibuffer-frame default-minibuffer-frame))
		(this-count
		 (cdr (frame-parameter minibuffer-frame 'desktop-mini))))
	    (unless this-count
	      ;; Make desktop-mini entry for minibuffer frame.
	      (setq count (1+ count) this-count count)
	      (set-frame-parameter
	       minibuffer-frame 'desktop-mini (cons t count)))
	    ;; Make desktop-mini entry for frame processed.
	    (set-frame-parameter
	     frame 'desktop-mini (cons nil this-count))))
	 ;; Do nothig if we are our own minibuffer frame.
	 ((eq minibuffer-frame frame))
	 ;; Use default-minibuffer-frame otherwise.
	 (t
	  (let ((this-count (cdr (frame-parameter
				  default-minibuffer-frame 'desktop-mini))))
	    (unless this-count
	      ;; Make desktop-mini entry for minibuffer frame.
	      (setq count (1+ count) this-count count)
	      (set-frame-parameter
	       default-minibuffer-frame 'desktop-mini (cons t count)))
	    ;; Make desktop-mini entry for frame processed.
	    (set-frame-parameter frame 'desktop-mini (cons nil t)))))))))