;;; window-tests.el -- tests for window.c -*- lexical-binding: t -*-

;; Copyright (C) 2016 Free Software Foundation, Inc.

;; This file is part of GNU Emacs.

;; This program is free software; you can redistribute it and/or modify
;; it under the terms of the GNU General Public License as published by
;; the Free Software Foundation, either version 3 of the License, or
;; (at your option) any later version.

;; This program is distributed in the hope that it will be useful,
;; but WITHOUT ANY WARRANTY; without even the implied warranty of
;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
;; GNU General Public License for more details.

;; You should have received a copy of the GNU General Public License
;; along with this program.  If not, see <http://www.gnu.org/licenses/>.

;;; Code:

(require 'ert)

(defun window-tests-scrolling (margin &optional effective-margin)
  (unless effective-margin
    (setq effective-margin margin))
  (erase-buffer)
  (insert (mapconcat #'number-to-string
                     (number-sequence 1 200) "\n"))
  (goto-char 1)
  (sit-for 0)
  (let ((scroll-margin margin)
        (wstart (window-start)))
    ;; Stopping before `scroll-margin' so we shouldn't have
    ;; scrolled.
    (let ((current-prefix-arg (- (window-text-height) 1 effective-margin)))
      (call-interactively 'next-line))
    (sit-for 0)
    (should (= wstart (window-start)))
    ;; Passing `scroll-margin' should trigger scrolling.
    (call-interactively 'next-line)
    (sit-for 0)
    (should (/= wstart (window-start)))
    ;; Scroll back to top.
    (let ((current-prefix-arg (window-start)))
      (call-interactively 'scroll-down-command))
    (sit-for 0)
    (should (= 1 (window-start)))))

(defmacro window-tests-with-buffer-window (&rest body)
  (declare (debug t))
  (let ((bufvar (make-symbol "buf")))
    `(let ((,bufvar (get-buffer-create "*test*")))
       (with-selected-window (display-buffer ,bufvar)
         (with-current-buffer ,bufvar
           ,@body)))))

(ert-deftest window-tests-scroll-margin-0 ()
  (skip-unless (not noninteractive))
  (window-tests-with-buffer-window
   (window-tests-scrolling 0)))

(ert-deftest window-tests-scroll-margin-negative ()
  "A negative `scroll-margin' should be the same as 0."
  (skip-unless (not noninteractive))
  (window-tests-with-buffer-window
   (window-tests-scrolling -10 0)))

(ert-deftest window-tests-scroll-margin-max ()
  (skip-unless (not noninteractive))
  (window-tests-with-buffer-window
   (let ((max-margin (/ (window-text-height) 4)))
     (window-tests-scrolling max-margin))))

(ert-deftest window-tests-scroll-margin-over-max ()
  "A `scroll-margin' more than max should be the same as max."
  (skip-unless (not noninteractive))
  (window-tests-with-buffer-window
   (set-window-text-height nil 7)
   (let ((max-margin (/ (window-text-height) 4)))
     (window-tests-scrolling (+ max-margin 1) max-margin)
     (window-tests-scrolling (+ max-margin 2) max-margin))))

(defun window-tests--point-in-middle-of-window-p ()
  (= (count-lines (window-start) (window-point))
     (/ (1- (window-text-height)) 2)))

(ert-deftest window-tests-scroll-margin-whole-window ()
  "Test `maximum-scroll-margin' at 0.5.
With a high `scroll-margin', this should keep cursor in the
middle of the window."
  (skip-unless (not noninteractive))
  (let ((maximum-scroll-margin 0.5)
        (scroll-margin 100))
    (window-tests-with-buffer-window
     (set-window-text-height nil 7)
     (erase-buffer)
     (insert (mapconcat #'number-to-string
                        (number-sequence 1 200) "\n"))
     (goto-char 1)
     (sit-for 0)
     (call-interactively 'scroll-up-command)
     (sit-for 0)
     (should (window-tests--point-in-middle-of-window-p))
     (call-interactively 'scroll-up-command)
     (sit-for 0)
     (should (window-tests--point-in-middle-of-window-p))
     (call-interactively 'scroll-down-command)
     (sit-for 0)
     (should (window-tests--point-in-middle-of-window-p)))))
;;; window-tests.el ends here