1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
| | ;;; toml-ts-mode.el --- tree-sitter support for TOML -*- lexical-binding: t; -*-
;; Copyright (C) 2022 Free Software Foundation, Inc.
;; Author : Jostein Kjønigsen <jostein@kjonigsen.net>
;; Maintainer : Jostein Kjønigsen <jostein@kjonigsen.net>
;; Created : December 2022
;; Keywords : toml languages tree-sitter
;; This file is part of GNU Emacs.
;; GNU Emacs is free software: you can redistribute it and/or modify
;; it under the terms of the GNU General Public License as published by
;; the Free Software Foundation, either version 3 of the License, or
;; (at your option) any later version.
;; GNU Emacs is distributed in the hope that it will be useful,
;; but WITHOUT ANY WARRANTY; without even the implied warranty of
;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
;; GNU General Public License for more details.
;; You should have received a copy of the GNU General Public License
;; along with GNU Emacs. If not, see <https://www.gnu.org/licenses/>.
;;; Commentary:
;;
;;; Code:
(require 'treesit)
(declare-function treesit-parser-create "treesit.c")
(declare-function treesit-induce-sparse-tree "treesit.c")
(declare-function treesit-node-start "treesit.c")
(declare-function treesit-node-child-by-field-name "treesit.c")
(defvar toml-ts-mode--font-lock-settings
(treesit-font-lock-rules
:language 'toml
:feature 'constant
'((boolean) @font-lock-constant-face)
:language 'toml
:feature 'delimiter
'((["="]) @font-lock-delimiter-face)
:language 'toml
:feature 'number
'((integer) @font-lock-number-face
(float) @font-lock-number-face
(local_date) @font-lock-number-face
(local_date_time) @font-lock-number-face
(local_time) @font-lock-number-face)
:language 'toml
:feature 'string
'((string) @font-lock-string-face)
:language 'toml
:feature 'escape-sequence
:override t
'((escape_sequence) @font-lock-escape-face)
:language 'toml
:feature 'pair
:override t ; Needed for overriding string face on keys.
'((comment) @font-lock-comment-face
(bare_key) @font-lock-property-face
(quoted_key) @font-lock-property-face
(table ("[" @font-lock-bracket-face
(_) @font-lock-type-face
"]" @font-lock-bracket-face))
(table_array_element ("[[" @font-lock-bracket-face
(_) @font-lock-type-face
"]]" @font-lock-bracket-face))
(table (quoted_key) @font-lock-type-face)
(table (dotted_key (quoted_key)) @font-lock-type-face))
:language 'toml
:feature 'error
:override t
'((ERROR) @font-lock-warning-face))
"Font-lock settings for TOML.")
(defun toml-ts-mode--get-table-name (node)
"Obtains the header-name for the associated tree-sitter `NODE'."
(if node
(treesit-node-text
(car (cdr (treesit-node-children node))))
"Root table"))
(defun toml-ts-mode--imenu-1 (node)
"Helper for `toml-ts-mode--imenu'.
Find string representation for NODE and set marker, then recurse
the subtrees."
(let* ((ts-node (car node))
(subtrees (mapcan #'toml-ts-mode--imenu-1 (cdr node)))
(name (toml-ts-mode--get-table-name ts-node))
(marker (when ts-node
(set-marker (make-marker)
(treesit-node-start ts-node)))))
(cond
((null ts-node) subtrees)
(subtrees
`((,name ,(cons name marker) ,@subtrees)))
(t
`((,name . ,marker))))))
(defun toml-ts-mode--imenu ()
"Return Imenu alist for the current buffer."
(let* ((node (treesit-buffer-root-node))
(table-tree (treesit-induce-sparse-tree
node "^table$" nil 1000))
(table-array-tree (treesit-induce-sparse-tree
node "^table_array_element$" nil 1000))
(table-index (toml-ts-mode--imenu-1 table-tree))
(table-array-index (toml-ts-mode--imenu-1 table-array-tree)))
;;(setq global-toml-node (treesit-buffer-root-node))
(append
(when table-index `(("Headers" . ,table-index)))
(when table-array-index `(("Arrays" . ,table-array-index))))))
;;;###autoload
(add-to-list 'auto-mode-alist '("\\.toml\\'" . toml-ts-mode))
;;;###autoload
(define-derived-mode toml-ts-mode text-mode "TOML"
"Major mode for editing TOML, powered by tree-sitter."
:group 'toml-mode
(when (treesit-ready-p 'toml)
(treesit-parser-create 'toml)
;; Comments
(setq-local comment-start "# ")
(setq-local commend-end "")
;; Navigation.
(setq-local treesit-defun-type-regexp
(rx (or "table" "table_array_element")))
;; Font-lock.
(setq-local treesit-font-lock-settings toml-ts-mode--font-lock-settings)
(setq-local treesit-font-lock-feature-list
'((constant number pair string)
(escape-sequence)
(delimiter error)))
;; Imenu.
(setq-local imenu-create-index-function #'toml-ts-mode--imenu)
(setq-local which-func-functions nil) ;; Piggyback on imenu
(treesit-major-mode-setup)))
(provide 'toml-ts-mode)
;;; toml-ts-mode.el ends here
|