bug#42147: 28.0.50; pure vs side-effect-free, missing optimizations?

["Mattias Engdegård" <mattiase@acm.org>]

[-- Attachment #1: Type: text/plain, Size: 320 bytes --]

Andrea, I see nothing directly wrong with your patch, but perhaps our messages went past one another since our lists of proposed pure functions differ.

> More useful would be the ability to constant-fold ash, expt, %, mod and abs for a subset of each respective domain. I can write a patch.

Here is that patch.


[-- Attachment #2: 0001-Constant-fold-mod-ash-expt-and-abs-with-constant-int.patch --]
[-- Type: application/octet-stream, Size: 3537 bytes --]

From aa9ce87268365f766a0d70e6a86bf44067e86b78 Mon Sep 17 00:00:00 2001
From: =?UTF-8?q?Mattias=20Engdeg=C3=A5rd?= <mattiase@acm.org>
Date: Wed, 1 Jul 2020 17:44:54 +0200
Subject: [PATCH] Constant-fold %, mod, ash, expt and abs with constant integer
 args

To ensure portability, the optimisation is confined to calls where the
result is a portable fixnum. (Bug#42147)

* lisp/emacs-lisp/byte-opt.el (byte-opt--integer-arith)
(byte-optimize-binary-integer-arith, byte-optimize-unary-integer-arith)
(byte-optimize-mod): New functions.
(%, mod, ash, expt, abs): Set byte-optimizer property.
* test/lisp/emacs-lisp/bytecomp-tests.el
(byte-opt-testsuite-arith-data): Add test cases.
---
 lisp/emacs-lisp/byte-opt.el            | 35 ++++++++++++++++++++++++++
 test/lisp/emacs-lisp/bytecomp-tests.el | 12 +++++++++
 2 files changed, 47 insertions(+)

diff --git a/lisp/emacs-lisp/byte-opt.el b/lisp/emacs-lisp/byte-opt.el
index 12bde8faf3..72c68d64b2 100644
--- a/lisp/emacs-lisp/byte-opt.el
+++ b/lisp/emacs-lisp/byte-opt.el
@@ -801,6 +801,34 @@ byte-optimize-divide
           form
         (cons '/ args)))))
 
+(defun byte-opt--integer-arith (form)
+  "Constant-fold FORM when args are integers and the result a portable fixnum."
+  (let ((args (cdr form)))
+    (if (memq nil (mapcar #'integerp args))
+        form
+      (let ((res (apply (car form) args)))
+        (if (byte-opt--portable-numberp res)
+            res
+          form)))))
+
+(defun byte-optimize-binary-integer-arith (form)
+  "Constant-fold the binary integer arithmetic call FORM."
+  (if (= (length form) 3)
+      (byte-opt--integer-arith form)
+    form))
+
+(defun byte-optimize-unary-integer-arith (form)
+  "Constant-fold the unary integer arithmetic call FORM."
+  (if (= (length form) 2)
+      (byte-opt--integer-arith form)
+    form))
+
+(defun byte-optimize-mod (form)
+  "Constant-fold the mod-like function call FORM."
+  (if (eql (nth 2 form) 0)
+      form
+    (byte-optimize-binary-integer-arith form)))
+
 (defun byte-optimize-binary-predicate (form)
   (cond
    ((or (not (macroexp-const-p (nth 1 form)))
@@ -918,6 +946,13 @@ byte-optimize-concat
 (put 'max 'byte-optimizer 'byte-optimize-associative-math)
 (put 'min 'byte-optimizer 'byte-optimize-associative-math)
 
+(put '% 'byte-optimizer 'byte-optimize-mod)
+(put 'mod 'byte-optimizer 'byte-optimize-mod)
+
+(put 'ash 'byte-optimizer 'byte-optimize-binary-integer-arith)
+(put 'expt 'byte-optimizer 'byte-optimize-binary-integer-arith)
+(put 'abs 'byte-optimizer 'byte-optimize-unary-integer-arith)
+
 (put '=   'byte-optimizer 'byte-optimize-binary-predicate)
 (put 'eq  'byte-optimizer 'byte-optimize-binary-predicate)
 (put 'eql   'byte-optimizer 'byte-optimize-equal)
diff --git a/test/lisp/emacs-lisp/bytecomp-tests.el b/test/lisp/emacs-lisp/bytecomp-tests.el
index bfe2d06a61..a96a7c8368 100644
--- a/test/lisp/emacs-lisp/bytecomp-tests.el
+++ b/test/lisp/emacs-lisp/bytecomp-tests.el
@@ -69,6 +69,18 @@ byte-opt-testsuite-arith-data
     (let ((a 3) (b 2))				   (/ a b 1))
     (let ((a 3) (b 2))				   (/ (+ a b) 1))
 
+    ;; More arithmetic constant-folding (bug#42147).
+    (ash 3 10)
+    (ash 3 25)
+    (abs -20)
+    (abs -2305843009213693952)
+    (expt 10 3)
+    (expt 10 20)
+    (% 20 3)
+    (% -20 3)
+    (mod 20 3)
+    (mod -20 3)
+
     ;; coverage test
     (let ((a 3) (b 2) (c 1.0)) (+))
     (let ((a 3) (b 2) (c 1.0)) (+ 2))
-- 
2.21.1 (Apple Git-122.3)