From: Peter Dyballa <Peter_Dyballa@Web.DE>
To: Drew Adams <drew.adams@oracle.com>
Cc: help-gnu-emacs@gnu.org, 'Fan' <gnu.emacs.fan@gmail.com>
Subject: Re: Need Help on Whitespace-mode in Emacs 24.1.1
Date: Sun, 26 Aug 2012 17:57:03 +0200 [thread overview]
Message-ID: <44668232-D1E0-4CBC-BDCA-C401D4263B25@Web.DE> (raw)
In-Reply-To: <C420DA22B20A4480AA0A0932031AA349@us.oracle.com>
Am 26.08.2012 um 17:17 schrieb Drew Adams:
> I've just posted my version on Emacs Wiki, as font-menus-da.el. But I will
> probably tweak it a bit more today.
The output is a list of XLFD names – do they enable GNU Emacs 24 to load these fonts via libfontconfig (and not via the X server), apply libotf and libm17n-* to get full font support and complex type layout? If not, than the fontconfig names (and features as if from fc-list/fc-match) would be a better choice.
And another output could be possible, that from this function by Miles Bader:
;;; ----------------------------------------------------------------
;;; list-fonts-display via font-config
(defun list-fonts-display (&optional matching)
"Display a list of font-families available via font-config, in a new buffer.
If the optional argument MATCHING is non-nil, only font families
matching that regexp are displayed; interactively, a prefix
argument will prompt for the regexp.
The name of each font family is displayed using that family, as
well as in the default font (to handle the case where a font
cannot be used to display its own name)."
(interactive
(list
(and current-prefix-arg
(read-string "Display font families matching regexp: "))))
(let (families)
(with-temp-buffer
(shell-command "fc-list : family" t)
(goto-char (point-min))
(while (not (eobp))
(let ((fam (buffer-substring (line-beginning-position)
(line-end-position))))
(when (or (null matching) (string-match matching fam))
(push fam families)))
(forward-line)))
(setq families
(sort families
(lambda (x y) (string-lessp (downcase x) (downcase y)))))
(let ((buf (get-buffer-create "*Font Families*")))
(with-current-buffer buf
(erase-buffer)
(dolist (family families)
;; We need to pick one of the comma-separated names to
;; actually use the font; choose the longest one because some
;; fonts have ambiguous general names as well as specific
;; ones.
(let ((family-name
(car (sort (split-string family ",")
(lambda (x y) (> (length x) (length y))))))
(nice-family (replace-regexp-in-string "," ", " family)))
(insert (concat (propertize nice-family
'face (list :family family-name))
" (" nice-family ")"))
(newline)))
(goto-char (point-min)))
(display-buffer buf))))
;; --------------------------------------------------------
--
Greetings
Pete
No project was ever completed on time and within budget.
– Cheops Law
next prev parent reply other threads:[~2012-08-26 15:57 UTC|newest]
Thread overview: 11+ messages / expand[flat|nested] mbox.gz Atom feed top
2012-08-26 3:15 Need Help on Whitespace-mode in Emacs 24.1.1 Fan
2012-08-26 8:17 ` Peter Dyballa
[not found] ` <mailman.7595.1345969075.855.help-gnu-emacs@gnu.org>
2012-08-26 14:46 ` Fan
2012-08-26 15:04 ` Peter Dyballa
2012-08-26 15:17 ` Drew Adams
2012-08-26 15:57 ` Peter Dyballa [this message]
2012-08-26 16:20 ` Drew Adams
2012-08-26 16:22 ` Drew Adams
[not found] ` <mailman.7604.1345994243.855.help-gnu-emacs@gnu.org>
2012-08-26 22:45 ` Fan
2012-08-26 22:54 ` Drew Adams
2012-08-26 23:31 ` Drew Adams
Reply instructions:
You may reply publicly to this message via plain-text email
using any one of the following methods:
* Save the following mbox file, import it into your mail client,
and reply-to-all from there: mbox
Avoid top-posting and favor interleaved quoting:
https://en.wikipedia.org/wiki/Posting_style#Interleaved_style
* Reply using the --to, --cc, and --in-reply-to
switches of git-send-email(1):
git send-email \
--in-reply-to=44668232-D1E0-4CBC-BDCA-C401D4263B25@Web.DE \
--to=peter_dyballa@web.de \
--cc=drew.adams@oracle.com \
--cc=gnu.emacs.fan@gmail.com \
--cc=help-gnu-emacs@gnu.org \
/path/to/YOUR_REPLY
https://kernel.org/pub/software/scm/git/docs/git-send-email.html
* If your mail client supports setting the In-Reply-To header
via mailto: links, try the mailto: link
Be sure your reply has a Subject: header at the top and a blank line
before the message body.
Code repositories for project(s) associated with this external index
https://git.savannah.gnu.org/cgit/emacs.git
https://git.savannah.gnu.org/cgit/emacs/org-mode.git
This is an external index of several public inboxes,
see mirroring instructions on how to clone and mirror
all data and code used by this external index.