incorrect button highlighting

incorrect button highlighting

[Dan Nicolaescu]

Evaluate this code:

(require 'cus-edit)

(defvar my-button-list 
  '((push-button
     :tag "prev"
     :help-echo "prev"
     :tag-glyph "prev-node"
     :action (lambda (widget &optional e) (ding)))
    (push-button
     :tag "next"
     :help-echo "next"
     :tag-glyph "next-node"
     :action (lambda (widget &optional e) (ding)))))

(defun test-buttons ()
  (interactive)
  (set (make-local-variable 'widget-button-pressed-face)
  custom-button-pressed)
  (mapc (lambda (arg) (widget-create arg)) my-button-list)
  (widget-setup))


And then do M-x test-buttons RET

No put the mouse over one of the 2 buttons that appear, and both will
be shown using the custom-button-pressed face instead of just the one
that is under the mouse cursor. 

Can someone please take a look at this? 

Thanks

        --dan

Re: incorrect button highlighting

[Glenn Morris]

Dan Nicolaescu wrote:

> No put the mouse over one of the 2 buttons that appear, and both will
> be shown using the custom-button-pressed face instead of just the one
> that is under the mouse cursor. 

I think this is a documented limitation of the widget library. From
the "User Interface" section of the widget manual:

    *Warning:* In an `editable-field' widget, the editable field must
    not be adjacent to another widget--that won't work. You must put
    some text in between. Either make this text part of the
    `editable-field' widget itself, or insert it with `widget-insert'.

Admittedly, I don't really see that your example is an "editable
field" one, but if you try:

(require 'cus-edit)
(defun foo ()
  (interactive)
  (switch-to-buffer "*Widget Example*")
  (set (make-local-variable 'widget-button-pressed-face) custom-button-pressed)
  (widget-create 'push-button
                 :tag "prev"
                 :help-echo "prev"
                 :tag-glyph "prev-node"
                 :action (lambda (widget &optional e) (ding)))
  (insert " ")
  (widget-create 'push-button
                 :tag "next"
                 :help-echo "next"
                 :tag-glyph "next-node"
                 :action (lambda (widget &optional e) (ding)))
  (widget-setup))

M-x foo

then it works ok if you insert a space between the two widgets, but
not if you don't.

Re: incorrect button highlighting

[Glenn Morris]

Glenn Morris wrote:

> I think this is a documented limitation of the widget library.

Actually, it's nothing to do with widgets. This has the same symptoms:

(progn
  (switch-to-buffer "*example*")
  (insert-image (create-image "prev-node.xpm")
                (propertize "prev" 'mouse-face 'custom-button-pressed-face))
  (insert-image (create-image "next-node.xpm")
                (propertize "next" 'mouse-face 'custom-button-pressed-face)))

Re: incorrect button highlighting

[Stephen Berman]

On Thu, 20 Sep 2007 04:05:03 -0400 Glenn Morris <rgm@gnu.org> wrote:

> Glenn Morris wrote:
>
>> I think this is a documented limitation of the widget library.
>
> Actually, it's nothing to do with widgets. This has the same symptoms:
>
> (progn
>   (switch-to-buffer "*example*")
>   (insert-image (create-image "prev-node.xpm")
>                 (propertize "prev" 'mouse-face 'custom-button-pressed-face))
>   (insert-image (create-image "next-node.xpm")
>                 (propertize "next" 'mouse-face 'custom-button-pressed-face)))

It appears to be due to using the same face symbol consecutively.
Compare the following: 

(progn
  (copy-face 'custom-button-pressed 'copy-button-pressed)
  (switch-to-buffer "*example*")
  (insert-image (create-image "prev-node.xpm")
                (propertize "prev" 'mouse-face 'highlight))
  (insert-image (create-image "next-node.xpm")
                (propertize "next" 'mouse-face 'highlight))
  (insert-image (create-image "prev-node.xpm")
                (propertize "prev" 'mouse-face 'copy-button-pressed))
  (insert-image (create-image "next-node.xpm")
                (propertize "next" 'mouse-face 'custom-button-pressed)))

The first two images, both with the highlight face, show the problem,
the second two, with different face symbols but identical face
definitions, show the face independently, as they should.

Steve Berman

Re: incorrect button highlighting

[Stefan Monnier]

>> I think this is a documented limitation of the widget library.

I think it's a bug in the widget library.

> Actually, it's nothing to do with widgets. This has the same symptoms:

> (progn
>   (switch-to-buffer "*example*")
>   (insert-image (create-image "prev-node.xpm")
>                 (propertize "prev" 'mouse-face 'custom-button-pressed-face))
>   (insert-image (create-image "next-node.xpm")
>                 (propertize "next" 'mouse-face 'custom-button-pressed-face)))

Easy to fix:

> (progn
>   (switch-to-buffer "*example*")
>   (insert-image (create-image "prev-node.xpm")
>                 (propertize "prev" 'mouse-face (list 'custom-button-pressed-face)))
>   (insert-image (create-image "next-node.xpm")
>                 (propertize "next" 'mouse-face (list 'custom-button-pressed-face))))


-- Stefan

Re: incorrect button highlighting

[Richard Stallman]

    Actually, it's nothing to do with widgets. This has the same symptoms:

    (progn
      (switch-to-buffer "*example*")
      (insert-image (create-image "prev-node.xpm")
		    (propertize "prev" 'mouse-face 'custom-button-pressed-face))
      (insert-image (create-image "next-node.xpm")
		    (propertize "next" 'mouse-face 'custom-button-pressed-face)))

That in itself is not a bug, it is just the way mouse-face works.
However, its consequence for widgets is a bug.

If the bug is simply due to using the a fixed value of mouse-face
on every widget, does this fix it?

*** wid-edit.el	12 Aug 2007 13:52:30 -0400	1.176.2.2
--- wid-edit.el	20 Sep 2007 16:51:56 -0400	
***************
*** 405,411 ****
      (unless (widget-get widget :suppress-face)
        (overlay-put overlay 'face (widget-apply widget :button-face-get))
        (overlay-put overlay 'mouse-face
! 		   (widget-apply widget :mouse-face-get)))
      (overlay-put overlay 'pointer 'hand)
      (overlay-put overlay 'follow-link follow-link)
      (overlay-put overlay 'help-echo help-echo)))
--- 405,421 ----
      (unless (widget-get widget :suppress-face)
        (overlay-put overlay 'face (widget-apply widget :button-face-get))
        (overlay-put overlay 'mouse-face
! 		   ;; Make new list structure for the mouse-face value
! 		   ;; so that different widgets will have
! 		   ;; different `mouse-face' property values
! 		   ;; and will highlight separately.
! 		   (let ((mouse-face-value
! 			  (widget-apply widget :mouse-face-get)))
! 		     ;; If it's a list, copy it.
! 		     (if (listp mouse-face-value)
! 			 (copy-sequence mouse-face-value)
! 		       ;; If it's a symbol, put it in a list.
! 		       (list mouse-face-value)))))
      (overlay-put overlay 'pointer 'hand)
      (overlay-put overlay 'follow-link follow-link)
      (overlay-put overlay 'help-echo help-echo)))

Re: incorrect button highlighting

[Stefan Monnier]

> If the bug is simply due to using the a fixed value of mouse-face
> on every widget, does this fix it?

> *** wid-edit.el	12 Aug 2007 13:52:30 -0400	1.176.2.2
> --- wid-edit.el	20 Sep 2007 16:51:56 -0400	
> ***************
> *** 405,411 ****
>       (unless (widget-get widget :suppress-face)
>         (overlay-put overlay 'face (widget-apply widget :button-face-get))
>         (overlay-put overlay 'mouse-face
> ! 		   (widget-apply widget :mouse-face-get)))
>       (overlay-put overlay 'pointer 'hand)
>       (overlay-put overlay 'follow-link follow-link)
>       (overlay-put overlay 'help-echo help-echo)))
> --- 405,421 ----
>       (unless (widget-get widget :suppress-face)
>         (overlay-put overlay 'face (widget-apply widget :button-face-get))
>         (overlay-put overlay 'mouse-face
> ! 		   ;; Make new list structure for the mouse-face value
> ! 		   ;; so that different widgets will have
> ! 		   ;; different `mouse-face' property values
> ! 		   ;; and will highlight separately.
> ! 		   (let ((mouse-face-value
> ! 			  (widget-apply widget :mouse-face-get)))
> ! 		     ;; If it's a list, copy it.
> ! 		     (if (listp mouse-face-value)
> ! 			 (copy-sequence mouse-face-value)
> ! 		       ;; If it's a symbol, put it in a list.
> ! 		       (list mouse-face-value)))))
>       (overlay-put overlay 'pointer 'hand)
>       (overlay-put overlay 'follow-link follow-link)
>       (overlay-put overlay 'help-echo help-echo)))

This problem should only appear with text properties: with overlays, Emacs
should be clever enough to use the end of the overlay as a boundary.


        Stefan

Re: incorrect button highlighting

[Richard Stallman]

    This problem should only appear with text properties: with overlays, Emacs
    should be clever enough to use the end of the overlay as a boundary.

I agree.

For the mean time, we will fix this at the Lisp level.  For the long
term, would someone like to work on the fix in handling the overlays?

Re: incorrect button highlighting

[Stefan Monnier]

> No put the mouse over one of the 2 buttons that appear, and both will
> be shown using the custom-button-pressed face instead of just the one
> that is under the mouse cursor. 

I believe I've just fixed it on the 22 branch.


        Stefan