Re: Add completion to compilation-read-command

[Spyros Roum <spyros.roum@posteo.net>]

[-- Attachment #1.1: Type: text/plain, Size: 2603 bytes --]

Visuwesh wrote:
> [வியாழன் டிசம்பர் 26, 2024] Spyros Roum wrote:
>
>>>> +(defcustom compilation-read-command-function
>>>> +  #'compilation-prompt-read-shell-command
>>>> +  "`compilation-read-command' uses this function to get user's input.
>>>> +Defaults to `compilation-prompt-read-shell-command',
>>>> +but 'compilation-prompt-read-with-history-completion' can be used instead for
>>>> +a completing version based on past runs."
>>>> +  :version "31.1"
>>>> +  :type 'function
>>>> +  :options
>>>> +  (list
>>>> +    #'compilation-prompt-read-shell-command
>>>> +    #'compilation-prompt-read-with-history-completion))
>>> It would be nice to say what these options mean in plain English (with
>>> :tag IIRC).
>> I like this suggestion, and it made me realize that even though I use
>> `:options`, there is no actual list of
>> options in the customization interface, which seems weird.
>>
>> [...]
>> +(defcustom compilation-read-command-function
>> +  #'compilation-prompt-read-shell-command
>> +  "`compilation-read-command' uses this function to get user's input.
>> +Defaults to `compilation-prompt-read-shell-command',
>> +but `compilation-prompt-read-with-history-completion' can be used instead for
>> +a completing version based on past runs."
>> +  :version "31.1"
>> +  :type
>> +  '(choice
>> +    (function :tag
>> +      "Read command using read-shell-command"
>> +      compilation-prompt-read-shell-command)
>> +    (function :tag
>> +      "Read command using completing-read, completing on compile-history"
>> +      compilation-prompt-read-with-history-completion)))
> I *think* this prevents adding a custom function from the Customise
> interface since we don't have a "any function" choice, and would warn
> when you say
>
>      (setopt compilation-read-command-function #'any-other-function-other-than-two)
>
> Unfortunately, I do know how to go about adding it myself since I am
> unfamiliar with defcustoms.

I did some more research and I ended up with this, which seems to work 
great.

`:tag` is not used, but `function-item` displays the docstrings of the 
functions in the customize interface.
Additionally, the `(function :tag "Other")` entry adds a third entry 
that can be any other function the user wants.

Seems to play nicely with `setopt`, and the customize interface. After 
reading some docs
on defcustom and what :type can be, it seems to me like this is the more 
"correct" version so far.

Worth noting that the earlier revision that used `:options` was normal 
to not work,
as `:options` does not support `:type function`.

[-- Attachment #1.2: Type: text/html, Size: 3344 bytes --]

[-- Attachment #2: 0001-Add-option-for-making-compilation-read-command-use-c.patch --]
[-- Type: text/x-patch, Size: 3486 bytes --]

From a92c3d691836eb762f54aeb93cdeb3e305b06185 Mon Sep 17 00:00:00 2001
From: Spyros Roum <spyros.roum@posteo.net>
Date: Thu, 26 Dec 2024 17:57:54 +0200
Subject: [PATCH] Add option for making compilation-read-command use
 completing-read

* etc/NEWS: Add to NEWS

* lisp/progmodes/compile.el (compilation-read-command):
Call function based on `compilation-read-command-function`.
(compilation-prompt-read-shell-command): The existing
functionality from compilation-read-command extracted to
a function.
(compilation-prompt-read-with-history-completion): A
function that uses completing-read to read the command.
(compilation-read-command-function): The new option that
controlls which function is used.
---
 etc/NEWS                  |  8 ++++++++
 lisp/progmodes/compile.el | 28 +++++++++++++++++++++++++++-
 2 files changed, 35 insertions(+), 1 deletion(-)

diff --git a/etc/NEWS b/etc/NEWS
index 8adead78a32..a9862ccf3ff 100644
--- a/etc/NEWS
+++ b/etc/NEWS
@@ -147,6 +147,14 @@ will still be on that candidate after "*Completions*" is updated with a
 new list of completions.  The candidate is automatically deselected when
 the "*Completions*" buffer is hidden.
 
+---
+*** New user option 'compilation-read-command-function'.
+This option controls what function is used to read user input for
+'compilation-read-command'.
+It defaults to 'compilation-prompt-read-shell-command', which preserves
+existing behavior.  When set to 'compilation-prompt-read-with-history-completion',
+'completing-read' is used allowing autocomplete based on past runs of 'compile'.
+
 ** Windows
 
 +++
diff --git a/lisp/progmodes/compile.el b/lisp/progmodes/compile.el
index 6784a12fd63..7ef1e5997d4 100644
--- a/lisp/progmodes/compile.el
+++ b/lisp/progmodes/compile.el
@@ -1797,12 +1797,38 @@ compilation-mode-font-lock-keywords
    '((compilation--ensure-parse))
    compilation-mode-font-lock-keywords))
 
-(defun compilation-read-command (command)
+(defun compilation-prompt-read-shell-command (command)
+  "Read command using read-shell-command"
   (read-shell-command "Compile command: " command
                       (if (equal (car compile-history) command)
                           '(compile-history . 1)
                         'compile-history)))
 
+(defun compilation-prompt-read-with-history-completion (command)
+  "Read command using completing-read, completing on compile-history"
+  (completing-read "Compile command: " compile-history
+                   nil nil command
+                   (if (equal (car compile-history) command)
+                       '(compile-history . 1)
+                     'compile-history)))
+
+(defcustom compilation-read-command-function
+  #'compilation-prompt-read-shell-command
+  "`compilation-read-command' uses this function to get user's input.
+Defaults to `compilation-prompt-read-shell-command',
+but `compilation-prompt-read-with-history-completion' can be used instead for
+a completing version based on past runs."
+  :version "31.1"
+  :type '(radio (function-item compilation-prompt-read-shell-command)
+                (function-item compilation-prompt-read-with-history-completion)
+                (function :tag "Other")))
+
+(defun compilation-read-command (command)
+  "Prompt user for command to run.
+`compilation-read-command-function' controls the way input is read
+from the minibuffer."
+  (funcall compilation-read-command-function command))
+
 \f
 ;;;###autoload
 (defun compile (command &optional comint)
-- 
2.47.1