More conventient move beginning/end of line

More conventient move beginning/end of line

[Lennart Borgman (gmail)]

Some editor I used long ago had some behaviour similar to the functions 
below. One press on HOME moved to the beginning of line, next to the 
start of the text on that line. It would be nice to have this in Emacs 
(maybe the ARG part should be skipped):

(defun my-move-beginning-of-line(arg)
   (interactive "p")
   (or arg (setq arg 1))
   (let ((pos (point)))
     (move-beginning-of-line arg)
     (when (= pos (point)) (skip-chars-forward " \t"))))
(put 'my-move-beginning-of-line 'CUA 'move)
(global-set-key [home] 'my-move-beginning-of-line)

(defun my-move-end-of-line(arg)
   (interactive "p")
   (or arg (setq arg 1))
   (let ((pos (point)))
     (move-end-of-line arg)
     (when (= pos (point)) (skip-chars-backward " \t"))))
(put 'my-move-end-of-line 'CUA 'move)
(global-set-key [end] 'my-move-end-of-line)

Re: More conventient move beginning/end of line

[Thien-Thi Nguyen]

() "Lennart Borgman (gmail)" <lennart.borgman@gmail.com>
() Sat, 22 Sep 2007 03:03:14 +0200

   (defun my-move-beginning-of-line(arg) ...)
   (defun my-move-end-of-line(arg) ...)

see also codeline.el, reachable via
<http://www.gnuvola.org/software/personal-elisp/index.html>

thi

Re: More conventient move beginning/end of line

[Davis Herring]

> Some editor I used long ago had some behaviour similar to the functions
> below. One press on HOME moved to the beginning of line, next to the
> start of the text on that line. It would be nice to have this in Emacs
> (maybe the ARG part should be skipped):

I use these very similar functions.  They use the prefix arg to force the
normal behavior (although I just use C-a and C-e, which I don't rebind,
when I want to avoid these).  They also have "bad" docstrings, of course. 
The important difference is that the end-of-line replacement moves back
before up to one comment and whitespace if repeated.

(defun maybe-beginning-of-line (ARG)
  "Move point to beginning of current line, or to beginning of text
after indentation if already there.  With ARG non-nil, acts as
`move-beginning-of-line'."
  (interactive "P")
  (if (and (bolp) (null ARG)) (back-to-indentation)
    (move-beginning-of-line ARG)))

(defun maybe-end-of-line (ARG)
  "Move point to end of current line, or to end of text before any comment
if already there.  With ARG non-nil, acts as `move-end-of-line'."
  (interactive "P")
  (if (and (eolp) (null ARG))
      (let* ((opoint (point))
             (bpoint (line-beginning-position)))
        ;; `forward-char' is dumb, but not all modes use ?< syntax.
        (while (< (point-after (forward-comment 1)) opoint)
          (skip-syntax-forward " ")
          (forward-char))
        (skip-syntax-backward " " bpoint)
        ;; If there's nothing but a comment, move back to its start.
        (when (bolp) (skip-syntax-forward " " opoint)))
    (move-end-of-line ARG)))

Davis

-- 
This product is sold by volume, not by mass.  If it appears too dense or
too sparse, it is because mass-energy conversion has occurred during
shipping.