* Re: org-mew.el: Bug in creating links to messages marked for refile
@ 2008-11-18 15:04 Tokuya Kameshima
2008-11-21 11:18 ` Carsten Dominik
2008-11-21 12:19 ` Harri Kiiskinen
0 siblings, 2 replies; 4+ messages in thread
From: Tokuya Kameshima @ 2008-11-18 15:04 UTC (permalink / raw)
To: emacs-orgmode; +Cc: kames
[-- Attachment #1: Type: Text/Plain, Size: 1673 bytes --]
Hi Harri,
Thank you for the bug report and clear explanation. Could you try the
attached version of org-mew.el?
Thanks,
--Tokuya
> From: Harri Kiiskinen <harri.kiiskinen <at> utu.fi>
> Subject: org-mew.el: Bug in creating links to messages marked for refile
> Newsgroups: gmane.emacs.orgmode
> Date: 2008-11-17 10:07:51 GMT (1 day, 4 hours and 48 minutes ago)
>
> There's a small bug in org-mew.el, which appears when trying to store
> links to messages which have been marked for refile. I try to be as
> clear as possible:
>
> First, a working case:
>
> when storing a link to a message on an IMAP server, the result is like
> this:
>
> [[mew:UTU:%inbox#20081117.115043.144292908.harri.kiiskinen <at> utu.fi][Email
> from Harri Kiiskinen: test]]
>
> which is exactly as it should be: First the link type ("mew:"), then
> the mew case and the folder name ("UTU:%inbox"), and then the Message
> ID. (This is a message I sent to myself.)
> Link type: "mew:"
> mew case: "UTU:"
> folder: "‰inbox"
> message id: "#20081117......"
>
> Now, I set the refile mark on the message, and create a new link to
> it. The result is:
>
> [[mew:%2008#20081117.115043.144292908.harri.kiiskinen <at> utu.fi][Email
> from Harri Kiiskinen: test]]
>
> Now, the mew case is still set to UTU, meaning that mew will refile
> the message to folder UTU:%2008, but the link that is created by
> org-mew-store-link does not include the case information. We have:
> Link type: mew:
> case: (empty)
> folder: %2008
> message id: (the rest)
>
> I'm no quite able to figure where the bug might be, but I'll keep
> trying.
>
> Harri K.
[-- Attachment #2: org-mew.el --]
[-- Type: Text/Plain, Size: 5058 bytes --]
;;; org-mew.el --- Support for links to Mew messages from within Org-mode
;; Copyright (C) 2008 Free Software Foundation, Inc.
;; Author: Tokuya Kameshima <kames at fa2 dot so-net dot ne dot jp>
;; Keywords: outlines, hypermedia, calendar, wp
;; Homepage: http://orgmode.org
;; Version: 6.03pre03
;; This file is part of GNU Emacs.
;; GNU Emacs is free software: you can redistribute it and/or modify
;; it under the terms of the GNU General Public License as published by
;; the Free Software Foundation, either version 3 of the License, or
;; (at your option) any later version.
;; GNU Emacs is distributed in the hope that it will be useful,
;; but WITHOUT ANY WARRANTY; without even the implied warranty of
;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
;; GNU General Public License for more details.
;; You should have received a copy of the GNU General Public License
;; along with GNU Emacs. If not, see <http://www.gnu.org/licenses/>.
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;;
;;; Commentary:
;; This file implements links to Mew messages from within Org-mode.
;; Org-mode loads this module by default - if this is not what you want,
;; configure the variable `org-modules'.
;;; Code:
(require 'org)
(defgroup org-mew nil
"Options concerning the Mew link."
:tag "Org Startup"
:group 'org-link)
(defcustom org-mew-link-to-refile-destination t
"Create a link to the refile destination if the message is marked as refile."
:group 'org-mew
:type 'boolean)
;; Declare external functions and variables
(declare-function mew-cache-hit "ext:mew-cache" (fld msg &optional must-hit))
(declare-function mew-case-folder "ext:mew-func" (case folder))
(declare-function mew-header-get-value "ext:mew-header"
(field &optional as-list))
(declare-function mew-init "ext:mew" ())
(declare-function mew-refile-get "ext:mew-refile" (msg))
(declare-function mew-sinfo-get-case "ext:mew-summary" ())
(declare-function mew-summary-display "ext:mew-summary2" (&optional redisplay))
(declare-function mew-summary-folder-name "ext:mew-syntax" (&optional ext))
(declare-function mew-summary-get-mark "ext:mew-mark" ())
(declare-function mew-summary-message-number2 "ext:mew-syntax" ())
(declare-function mew-summary-pick-with-mewl "ext:mew-pick"
(pattern folder src-msgs))
(declare-function mew-summary-search-msg "ext:mew-const" (msg))
(declare-function mew-summary-set-message-buffer "ext:mew-summary3" (fld msg))
(declare-function mew-summary-visit-folder "ext:mew-summary4"
(folder &optional goend no-ls))
(declare-function mew-window-push "ext:mew" ())
(defvar mew-init-p)
(defvar mew-summary-goto-line-then-display)
;; Install the link type
(org-add-link-type "mew" 'org-mew-open)
(add-hook 'org-store-link-functions 'org-mew-store-link)
;; Implementation
(defun org-mew-store-link ()
"Store a link to a Mew folder or message."
(when (memq major-mode '(mew-summary-mode mew-virtual-mode))
(let* ((msgnum (mew-summary-message-number2))
(mark-info (mew-summary-get-mark))
(folder-name
(if (and org-mew-link-to-refile-destination
(eq mark-info ?o)) ; marked as refile
(mew-case-folder (mew-sinfo-get-case)
(nth 1 (mew-refile-get msgnum)))
(mew-summary-folder-name)))
message-id from to subject desc link)
(save-window-excursion
(if (fboundp 'mew-summary-set-message-buffer)
(mew-summary-set-message-buffer folder-name msgnum)
(set-buffer (mew-cache-hit folder-name msgnum t)))
(setq message-id (mew-header-get-value "Message-Id:"))
(setq from (mew-header-get-value "From:"))
(setq to (mew-header-get-value "To:"))
(setq subject (mew-header-get-value "Subject:")))
(org-store-link-props :type "mew" :from from :to to
:subject subject :message-id message-id)
(setq message-id (org-remove-angle-brackets message-id))
(setq desc (org-email-link-description))
(setq link (org-make-link "mew:" folder-name
"#" message-id))
(org-add-link-props :link link :description desc)
link)))
(defun org-mew-open (path)
"Follow the Mew message link specified by PATH."
(let (folder msgnum)
(cond ((string-match "\\`\\(+.*\\)+\\+\\([0-9]+\\)\\'" path) ; for Bastien's
(setq folder (match-string 1 path))
(setq msgnum (match-string 2 path)))
((string-match "\\`\\(\\(%#\\)?[^#]+\\)\\(#\\(.*\\)\\)?" path)
(setq folder (match-string 1 path))
(setq msgnum (match-string 4 path)))
(t (error "Error in Mew link")))
(require 'mew)
(mew-window-push)
(unless mew-init-p (mew-init))
(mew-summary-visit-folder folder)
(when msgnum
(if (not (string-match "\\`[0-9]+\\'" msgnum))
(let* ((pattern (concat "message-id=" msgnum))
(msgs (mew-summary-pick-with-mewl pattern folder nil)))
(setq msgnum (car msgs))))
(if (mew-summary-search-msg msgnum)
(if mew-summary-goto-line-then-display
(mew-summary-display))
(error "Message not found")))))
(provide 'org-mew)
;; arch-tag: 07ccdca7-6020-4941-a593-588a1e51b870
;;; org-mew.el ends here
[-- Attachment #3: Type: text/plain, Size: 204 bytes --]
_______________________________________________
Emacs-orgmode mailing list
Remember: use `Reply All' to send replies to the list.
Emacs-orgmode@gnu.org
http://lists.gnu.org/mailman/listinfo/emacs-orgmode
^ permalink raw reply [flat|nested] 4+ messages in thread
* Re: Re: org-mew.el: Bug in creating links to messages marked for refile
2008-11-18 15:04 org-mew.el: Bug in creating links to messages marked for refile Tokuya Kameshima
@ 2008-11-21 11:18 ` Carsten Dominik
2008-11-21 12:19 ` Harri Kiiskinen
1 sibling, 0 replies; 4+ messages in thread
From: Carsten Dominik @ 2008-11-21 11:18 UTC (permalink / raw)
To: Tokuya Kameshima; +Cc: emacs-orgmode
Hi Tokuya,
strangely enough I have not heard back from Harri. Are you confident
about the new version so that I should install in into the Org tree?
Could you provide me wit a ChangeLog entry?
Thanks a lot.
Best wishes
- Carsten
On Nov 18, 2008, at 4:04 PM, Tokuya Kameshima wrote:
> Hi Harri,
>
> Thank you for the bug report and clear explanation. Could you try the
> attached version of org-mew.el?
>
> Thanks,
> --Tokuya
>
>> From: Harri Kiiskinen <harri.kiiskinen <at> utu.fi>
>> Subject: org-mew.el: Bug in creating links to messages marked for
>> refile
>> Newsgroups: gmane.emacs.orgmode
>> Date: 2008-11-17 10:07:51 GMT (1 day, 4 hours and 48 minutes ago)
>>
>> There's a small bug in org-mew.el, which appears when trying to store
>> links to messages which have been marked for refile. I try to be as
>> clear as possible:
>>
>> First, a working case:
>>
>> when storing a link to a message on an IMAP server, the result is
>> like
>> this:
>>
>> [[mew:UTU:%inbox#20081117.115043.144292908.harri.kiiskinen <at>
>> utu.fi][Email
>> from Harri Kiiskinen: test]]
>>
>> which is exactly as it should be: First the link type ("mew:"), then
>> the mew case and the folder name ("UTU:%inbox"), and then the Message
>> ID. (This is a message I sent to myself.)
>> Link type: "mew:"
>> mew case: "UTU:"
>> folder: "‰inbox"
>> message id: "#20081117......"
>>
>> Now, I set the refile mark on the message, and create a new link to
>> it. The result is:
>>
>> [[mew:%2008#20081117.115043.144292908.harri.kiiskinen <at> utu.fi]
>> [Email
>> from Harri Kiiskinen: test]]
>>
>> Now, the mew case is still set to UTU, meaning that mew will refile
>> the message to folder UTU:%2008, but the link that is created by
>> org-mew-store-link does not include the case information. We have:
>> Link type: mew:
>> case: (empty)
>> folder: %2008
>> message id: (the rest)
>>
>> I'm no quite able to figure where the bug might be, but I'll keep
>> trying.
>>
>> Harri K.
>
> ;;; org-mew.el --- Support for links to Mew messages from within Org-
> mode
>
> ;; Copyright (C) 2008 Free Software Foundation, Inc.
>
> ;; Author: Tokuya Kameshima <kames at fa2 dot so-net dot ne dot jp>
> ;; Keywords: outlines, hypermedia, calendar, wp
> ;; Homepage: http://orgmode.org
> ;; Version: 6.03pre03
>
> ;; This file is part of GNU Emacs.
>
> ;; GNU Emacs is free software: you can redistribute it and/or modify
> ;; it under the terms of the GNU General Public License as published
> by
> ;; the Free Software Foundation, either version 3 of the License, or
> ;; (at your option) any later version.
>
> ;; GNU Emacs is distributed in the hope that it will be useful,
> ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
> ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
> ;; GNU General Public License for more details.
>
> ;; You should have received a copy of the GNU General Public License
> ;; along with GNU Emacs. If not, see <http://www.gnu.org/licenses/>.
> ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
> ;;
> ;;; Commentary:
>
> ;; This file implements links to Mew messages from within Org-mode.
> ;; Org-mode loads this module by default - if this is not what you
> want,
> ;; configure the variable `org-modules'.
>
> ;;; Code:
>
> (require 'org)
>
> (defgroup org-mew nil
> "Options concerning the Mew link."
> :tag "Org Startup"
> :group 'org-link)
>
> (defcustom org-mew-link-to-refile-destination t
> "Create a link to the refile destination if the message is marked as
> refile."
> :group 'org-mew
> :type 'boolean)
>
> ;; Declare external functions and variables
> (declare-function mew-cache-hit "ext:mew-cache" (fld msg &optional
> must-hit))
> (declare-function mew-case-folder "ext:mew-func" (case folder))
> (declare-function mew-header-get-value "ext:mew-header"
> (field &optional as-list))
> (declare-function mew-init "ext:mew" ())
> (declare-function mew-refile-get "ext:mew-refile" (msg))
> (declare-function mew-sinfo-get-case "ext:mew-summary" ())
> (declare-function mew-summary-display "ext:mew-summary2" (&optional
> redisplay))
> (declare-function mew-summary-folder-name "ext:mew-
> syntax" (&optional ext))
> (declare-function mew-summary-get-mark "ext:mew-mark" ())
> (declare-function mew-summary-message-number2 "ext:mew-syntax" ())
> (declare-function mew-summary-pick-with-mewl "ext:mew-pick"
> (pattern folder src-msgs))
> (declare-function mew-summary-search-msg "ext:mew-const" (msg))
> (declare-function mew-summary-set-message-buffer "ext:mew-
> summary3" (fld msg))
> (declare-function mew-summary-visit-folder "ext:mew-summary4"
> (folder &optional goend no-ls))
> (declare-function mew-window-push "ext:mew" ())
> (defvar mew-init-p)
> (defvar mew-summary-goto-line-then-display)
>
> ;; Install the link type
> (org-add-link-type "mew" 'org-mew-open)
> (add-hook 'org-store-link-functions 'org-mew-store-link)
>
> ;; Implementation
> (defun org-mew-store-link ()
> "Store a link to a Mew folder or message."
> (when (memq major-mode '(mew-summary-mode mew-virtual-mode))
> (let* ((msgnum (mew-summary-message-number2))
> (mark-info (mew-summary-get-mark))
> (folder-name
> (if (and org-mew-link-to-refile-destination
> (eq mark-info ?o)) ; marked as refile
> (mew-case-folder (mew-sinfo-get-case)
> (nth 1 (mew-refile-get msgnum)))
> (mew-summary-folder-name)))
> message-id from to subject desc link)
> (save-window-excursion
> (if (fboundp 'mew-summary-set-message-buffer)
> (mew-summary-set-message-buffer folder-name msgnum)
> (set-buffer (mew-cache-hit folder-name msgnum t)))
> (setq message-id (mew-header-get-value "Message-Id:"))
> (setq from (mew-header-get-value "From:"))
> (setq to (mew-header-get-value "To:"))
> (setq subject (mew-header-get-value "Subject:")))
> (org-store-link-props :type "mew" :from from :to to
> :subject subject :message-id message-id)
> (setq message-id (org-remove-angle-brackets message-id))
> (setq desc (org-email-link-description))
> (setq link (org-make-link "mew:" folder-name
> "#" message-id))
> (org-add-link-props :link link :description desc)
> link)))
>
> (defun org-mew-open (path)
> "Follow the Mew message link specified by PATH."
> (let (folder msgnum)
> (cond ((string-match "\\`\\(+.*\\)+\\+\\([0-9]+\\)\\'" path) ; for
> Bastien's
> (setq folder (match-string 1 path))
> (setq msgnum (match-string 2 path)))
> ((string-match "\\`\\(\\(%#\\)?[^#]+\\)\\(#\\(.*\\)\\)?" path)
> (setq folder (match-string 1 path))
> (setq msgnum (match-string 4 path)))
> (t (error "Error in Mew link")))
> (require 'mew)
> (mew-window-push)
> (unless mew-init-p (mew-init))
> (mew-summary-visit-folder folder)
> (when msgnum
> (if (not (string-match "\\`[0-9]+\\'" msgnum))
> (let* ((pattern (concat "message-id=" msgnum))
> (msgs (mew-summary-pick-with-mewl pattern folder nil)))
> (setq msgnum (car msgs))))
> (if (mew-summary-search-msg msgnum)
> (if mew-summary-goto-line-then-display
> (mew-summary-display))
> (error "Message not found")))))
>
> (provide 'org-mew)
>
> ;; arch-tag: 07ccdca7-6020-4941-a593-588a1e51b870
>
> ;;; org-mew.el ends here
> _______________________________________________
> Emacs-orgmode mailing list
> Remember: use `Reply All' to send replies to the list.
> Emacs-orgmode@gnu.org
> http://lists.gnu.org/mailman/listinfo/emacs-orgmode
^ permalink raw reply [flat|nested] 4+ messages in thread
* Re: Re: org-mew.el: Bug in creating links to messages marked for refile
2008-11-18 15:04 org-mew.el: Bug in creating links to messages marked for refile Tokuya Kameshima
2008-11-21 11:18 ` Carsten Dominik
@ 2008-11-21 12:19 ` Harri Kiiskinen
1 sibling, 0 replies; 4+ messages in thread
From: Harri Kiiskinen @ 2008-11-21 12:19 UTC (permalink / raw)
To: kames; +Cc: emacs-orgmode
[-- Attachment #1: Type: Text/Plain, Size: 2022 bytes --]
Hi Tokuya,
sorry for not replying immediately, I was travelling for a few
days. Now that I try this version, the links are correct and function
as they should.
Thanks a lot!
Harri
From: Tokuya Kameshima <kames@fa2.so-net.ne.jp>
> Hi Harri,
>
> Thank you for the bug report and clear explanation. Could you try the
> attached version of org-mew.el?
>
> Thanks,
> --Tokuya
>
> > From: Harri Kiiskinen <harri.kiiskinen <at> utu.fi>
> > Subject: org-mew.el: Bug in creating links to messages marked for refile
> > Newsgroups: gmane.emacs.orgmode
> > Date: 2008-11-17 10:07:51 GMT (1 day, 4 hours and 48 minutes ago)
> >
> > There's a small bug in org-mew.el, which appears when trying to store
> > links to messages which have been marked for refile. I try to be as
> > clear as possible:
> >
> > First, a working case:
> >
> > when storing a link to a message on an IMAP server, the result is like
> > this:
> >
> > [[mew:UTU:%inbox#20081117.115043.144292908.harri.kiiskinen <at> utu.fi][Email
> > from Harri Kiiskinen: test]]
> >
> > which is exactly as it should be: First the link type ("mew:"), then
> > the mew case and the folder name ("UTU:%inbox"), and then the Message
> > ID. (This is a message I sent to myself.)
> > Link type: "mew:"
> > mew case: "UTU:"
> > folder: "‰inbox"
> > message id: "#20081117......"
> >
> > Now, I set the refile mark on the message, and create a new link to
> > it. The result is:
> >
> > [[mew:%2008#20081117.115043.144292908.harri.kiiskinen <at> utu.fi][Email
> > from Harri Kiiskinen: test]]
> >
> > Now, the mew case is still set to UTU, meaning that mew will refile
> > the message to folder UTU:%2008, but the link that is created by
> > org-mew-store-link does not include the case information. We have:
> > Link type: mew:
> > case: (empty)
> > folder: %2008
> > message id: (the rest)
> >
> > I'm no quite able to figure where the bug might be, but I'll keep
> > trying.
> >
> > Harri K.
>
[-- Attachment #2: Type: text/plain, Size: 204 bytes --]
_______________________________________________
Emacs-orgmode mailing list
Remember: use `Reply All' to send replies to the list.
Emacs-orgmode@gnu.org
http://lists.gnu.org/mailman/listinfo/emacs-orgmode
^ permalink raw reply [flat|nested] 4+ messages in thread
* org-mew.el: Bug in creating links to messages marked for refile
@ 2008-11-17 10:07 Harri Kiiskinen
0 siblings, 0 replies; 4+ messages in thread
From: Harri Kiiskinen @ 2008-11-17 10:07 UTC (permalink / raw)
To: emacs-orgmode
[-- Attachment #1: Type: Text/Plain, Size: 1205 bytes --]
There's a small bug in org-mew.el, which appears when trying to store
links to messages which have been marked for refile. I try to be as
clear as possible:
First, a working case:
when storing a link to a message on an IMAP server, the result is like
this:
[[mew:UTU:%inbox#20081117.115043.144292908.harri.kiiskinen@utu.fi][Email
from Harri Kiiskinen: test]]
which is exactly as it should be: First the link type ("mew:"), then
the mew case and the folder name ("UTU:%inbox"), and then the Message
ID. (This is a message I sent to myself.)
Link type: "mew:"
mew case: "UTU:"
folder: "‰inbox"
message id: "#20081117......"
Now, I set the refile mark on the message, and create a new link to
it. The result is:
[[mew:%2008#20081117.115043.144292908.harri.kiiskinen@utu.fi][Email
from Harri Kiiskinen: test]]
Now, the mew case is still set to UTU, meaning that mew will refile
the message to folder UTU:%2008, but the link that is created by
org-mew-store-link does not include the case information. We have:
Link type: mew:
case: (empty)
folder: %2008
message id: (the rest)
I'm no quite able to figure where the bug might be, but I'll keep
trying.
Harri K.
[-- Attachment #2: Type: text/plain, Size: 204 bytes --]
_______________________________________________
Emacs-orgmode mailing list
Remember: use `Reply All' to send replies to the list.
Emacs-orgmode@gnu.org
http://lists.gnu.org/mailman/listinfo/emacs-orgmode
^ permalink raw reply [flat|nested] 4+ messages in thread
end of thread, other threads:[~2008-11-21 12:20 UTC | newest]
Thread overview: 4+ messages (download: mbox.gz follow: Atom feed
-- links below jump to the message on this page --
2008-11-18 15:04 org-mew.el: Bug in creating links to messages marked for refile Tokuya Kameshima
2008-11-21 11:18 ` Carsten Dominik
2008-11-21 12:19 ` Harri Kiiskinen
-- strict thread matches above, loose matches on Subject: below --
2008-11-17 10:07 Harri Kiiskinen
Code repositories for project(s) associated with this external index
https://git.savannah.gnu.org/cgit/emacs.git
https://git.savannah.gnu.org/cgit/emacs/org-mode.git
This is an external index of several public inboxes,
see mirroring instructions on how to clone and mirror
all data and code used by this external index.