Disabling show-wspace for a specific mode or buffer

Disabling show-wspace for a specific mode or buffer

[Valera Rozuvan]

Hi!

I am using the package show-wspace (
http://www.emacswiki.org/emacs/show-wspace.el ) to visually show
trailing whitespace and tab characters in all my files. I achieve this
by adding the following line to the ~/.emacs file:

(add-to-list 'load-path "~/.emacs.d/") ;; show-wspace.el can be found here
(require 'show-wspace)

(add-hook 'font-lock-mode-hook 'show-ws-highlight-tabs)
(add-hook 'font-lock-mode-hook 'show-ws-highlight-trailing-whitespace)

My problem is that in 99% of buffers I want this behavior, but
sometimes I don't. For example, when I run the command M-x w3m to
browse the web, I don't want to see trailing whitespace highlighted.
Can anyone suggest a solution for this problem?

Regards,
Valera Rozuvan

Re: Disabling show-wspace for a specific mode or buffer

[Alp Aker]

> I am using the package show-wspace
>
> (add-hook 'font-lock-mode-hook 'show-ws-highlight-tabs)
> (add-hook 'font-lock-mode-hook 'show-ws-highlight-trailing-whitespace)
>
> My problem is that in 99% of buffers I want this behavior, but
> sometimes I don't.
>
> Can anyone suggest a solution for this problem?

Does this work?  (Untested.)

(add-hook 'w3m-mode-hook 'show-ws-dont-highlight-trailing-whitespace)
(add-hook 'w3m-mode-hook 'show-ws-dont-highlight-tabs)

Re: Disabling show-wspace for a specific mode or buffer

[Valera Rozuvan]

On Wed, Jun 27, 2012 at 11:01 PM, Alp Aker <alptekin.aker@gmail.com> wrote:
> Does this work?  (Untested.)
>
> (add-hook 'w3m-mode-hook 'show-ws-dont-highlight-trailing-whitespace)
> (add-hook 'w3m-mode-hook 'show-ws-dont-highlight-tabs)

Hi Alp,

I added your add-hook statements, restarted emacs, but when I open w3m
they appear to have no effect. Also when I run the command

M-x show-ws-dont-highlight-trailing-whitespace

Nothing happens, and "[No match]" is inserted at the end of the mini buffer.

Thanks,
Valera Rozuvan

RE: Disabling show-wspace for a specific mode or buffer

[Drew Adams]

> I am using the package show-wspace (
> http://www.emacswiki.org/emacs/show-wspace.el ) to visually show
> trailing whitespace and tab characters in all my files. I achieve this
> by adding the following line to the ~/.emacs file:
> 
> (add-to-list 'load-path "~/.emacs.d/") ;; show-wspace.el can 
> be found here
> (require 'show-wspace)
> 
> (add-hook 'font-lock-mode-hook 'show-ws-highlight-tabs)
> (add-hook 'font-lock-mode-hook 'show-ws-highlight-trailing-whitespace)
> 
> My problem is that in 99% of buffers I want this behavior, but
> sometimes I don't. For example, when I run the command M-x w3m to
> browse the web, I don't want to see trailing whitespace highlighted.
> Can anyone suggest a solution for this problem?

Sorry, but there is no simple way to do that.  But you can do it in this
roundabout way (ugly!):

(add-hook 'change-major-mode-hook
          (lambda ()
            (add-hook 'font-lock-mode-hook
                      'show-ws-highlight-trailing-whitespace)))

(add-hook 'after-change-major-mode-hook
          (lambda ()
            (when (eq major-mode 'THE-MODE)
              (remove-hook 'font-lock-mode-hook
                           'show-ws-highlight-trailing-whitespace)
              (show-ws-dont-highlight-trailing-whitespace)))
          'append)

where THE-MODE is the mode of the buffer where you do not want the highlighting.

It's an old library - the code should probably be rewritten to define a minor
mode (and a globalized version of it).

Re: Disabling show-wspace for a specific mode or buffer

[Alp Aker]

> I added your add-hook statements, restarted emacs, but when I open w3m
> they appear to have no effect.

Did you add them to your .emacs *after* you load w3?  You could also
try this (it's overkill, but might work):

(add-hook 'w3m-fontify-before-hook
'show-ws-dont-highlight-trailing-whitespace)

Again, this is untested, as w3m breaks my setup, so I'm just looking
at the sources.

> Also when I run the command
>
> M-x show-ws-dont-highlight-trailing-whitespace
>
> Nothing happens, and "[No match]" is inserted at the end of the mini buffer.

Correct:  show-ws-dont-highlight-trailing-whitespace is not an
interactive command, so you can't invoke it that way.  You could
redefine it by placing the following in your .emacs (after you load
show-wspace):

(defun show-ws-dont-highlight-trailing-whitespace ()
  "Don't highlight whitespace characters at line ends."
  (interactive)
  (when (fboundp 'font-lock-remove-keywords)
    (font-lock-remove-keywords
     nil '(("[\240\040\t]+$" (0 'show-ws-trailing-whitespace t)))))
  (when (called-interactively-p 'any)
    (font-lock-fontify-buffer)))

and then it can be invoked via

  M-x show-ws-dont-highlight-trailing-whitespace

Re: Disabling show-wspace for a specific mode or buffer

[Alp Aker]

On Wed, Jun 27, 2012 at 4:31 PM, Alp Aker <alptekin.aker@gmail.com> wrote:

> Did you add them to your .emacs *after* you load w3?

Actually, that's not important.  But try Drew's suggestion, or my
other suggestion.

Re: Disabling show-wspace for a specific mode or buffer

[Valera Rozuvan]

> Actually, that's not important.  But try Drew's suggestion, or my
> other suggestion.

Thanks for your replies! I have modified your suggestions, and came up
with the following:

(defun show-ws-dont-highlight-trailing-whitespace ()
    "Don't highlight whitespace characters at line ends."
    (interactive)
    (when (fboundp 'font-lock-remove-keywords)
        (font-lock-remove-keywords
            nil '(("[\240\040\t]+$" (0 'show-ws-trailing-whitespace t)))))
    (when (called-interactively-p 'any)
        (font-lock-fontify-buffer)))

(defun show-ws-highlight-trailing-whitespace ()
    "Highlight whitespace characters at line ends."
    (interactive)
    (font-lock-add-keywords
        nil '(("[\240\040\t]+$" (0 'show-ws-trailing-whitespace t))))
    (when (called-interactively-p 'any)
        (font-lock-fontify-buffer)))

(global-set-key (kbd "<f11>") 'show-ws-dont-highlight-trailing-whitespace)
(global-set-key (kbd "<f12>") 'show-ws-highlight-trailing-whitespace)

Now when I press F11 - the highlighting is turned off (F12 turns it
back on). I believe that this approach is the best for me because I
don't have to hard code into ~/.emacs the modes for which I want to
disable the highlighting functionality.

Thanks,
Valera Rozuvan

RE: Disabling show-wspace for a specific mode or buffer

[Drew Adams]

> (global-set-key (kbd "<f11>") 
> 'show-ws-dont-highlight-trailing-whitespace)
> (global-set-key (kbd "<f12>") 'show-ws-highlight-trailing-whitespace)
> 
> Now when I press F11 - the highlighting is turned off (F12 turns it
> back on). I believe that this approach is the best for me because I
> don't have to hard code into ~/.emacs the modes for which I want to
> disable the highlighting functionality.

I thought you wanted to leave it off for specific modes (you mentioned w3m),
which is what my suggestion does.

If instead you just want to hit a key to turn it on/off, all you need to do is
bind `show-ws-toggle-show-trailing-whitespace' to a (single) key - that's what
it's for:

(global-set-key (kbd "<f11>")
                'show-ws-toggle-show-trailing-whitespace)

Re: Disabling show-wspace for a specific mode or buffer

[Valera Rozuvan]

> I thought you wanted to leave it off for specific modes (you mentioned w3m),
> which is what my suggestion does.

I am just experimenting - and for now looking for the best possible solutions.

> If instead you just want to hit a key to turn it on/off, all you need to do is
> bind `show-ws-toggle-show-trailing-whitespace' to a (single) key - that's what
> it's for:
>
> (global-set-key (kbd "<f11>")
>                'show-ws-toggle-show-trailing-whitespace)

Thanks for the suggestion. But the command
show-ws-toggle-show-trailing-whitespace initially assumes that the
highlighting is OFF. I, on the other hand, from the start turn ON the
highlighting everywhere with the command:

(add-hook 'font-lock-mode-hook 'show-ws-highlight-trailing-whitespace)

So, with your suggestion, I have to press F11 twice to actually tun
OFF highlighting. And also I am not sure if
show-ws-toggle-show-trailing-whitespace works just with the buffer, or
if it is a global toggle.

Regards,
Valera Rozuvan

RE: Disabling show-wspace for a specific mode or buffer

[Drew Adams]

> Thanks for the suggestion. But the command
> show-ws-toggle-show-trailing-whitespace initially assumes that the
> highlighting is OFF.

No, it doesn't assume on or off.  It just toggles whatever the state is.

> I, on the other hand, from the start turn ON the
> highlighting everywhere with the command:
> (add-hook 'font-lock-mode-hook 'show-ws-highlight-trailing-whitespace)
> So, with your suggestion, I have to press F11 twice to actually tun
> OFF highlighting. 

So add this: (setq show-ws-highlight-trailing-whitespace-p t)

> And also I am not sure if
> show-ws-toggle-show-trailing-whitespace works just with the buffer, or
> if it is a global toggle.

It is global.  For that your commands are better for what you want.

Re: Disabling show-wspace for a specific mode or buffer

[Michael Heerdegen]

"Drew Adams" <drew.adams@oracle.com> writes:

> > (add-hook 'font-lock-mode-hook 'show-ws-highlight-tabs)
> > (add-hook 'font-lock-mode-hook 'show-ws-highlight-trailing-whitespace)
> > 
> > My problem is that in 99% of buffers I want this behavior, but
> > sometimes I don't. For example, when I run the command M-x w3m to
> > browse the web, I don't want to see trailing whitespace highlighted.
> > Can anyone suggest a solution for this problem?
>
> Sorry, but there is no simple way to do that.  But you can do it in this
> roundabout way (ugly!):
>
> (add-hook 'change-major-mode-hook
>           (lambda ()
>             (add-hook 'font-lock-mode-hook
>                       'show-ws-highlight-trailing-whitespace)))
>
> (add-hook 'after-change-major-mode-hook
>           (lambda ()
>             (when (eq major-mode 'THE-MODE)
>               (remove-hook 'font-lock-mode-hook
>                            'show-ws-highlight-trailing-whitespace)
>               (show-ws-dont-highlight-trailing-whitespace)))
>           'append)

Maybe an alternative approach would be to add the highlighting functions
to the text-mode-hook:

(add-hook 'text-mode-hook 'show-ws-highlight-tabs)
(add-hook 'text-mode-hook 'show-ws-highlight-trailing-whitespace)

Since most editing modes run `text-mode-hook', and other modes don't,
maybe this way you can get along with less exceptions?  Just an idea.


Michael.

Re: Disabling show-wspace for a specific mode or buffer

[John Wiegley]

>>>>> Valera Rozuvan <valera.rozuvan@gmail.com> writes:

> I am using the package show-wspace (
> http://www.emacswiki.org/emacs/show-wspace.el ) to visually show
> trailing whitespace and tab characters in all my files.

FWIW- M-x whitespace-mode does this exact same thing, is highly configurable,
can even cleanup whitespace issues, and comes with Emacs 24.

John