Re: Clocking in on non-org files

[Marcin Borkowski <mbork@wmi.amu.edu.pl>]

Dnia 2013-10-06, o godz. 23:26:25
Marcin Borkowski <mbork@wmi.amu.edu.pl> napisał(a):

> Dnia 2013-10-06, o godz. 17:11:25
> Suvayu Ali <fatkasuvayu+linux@gmail.com> napisał(a):
> 
> > On Sun, Oct 06, 2013 at 02:07:45PM +0200, Marcin Borkowski wrote:
> > > 
> > > I have a bunch of TODO items connected with LaTeX files (in
> > > general: projects) I'm working on.  I was wondering whether it
> > > might be possible and/or wise to set things up so that I could
> > > clock in (C-c C-x C-i) in a buffer containing such a file.
> > > Currently, executing org-clock-in in a non-Org buffer results in
> > > an error (at least with my setup); with a prefix argument,
> > > everything is fine, I'm asked for one of the last clocked items.
> > > My dream is that I can clock in my buffer with just
> > 
> > Try capture: (info "(org) Template elements").
> 
> Thanks, I didn't think about it, though it's not exactly what I'm
> looking for.  My dream setup is like this: I bind globally C-c C-x C-i
> to something, and when typing this key sequence /outside/ Org-mode, I
> am asked about a /node/ somewhere in my Org files (preferably with
> autocompletion, like refiling).  Then, apart from starting the clock,
> a file-local variable remembering this node is added /to the file I'm
> in/ (as a comment at the end, for instance), so that the /next/ time
> I'm editing this file, C-c C-x C-i just starts clocking.

Hi,

I finally had some time & motivation to look into it.  Below is my
solution.  It is not perfect (in fact, probably far from being
perfect), but should work.  I'd like to hear some comments, especially
regarding two issues: (1) whether my keybindings are reasonable
(especially C-c C-x C-j, which has different semantics than its
Org-mode counterpart, but C-c C-j is already taken e.g. by AUCTeX) and
(2) usage of org-insert-link, which asks for the description, which is
completely unnecessary here.  (This touches one problem I have with
Org: it has lots of huge functions, which could be split into smaller
ones.  For instance, if org-insert-link called a separate function to
select the link and another one asking for the description, I could
use the former and not care about the latter.  But this is a minor
issue.)

The workflow is as follows: I use org-store-link in e.g. some Org
headline, say "* TODO Write a cool book", then go to cool-book.tex and
do M-x org-insert-default-link.  From now on, in cool-book.tex, I can
C-c C-x C-j in cool-book.tex (and look into subtasks of the
abovementioned TODO, for example), I can also C-c C-x C-i to clock in,
C-c C-x C-o to clock out and C-c C-x C-x to cancel the clock.

WDYT?

;;;;;;;;;;;; Code begins here ;;;;;;;;;;;;
;; Org-related functions (clocking and goto) working in arbitrary files

(defun org-goto-default-link ()
  "Jumps to the link pointed by the variable org-default-link,
which should be a file local variable."
  (if (boundp 'org-default-link)
	  (let ((org-link org-default-link))
	    (set-buffer (get-buffer-create "*Org Link Temp Buffer*"))
	    (erase-buffer)
	    (insert org-link)
	    (org-open-at-point-global)
	    (kill-buffer "*Org Link Temp Buffer*"))
	(error "Not in Org mode and org-default-link not set.")))

(defun org-goto-anywhere (&optional alternative-interface)
  "An interactive wrapper around org-goto-default-link, calling
normal org-goto if in Org mode."
  (interactive)
  (if (equal major-mode 'org-mode)
      (org-goto alternative-interface)
    (org-goto-default-link)))
    
(defun org-clock-in-anywhere (&optional select)
  "Clock in.  If called without prefix and not in Org-mode, clock
in the entry pointed by org-default-link."
  (interactive "P")
  (if (or select (equal major-mode 'org-mode))
      (org-clock-in select)
    (save-excursion
      (org-goto-default-link)
      (org-clock-in))))

(defun org-insert-default-link ()
  "Inserts a link (using org-insert-link) into the
org-default-link file local variable.  Uses org-insert-link
interface, which prompts also for the description, which is
irrelevant here."
  (interactive)
  (let ((link (save-excursion
	       (switch-to-buffer (get-buffer-create "*Org Link Temp Buffer*"))
	       (erase-buffer)
	       (org-insert-link)
	       (buffer-string))))
    (add-file-local-variable 'org-default-link link)
    (kill-buffer "*Org Link Temp Buffer*")))
    
(global-set-key (kbd "C-c C-x C-i") 'org-clock-in-anywhere)
(global-set-key (kbd "C-c C-x C-o") 'org-clock-out)
(global-set-key (kbd "C-c C-x C-j") 'org-goto-anywhere)
(global-set-key (kbd "C-c C-x C-x") 'org-clock-cancel)

;;;;;;;;;;;; Code ends here ;;;;;;;;;;;;

-- 
Marcin Borkowski
http://octd.wmi.amu.edu.pl/en/Marcin_Borkowski
Adam Mickiewicz University