About `current-directory-list'

About `current-directory-list'

[Xue Fuqiao]

[-- Attachment #1: Type: text/plain, Size: 571 bytes --]

In node 14.9.2 of Bob's `An Introduction to Programming in Emacs Lisp'(http://www.gnu.org/software/emacs/emacs-lisp-intro/html_node/Files-List.html#Files-List), there is a function called `files-in-below-directory' that lists the .el files in a directory and its subdirs.

The varlist of the `let' special form is:
(el-files-list
 (current-directory-list
  (directory-files-and-attributes directory t)))

I don't know what does `current-directory-list' means, in my Emacs(24.2), there isn't a function named `current-directory-list'.  Can anybody help?
-- 
Best regards.

[-- Attachment #2: filelist.el --]
[-- Type: application/octet-stream, Size: 1715 bytes --]

(defun files-in-below-directory (directory)
  "List the .el files in DIRECTORY and in its sub-directories."
  ;; Although the function will be used non-interactively,
  ;; it will be easier to test if we make it interactive.
  ;; The directory will have a name such as
  ;;  "/usr/local/share/emacs/22.1.1/lisp/"
  (interactive "DDirectory name: ")
  (let (el-files-list
        (current-directory-list
         (directory-files-and-attributes directory t)))
    ;; while we are in the current directory
    (while current-directory-list
      (cond
       ;; check to see whether filename ends in `.el'
       ;; and if so, append its name to a list.
       ((equal ".el" (substring (car (car current-directory-list)) -3))
        (setq el-files-list
              (cons (car (car current-directory-list)) el-files-list)))
       ;; check whether filename is that of a directory
       ((eq t (car (cdr (car current-directory-list))))
        ;; decide whether to skip or recurse
        (if
            (equal "."
                   (substring (car (car current-directory-list)) -1))
            ;; then do nothing since filename is that of
            ;;   current directory or parent, "." or ".."
            ()
          ;; else descend into the directory and repeat the process
          (setq el-files-list
                (append
                 (files-in-below-directory
                  (car (car current-directory-list)))
                 el-files-list)))))
      ;; move to the next filename in the list; this also
      ;; shortens the list so the while loop eventually comes to an end
      (setq current-directory-list (cdr current-directory-list)))
    ;; return the filenames
    el-files-list))

RE: About `current-directory-list'

[Drew Adams]

> The varlist of the `let' special form is:
> (el-files-list
>  (current-directory-list
>   (directory-files-and-attributes directory t)))
> 
> I don't know what does `current-directory-list' means, in my 
> Emacs(24.2), there isn't a function named 
> `current-directory-list'.  Can anybody help?

It is a local variable bound in that `let'.  You show two bindings:

1. `el-files-list' is bound to nil (implicitly).
2. `current-directory-list' is bound to (directory-files-and...).

I, for one, prefer to write any implicit bindings last, after the explicit ones:

(let ((current-directory-list  (directory-files-...))
      el-files-list)

I think that is more readable.  And if I want to draw attention to an initial
value of nil then I use an explicit binding.  And if it is a list variable then
I use (); if a Boolean or other I use nil.  E.g.:

(let ((el-files-list  ())
      (found          nil))

Re: About `current-directory-list'

[Xue Fuqiao]

On Sat, 22 Dec 2012 18:25:58 -0800
"Drew Adams" <drew.adams@oracle.com> wrote:

> 1. `el-files-list' is bound to nil (implicitly).
> 2. `current-directory-list' is bound to (directory-files-and...).
Thanks, I read it wrong(carelessly).

-- 
Best regards.