bug#69305: outline-minor-mode for tabulated-list-mode

[Adam Porter <adam@alphapapa.net>]

[-- Attachment #1: Type: text/plain, Size: 2010 bytes --]

Hi Juri,

On 2/25/24 11:36, Juri Linkov wrote:
>> So if you were to use one of these as inspiration (or as a library
>> directly), I'd strongly recommend using `taxy', as that's what it's
>> designed for.
>> [...]
>> Let me know if I can help facilitate a solution using it, or help anyone
>> work with the API.
> 
> Thanks for proposing help, but for inspiration I'm using
> my own package https://github.com/link0ff/emacs-ee
> It's much more powerful than anything I have seen so far.
> But on the other hand, it became so unmanageable
> that I semi-abandoned it due to its overly complexity.

Taxy might be able to help with that, because it's designed to simply 
abstract the matter of classifying data into hierarchies.  It's only 381 
lines of code, which includes macros that allow applications to define 
their own, user-extensible grouping languages with top-level forms.

UI frontends to render the data structures are separated from the 
concern of grouping.  A simple "pretty print" one is provided, but the 
main implementation so far is the associated library, taxy-magit-section.

> Is your package more light-weight than mine?  I doubt it ;-)

Well, judge for yourself.  :)  Attached is a file that provides a simple 
buffer-grouping command based on Taxy.  It's what I would call a "level 
one" implementation, without defining a DSL or user-customizeable 
grouping.  Adding those features would only take a few more lines of 
code, but I'm keeping this example as simple as possible.  This only 
takes 41 lines of code.  It produces a view as seen in the attached 
screenshot.  And it only took about 5 minutes to write by modifying a 
similar example that works on another kind of object.

Anyway, I'm not necessarily pushing a solution here, only trying to 
share what's available.  I did spend a lot of time on this project, and 
IMHO it solves the problem elegantly and powerfully, so I would like to 
see it applied more widely, but things included with Emacs itself are 
another matter.

[-- Attachment #2: buffery.el --]
[-- Type: text/x-emacs-lisp, Size: 2305 bytes --]

;;; buffery.el --- Buffer view with Taxy grouping    -*- lexical-binding: t; -*-

;; Keywords: 

;; This program is free software; you can redistribute it and/or modify
;; it under the terms of the GNU General Public License as published by
;; the Free Software Foundation, either version 3 of the License, or
;; (at your option) any later version.

;; This program is distributed in the hope that it will be useful,
;; but WITHOUT ANY WARRANTY; without even the implied warranty of
;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
;; GNU General Public License for more details.

;; You should have received a copy of the GNU General Public License
;; along with this program.  If not, see <https://www.gnu.org/licenses/>.

;;; Commentary:

;; 

;;; Code:

(require 'cl-lib)
(require 'project)
(require 'taxy)
(require 'taxy-magit-section)

(defvar buffery-taxy
  (cl-labels ((directory (buffer)
                (buffer-local-value 'default-directory buffer))
              (mode (buffer)
                (prin1-to-string (buffer-local-value 'major-mode buffer)))
              (project (buffer)
                (with-current-buffer buffer
                  (when-let ((project (project-current)))
                    (project-root project))))
              (specialp (buffer)
                (when (not (buffer-file-name buffer))
                  "*special*"))
              (make-fn (&rest args)
                (apply #'make-taxy-magit-section
                       :make #'make-fn
                       :format-fn #'buffer-name
                       args)))
    (make-fn
     :name "Buffers"
     :take (apply-partially #'taxy-take-keyed
                            (list (list #'project)
                                  (list #'specialp)
                                  #'directory #'mode)))))

(defun buffery ()
  (interactive)
  (let* ((buffers (buffer-list))
         (buffer (get-buffer-create "*Buffery*"))
         (inhibit-read-only t))
    (with-current-buffer buffer
      (erase-buffer)
      (thread-last buffery-taxy
                   taxy-emptied
                   (taxy-fill buffers)
                   (taxy-sort* #'string< #'taxy-name)
                   taxy-magit-section-insert))
    (pop-to-buffer buffer)))

(provide 'buffery)
;;; buffery.el ends here

[-- Attachment #3: example.png --]
[-- Type: image/png, Size: 63425 bytes --]