problems with save-excursion

problems with save-excursion

[filcab]

I have the following function:
(defun copy-line ()
   (interactive)
   (save-excursion
      (beginning-of-line)
      (set-mark-command)
      (end-of-line)
      (copy-region-as-kill)))

But it's not working...
It says:
save-excursion: Wrong number of arguments: #[(arg) ... (some trash)


Any clues?

Re: problems with save-excursion

[Katsumi Yamaoka]

>>>>> In <1141857397.880352.44860@u72g2000cwu.googlegroups.com>
>>>>>	filcab@gmail.com wrote:

> I have the following function:
> (defun copy-line ()
>    (interactive)
>    (save-excursion
>       (beginning-of-line)
>       (set-mark-command)
>       (end-of-line)
>       (copy-region-as-kill)))

> But it's not working...
> It says:
> save-excursion: Wrong number of arguments: #[(arg) ... (some trash)

You can modify it to work as follows:

(defun copy-line ()
   (interactive)
   (save-excursion
      (beginning-of-line)
      (call-interactively 'set-mark-command)
      (end-of-line)
      (call-interactively 'copy-region-as-kill)))

If you wish only to copy a line, it can be simplified as follows:

(defun copy-line ()
  (interactive)
  (kill-new
   (buffer-substring (line-beginning-position)
		     (line-end-position))))

Re: problems with save-excursion

[bhenz]

[-- Attachment #1.1: Type: text/plain, Size: 758 bytes --]

I believe it's actually complaining about your usage of (interactive) 
without ARGS.

Bob





filcab@gmail.com
Sent by: help-gnu-emacs-bounces+bhenz=lexmark.com@gnu.org
03/08/2006 05:36 PM

 
        To:     help-gnu-emacs@gnu.org
        cc: 
        Subject:        problems with save-excursion


I have the following function:
(defun copy-line ()
   (interactive)
   (save-excursion
      (beginning-of-line)
      (set-mark-command)
      (end-of-line)
      (copy-region-as-kill)))

But it's not working...
It says:
save-excursion: Wrong number of arguments: #[(arg) ... (some trash)


Any clues?

_______________________________________________
help-gnu-emacs mailing list
help-gnu-emacs@gnu.org
http://lists.gnu.org/mailman/listinfo/help-gnu-emacs



[-- Attachment #1.2: Type: text/html, Size: 1574 bytes --]

[-- Attachment #2: Type: text/plain, Size: 152 bytes --]

_______________________________________________
help-gnu-emacs mailing list
help-gnu-emacs@gnu.org
http://lists.gnu.org/mailman/listinfo/help-gnu-emacs

Re: problems with save-excursion

[Eli Zaretskii]

> From: filcab@gmail.com
> Date: 8 Mar 2006 14:36:37 -0800
> 
> I have the following function:
> (defun copy-line ()
>    (interactive)
>    (save-excursion
>       (beginning-of-line)
>       (set-mark-command)
>       (end-of-line)
>       (copy-region-as-kill)))
> 
> But it's not working...
> It says:
> save-excursion: Wrong number of arguments: #[(arg) ... (some trash)

It complains about the use of copy-region-as-kill" that function needs
to receive two arguments.  See its doc string for the details.

Re: problems with save-excursion

[Marc Tfardy]

filcab@gmail.com schrieb:
> I have the following function:
> (defun copy-line ()
>    (interactive)
>    (save-excursion
>       (beginning-of-line)
>       (set-mark-command)
>       (end-of-line)
>       (copy-region-as-kill)))
> 
> But it's not working...
> It says:
> save-excursion: Wrong number of arguments: #[(arg) ... (some trash)
> 
> 
> Any clues?

You may try:

(defun copy-line ()
   (interactive)
   (save-excursion
     (let (beg)
       (beginning-of-line)
       (setq beg (point))
       (end-of-line)
       (copy-region-as-kill beg (point)))))


regards

Marc

Re: problems with save-excursion

[Marc Tfardy]

Marc Tfardy schrieb:
> filcab@gmail.com schrieb:
>> I have the following function:
>> (defun copy-line ()
>>    (interactive)
>>    (save-excursion
>>       (beginning-of-line)
>>       (set-mark-command)
>>       (end-of-line)
>>       (copy-region-as-kill)))
>>
>> But it's not working...
>> It says:
>> save-excursion: Wrong number of arguments: #[(arg) ... (some trash)
>>
>>
>> Any clues?
> 
> You may try:
> 
> (defun copy-line ()
>   (interactive)
>   (save-excursion
>     (let (beg)
>       (beginning-of-line)
>       (setq beg (point))
>       (end-of-line)
>       (copy-region-as-kill beg (point)))))
> 

Second and shorter version:

(defun copy-line ()
   (interactive)
   (copy-region-as-kill (line-beginning-position)
                        (line-end-position)))


Marc

Re: problems with save-excursion

[Kevin Rodgers]

bhenz@Lexmark.com wrote:
> I believe it's actually complaining about your usage of (interactive) 
> without ARGS.

Why do you believe that?  `C-h f interactive' says:

	Just `(interactive)' means pass no args when calling interactively.

And the containing function's lambda list is indeed empty.

-- 
Kevin Rodgers

Re: problems with save-excursion

[Stefan Monnier]

> (defun copy-line ()
>   (interactive)
>   (save-excursion
>     (let (beg)
>       (beginning-of-line)
>       (setq beg (point))
>       (end-of-line)
>       (copy-region-as-kill beg (point)))))

It's a good habit to initialize your variables directly when you declare
them (in C-style languages as well, BTW):

 (defun copy-line ()
   (interactive)
   (save-excursion
     (beginning-of-line)
     (let ((beg (point)))
       (end-of-line)
       (copy-region-as-kill beg (point)))))

In elisp it's also marginally more efficient.


        Stefan

Re: problems with save-excursion

[Peter Lee]

>>>> filcab  writes:

    >> I have the following function:
    >> (defun copy-line ()
    >>    (interactive)
    >>    (save-excursion
    >>       (beginning-of-line)
    >>       (set-mark-command)
    >>       (end-of-line)
    >>       (copy-region-as-kill)))

    >> But it's not working...

you could do:

(defun copy-line ()
  (interactive)
  (kill-new (thing-at-point 'line)))