Re: Unicode confusables and reordering characters considered harmful

[Gregory Heytings <gregory@heytings.org>]

[-- Attachment #1: Type: text/plain, Size: 188 bytes --]


>
> I did not spend enough time tweaking that code, given that Eli already 
> said he doesn't want it.
>

But I could not resist, I implemented your suggestions anyway ;-)  Thanks 
again!

[-- Warning: decoded text below may be mangled, UTF-8 assumed --]
[-- Attachment #2: Type: text/x-diff; name=Make-bidi-reordering-characters-visible.patch, Size: 3445 bytes --]

From 8a4eda2e417c0d7d4ca4489b9c025258d53f20c1 Mon Sep 17 00:00:00 2001
From: Gregory Heytings <gregory@heytings.org>
Date: Wed, 3 Nov 2021 21:54:03 +0000
Subject: [PATCH] Make bidi reordering characters visible

* lisp/progmodes/prog-mode.el (bidi-reordering-characters-visible):
New minor mode.
(bidi-reordering-characters-visible--fontify,
bidi-reordering-characters-visible--toggle): New helper functions.
(prog-mode): Enable the new minor mode.
---
 lisp/progmodes/prog-mode.el | 43 ++++++++++++++++++++++++++++++++++++-
 1 file changed, 42 insertions(+), 1 deletion(-)

diff --git a/lisp/progmodes/prog-mode.el b/lisp/progmodes/prog-mode.el
index db350a5f70..8c863f56a7 100644
--- a/lisp/progmodes/prog-mode.el
+++ b/lisp/progmodes/prog-mode.el
@@ -293,6 +293,46 @@ turn-on-prettify-symbols-mode
 (define-globalized-minor-mode global-prettify-symbols-mode
   prettify-symbols-mode turn-on-prettify-symbols-mode)
 
+(defun bidi-reordering-characters-visible--fontify ()
+  "Fontify bidi reordering characters with `font-lock-warning-face'."
+  (font-lock-add-keywords
+   nil
+   '(("[\N{left-to-right embedding}\N{right-to-left embedding}\
+\N{left-to-right override}\N{right-to-left override}\
+\N{left-to-right isolate}\N{right-to-left isolate}\
+\N{first strong isolate}\N{pop directional formatting}\
+\N{pop directional isolate}]" . (0 'font-lock-warning-face t)))))
+
+(defun bidi-reordering-character-visible--toggle ()
+  "Toggle the visibility of bidi reordering characters."
+  (let ((v bidi-reordering-characters-visible)
+        (bdt buffer-display-table))
+    (aset bdt ?\N{left-to-right embedding} (if v [?→] nil))
+    (aset bdt ?\N{right-to-left embedding} (if v [?←] nil))
+    (aset bdt ?\N{left-to-right override} (if v [?→] nil))
+    (aset bdt ?\N{right-to-left override} (if v [?←] nil))
+    (aset bdt ?\N{left-to-right isolate} (if v [?→] nil))
+    (aset bdt ?\N{right-to-left isolate} (if v [?←] nil))
+    (aset bdt ?\N{first strong isolate} (if v [?↓] nil))
+    (aset bdt ?\N{pop directional formatting} (if v [?↑] nil))
+    (aset bdt ?\N{pop directional isolate} (if v [?↑] nil))))
+
+;;;###autoload
+(define-minor-mode bidi-reordering-characters-visible
+  "Make the bidi reordering characters visible."
+  :init-value nil
+  (if bidi-reordering-characters-visible
+      (progn
+          (setq buffer-display-table (or buffer-display-table
+                                         standard-display-table
+                                         (make-display-table)))
+          (bidi-reordering-character-visible--toggle)
+          (add-hook 'font-lock-mode-hook
+                    #'bidi-reordering-characters-visible--fontify))
+    (bidi-reordering-character-visible--toggle)
+    (remove-hook 'font-lock-mode-hook
+                 #'bidi-reordering-characters-visible--fontify)))
+
 ;;;###autoload
 (define-derived-mode prog-mode fundamental-mode "Prog"
   "Major mode for editing programming language source code."
@@ -300,7 +340,8 @@ prog-mode
   (setq-local parse-sexp-ignore-comments t)
   (add-hook 'context-menu-functions 'prog-context-menu 10 t)
   ;; Any programming language is always written left to right.
-  (setq bidi-paragraph-direction 'left-to-right))
+  (setq bidi-paragraph-direction 'left-to-right)
+  (bidi-reordering-characters-visible))
 
 (provide 'prog-mode)
 
-- 
2.33.0