1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
| | ;;; button-tests.el --- tests for button.el -*- lexical-binding: t -*-
;; Copyright (C) 2019 Free Software Foundation, Inc.
;; This file is part of GNU Emacs.
;; GNU Emacs is free software: you can redistribute it and/or modify
;; it under the terms of the GNU General Public License as published by
;; the Free Software Foundation, either version 3 of the License, or
;; (at your option) any later version.
;; GNU Emacs is distributed in the hope that it will be useful,
;; but WITHOUT ANY WARRANTY; without even the implied warranty of
;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
;; GNU General Public License for more details.
;; You should have received a copy of the GNU General Public License
;; along with GNU Emacs. If not, see <https://www.gnu.org/licenses/>.
;;; Code:
(require 'ert)
(ert-deftest button-at ()
"Test `button-at' behavior."
(with-temp-buffer
(should-not (button-at (point)))
(let ((button (insert-text-button "text button"))
(marker (button-at (1- (point)))))
(should (markerp marker))
(should (= (button-end button) (button-end marker) (point))))
(let ((button (insert-button "overlay button"))
(overlay (button-at (1- (point)))))
(should (overlayp overlay))
(should (eq button overlay)))
;; Buttons and widgets are incompatible (bug#34506).
(widget-create 'link "link widget")
(should-not (button-at (1- (point))))))
(ert-deftest button--help-echo ()
"Test `button--help-echo' behavior."
(with-temp-buffer
;; Text property buttons.
(let ((button (insert-text-button "text" 'help-echo "string")))
(should (equal (button--help-echo button) "string")))
(let ((button (insert-text-button "text" 'help-echo '(concat "form"))))
(should (equal (button--help-echo button) "form")))
(let* ((owin (selected-window))
(obuf (current-buffer))
(opos (point))
(help (lambda (win obj pos)
(should (eq win owin))
(should (eq obj obuf))
(should (= pos opos))
"function"))
(button (insert-text-button "text" 'help-echo help)))
(should (equal (button--help-echo button) "function")))
;; Overlay buttons.
(let ((button (insert-button "overlay" 'help-echo "string")))
(should (equal (button--help-echo button) "string")))
(let ((button (insert-button "overlay" 'help-echo '(concat "form"))))
(should (equal (button--help-echo button) "form")))
(letrec ((owin (selected-window))
(obuf (current-buffer))
(opos (point))
(help (lambda (win obj pos)
(should (eq win owin))
(should (overlayp obj))
(should (eq obj button))
(should (eq (overlay-buffer obj) obuf))
(should (= (overlay-start obj) opos))
(should (= pos opos))
"function"))
(button (insert-button "overlay" 'help-echo help)))
(should (equal (button--help-echo button) "function")))))
;;; button-tests.el ends here
|