bug#3142: 23.0.92; split-window-prefered-function should be able to use split-window-horizontally/split-window-vertically

[martin rudalics <rudalics@gmx.at>]

[-- Attachment #1: Type: text/plain, Size: 1332 bytes --]

 >> + (defcustom split-window-preferred-function 'split-selected-window
 >> +   "Function called by `display-buffer' to split a window.
 >> + The window that shall be split is selected when this function is
 >> + called.  The function is supposed to either return the new window
 >> + or nil if the window can (or shall) not be split."
 >> +   :type 'function
 >> +   :version "23.1"
 >> +   :group 'windows)
 >
 > If setting this option to `split-window-horizontally' and
 > `split-window-vertically' is possible and it works correctly
 > with these value, then I suggest adding them as constants,
 > e.g. "Always split horizontally" and "Always split vertically".

Done.  But note that a function like `split-window-vertically' is suited
for interactive use and thus may throw an error when the window is too
small.  I can't allow an error in `display-buffer' so I have to wrap
that call in a `condition-case'.

 > Also I suggest keeping the common function name prefix "split-window-",
 > i.e. instead of `split-selected-window' to name it something like
 > "split-window-sensibly" or "split-window-with-thresholds".

I've chosen `split-window-sensibly'.  It also calls
`split-window-vertically' and `split-window-horizontally' now.

Please try the new patch - we're in pretest and I don't want to take too
many chances.

martin

[-- Attachment #2: window.el.diff --]
[-- Type: text/plain, Size: 6656 bytes --]

*** window.el.~1.179.~	2009-04-29 07:50:42.078125000 +0200
--- window.el	2009-05-01 10:19:20.625000000 +0200
***************
*** 794,832 ****
    :type 'boolean
    :group 'windows)
  
  (defcustom split-height-threshold 80
    "Minimum height of window to be split vertically.
! If the value is a number, `display-buffer' can split a window
! only if it has at least as many lines.  If the value is nil,
! `display-buffer' cannot split a window vertically.
! 
! If the window is the only window on its frame, `display-buffer'
! can split it regardless of this value."
    :type '(choice (const nil) (number :tag "lines"))
    :version "23.1"
    :group 'windows)
  
  (defcustom split-width-threshold 160
    "Minimum width of window to be split horizontally.
! If the value is a number, `display-buffer' can split a window
! only if it has at least as many columns.  If the value is nil,
! `display-buffer' cannot split a window horizontally."
    :type '(choice (const nil) (number :tag "columns"))
    :version "23.1"
    :group 'windows)
  
- (defcustom split-window-preferred-function nil
-   "Function used by `display-buffer' to split windows.
- If non-nil, a function called with a window as single argument
- supposed to split that window and return the new window.  If the
- function returns nil the window is not split.
- 
- If nil, `display-buffer' will split the window respecting the
- values of `split-height-threshold' and `split-width-threshold'."
-   :type '(choice (const nil) (function :tag "Function"))
-   :version "23.1"
-   :group 'windows)
- 
  (defun window--splittable-p (window &optional horizontal)
    "Return non-nil if WINDOW can be split evenly.
  Optional argument HORIZONTAL non-nil means check whether WINDOW
--- 794,831 ----
    :type 'boolean
    :group 'windows)
  
+ (defcustom split-window-preferred-function 'split-window-sensibly
+   "Function called by `display-buffer' to split a window.
+ The window that shall be split is selected when this function is
+ called.  The function is supposed to either return the new window
+ or nil if the window can (or shall) not be split."
+   :type '(choice
+ 	  (function :tag "Function")
+ 	  (const :tag "Split vertically" split-window-vertically)
+ 	  (const :tag "Split horizontally" split-window-horizontally))
+   :version "23.1"
+   :group 'windows)
+ 
  (defcustom split-height-threshold 80
    "Minimum height of window to be split vertically.
! If the value is a number, `split-window-sensibly' splits a window
! vertically only if it has at least as many lines.  If the value
! is nil, it does not split a window vertically.  If a window is
! the only window on its frame, it can be split regardless of the
! value of this variable."
    :type '(choice (const nil) (number :tag "lines"))
    :version "23.1"
    :group 'windows)
  
  (defcustom split-width-threshold 160
    "Minimum width of window to be split horizontally.
! If the value is a number, `split-window-sensibly' splits a window
! only if it has at least as many columns.  If the value is nil, it
! does not split a window horizontally."
    :type '(choice (const nil) (number :tag "columns"))
    :version "23.1"
    :group 'windows)
  
  (defun window--splittable-p (window &optional horizontal)
    "Return non-nil if WINDOW can be split evenly.
  Optional argument HORIZONTAL non-nil means check whether WINDOW
***************
*** 882,911 ****
  		      (* 2 (max window-min-height
  				(if mode-line-format 2 1))))))))))
  
  (defun window--try-to-split-window (window)
!   "Split WINDOW if it is splittable.
! See `window--splittable-p' for how to determine whether a window
! is splittable.  If WINDOW can be split, return the value returned
! by `split-window' (or `split-window-preferred-function')."
!   (when (and (window-live-p window)
! 	     (not (frame-parameter (window-frame window) 'unsplittable)))
!     (if (functionp split-window-preferred-function)
! 	;; `split-window-preferred-function' is specified, so use it.
! 	(funcall split-window-preferred-function window)
!       (or (and (window--splittable-p window)
! 	       ;; Split window vertically.
! 	       (split-window window))
! 	  (and (window--splittable-p window t)
! 	       ;; Split window horizontally.
! 	       (split-window window nil t))
! 	  (and (eq window (frame-root-window (window-frame window)))
! 	       (not (window-minibuffer-p window))
! 	       ;; If WINDOW is the only window on its frame and not the
! 	       ;; minibuffer window, attempt to split it vertically
! 	       ;; disregarding the value of `split-height-threshold'.
! 	       (let ((split-height-threshold 0))
! 		 (and (window--splittable-p window)
! 		      (split-window window))))))))
  
  (defun window--frame-usable-p (frame)
    "Return FRAME if it can be used to display a buffer."
--- 881,922 ----
  		      (* 2 (max window-min-height
  				(if mode-line-format 2 1))))))))))
  
+ (defun split-window-sensibly ()
+   "\"Sensibly\" split the selected window.
+ Split selected window vertically or horizontally respecting the
+ values of `split-height-threshold' and `split-width-threshold'.
+ If the selected window is the only window on its frame, it may be
+ split disregarding the value of `split-height-threshold'.  If the
+ window can be split, return the new window, nil otherwise.
+ 
+ The default value of `split-window-preferred-function' is set to
+ this function."
+   (or (and (window--splittable-p (selected-window))
+ 	   ;; Split window vertically.
+ 	   (split-window-vertically))
+       (and (window--splittable-p (selected-window) t)
+ 	   ;; Split window horizontally.
+ 	   (split-window-horizontally))
+       (and (eq (selected-window) (frame-root-window))
+ 	   (not (window-minibuffer-p))
+ 	   ;; If the selected window is the only window on its frame and
+ 	   ;; is not the minibuffer window, try to split it vertically
+ 	   ;; disregarding the value of `split-height-threshold'.
+ 	   (let ((split-height-threshold 0))
+ 	     (and (window--splittable-p (selected-window))
+ 		  (split-window-vertically))))))
+ 
  (defun window--try-to-split-window (window)
!   "Split WINDOW if it can be split.
! Return value returned by `split-window-preferred-function'."
!   ;; Use `condition-case' since `split-window-preferred-function' might
!   ;; throw an error.
!   (condition-case nil
!       (and (window-live-p window)
! 	   (not (frame-parameter (window-frame window) 'unsplittable))
! 	   (with-selected-window window
! 	     (funcall split-window-preferred-function)))
!     (error nil)))
  
  (defun window--frame-usable-p (frame)
    "Return FRAME if it can be used to display a buffer."