bug#8856: 24.0.50; regression: special-display-frame is no longer dedicated

["Drew Adams" <drew.adams@oracle.com>]

[-- Attachment #1: Type: text/plain, Size: 347 bytes --]


I've pared down the code to load.  Just load the attached and then follow the
recipe:

M-x f TAB ; to display *Completions* frame.
C-]       ; to return to top level.

M-x f TAB o

Or just hit TAB twice in a row: M-x f TAB TAB.  IOW, try to type more
input in minibuffer.

This then raises the error
"Buffer is read-only #<buffer *Completions*>"

[-- Attachment #2: throw-one.el --]
[-- Type: application/octet-stream, Size: 7544 bytes --]

(defvar 1on1-minibuffer-frame nil "Minibuffer-only frame")

(defcustom 1on1-minibuffer-frame-alist
  (list
   (assq 'foreground-color minibuffer-frame-alist)
   (assq 'background-color minibuffer-frame-alist)
   (assq 'font minibuffer-frame-alist)
   (assq 'mouse-color minibuffer-frame-alist)
   (assq 'cursor-color minibuffer-frame-alist)
   (assq 'menu-bar-lines minibuffer-frame-alist)
   (or (assq 'left minibuffer-frame-alist) (cons 'left 0))
   (or (assq 'height minibuffer-frame-alist) (cons 'height 2))
   (or (assq 'minibuffer minibuffer-frame-alist) (cons 'minibuffer 'only))
   (or (assq 'user-position minibuffer-frame-alist) (cons 'user-position t))
   (or (assq 'vertical-scroll-bars minibuffer-frame-alist)
       (cons 'vertical-scroll-bars nil))
   (or (assq 'name minibuffer-frame-alist) (cons 'name "Emacs Minibuffer")))
  "*Frame-parameter alist for the standalone minibuffer frame
`1on1-minibuffer-frame'.
If you customize this variable, you will need to rerun `1on1-emacs'
for the new value to take effect."
  ;; If we didn't need Emacs 20 compatibility, this could be:
  ;; :type '(alist :key-type symbol :value-type sexp)
  :type '(repeat (cons :format "%v"
                  (symbol :tag "Frame Parameter")
                  (sexp :tag "Value")))
  :group 'frames)

(defcustom 1on1-default-frame-alist
  (list
   (assq 'foreground-color default-frame-alist)
   (or (assq 'background-color default-frame-alist)
       (cons 'background-color "LightBlue"))
   (assq 'font default-frame-alist)
   (assq 'mouse-color default-frame-alist)
   (assq 'cursor-color default-frame-alist)
   (assq 'cursor-type default-frame-alist)
   (assq 'menu-bar-lines default-frame-alist)
   (or (assq 'top default-frame-alist) (cons 'top 0))
   (or (assq 'left default-frame-alist) (cons 'left 0))
   (or (assq 'width default-frame-alist) (cons 'width 80))
   (or (assq 'height default-frame-alist) (cons 'height 35))
   (or (assq 'minibuffer default-frame-alist) (cons 'minibuffer nil))
   (or (assq 'user-position default-frame-alist) (cons 'user-position t))
   (or (assq 'vertical-scroll-bars default-frame-alist)
       (cons 'vertical-scroll-bars 'right))
   (or (assq 'icon-type default-frame-alist) (cons 'icon-type nil))
   (or (assq 'tool-bar-lines default-frame-alist) (cons 'tool-bar-lines 1))
   (if (cdr (assq 'left-fringe default-frame-alist))
       (assq 'left-fringe default-frame-alist)
     (cons 'left-fringe 0))
   (if (cdr (assq 'right-fringe default-frame-alist))
       (assq 'right-fringe default-frame-alist)
     (cons 'right-fringe 0)))
  "Properties to be used for One-on-One Emacs `default-frame-alist'.
If you customize this variable, you will need to rerun `1on1-emacs'
for the new value to take effect."
  ;; If we didn't need Emacs 20 compatibility, this could be:
  ;; :type '(alist :key-type symbol :value-type sexp)
  :type '(repeat (cons :format "%v"
                  (symbol :tag "Frame Parameter")
                  (sexp :tag "Value")))
  :group 'frames)

(defcustom 1on1-special-display-frame-alist
  (list
   (assq 'font special-display-frame-alist)
   (or (assq 'width special-display-frame-alist) (cons 'width 80))
   (or (assq 'height special-display-frame-alist) (cons 'height 20))
   (assq 'mouse-color special-display-frame-alist)
   (assq 'cursor-color special-display-frame-alist)
   (assq 'menu-bar-lines special-display-frame-alist)
   (assq 'foreground-color special-display-frame-alist)
   (or (assq 'background-color special-display-frame-alist)
       (cons 'background-color "LightSteelBlue"))
   (or (assq 'top special-display-frame-alist) (cons 'top 0))
   (or (assq 'left special-display-frame-alist) (cons 'left 0))
   (or (assq 'unsplittable special-display-frame-alist)
       (cons 'unsplittable t))
   (or (assq 'user-position special-display-frame-alist)
       (cons 'user-position t))
   (or (assq 'vertical-scroll-bars special-display-frame-alist)
       (cons 'vertical-scroll-bars 'right)))
  "Properties to be used for One-on-One `special-display-frame-alist'.
If you customize this variable, you will need to rerun `1on1-emacs'
for the new value to take effect."
  ;; If we didn't need Emacs 20 compatibility, this could be:
  ;; :type '(alist :key-type symbol :value-type sexp)
  :type '(repeat (cons :format "%v"
                  (symbol :tag "Frame Parameter")
                  (sexp :tag "Value")))
  :group 'frames)

(defun 1on1-emacs ()
  "One-on-One Emacs setup.
Use `1on1-default-frame-alist' and `1on1-special-display-frame-alist'.
Create minibuffer-only frame, `1on1-minibuffer-frame', using
`1on1-minibuffer-frame-alist'.
Use special frame for *Completions* buffer."
  (interactive)
  (unless (if (fboundp 'display-graphic-p) (display-graphic-p) window-system)
    (error "Use `1on1-emacs' only with a graphics display"))
  (setq default-frame-alist (append 1on1-default-frame-alist default-frame-alist)
        special-display-frame-alist (append 1on1-special-display-frame-alist
                                            special-display-frame-alist))
  ;; Treat *Completions* frame, so it gets focus from minibuffer frame.
  (add-to-list
   'special-display-buffer-names
   '("*Completions*" 1on1-display-*Completions*-frame
     ((background-color . "LavenderBlush2")
      (menu-bar-lines . 0) (tool-bar-lines . 0)
      (width . 100))))
  (setq pop-up-frames  t)
  (setq minibuffer-frame-alist (append 1on1-minibuffer-frame-alist
                                       minibuffer-frame-alist))
  (if 1on1-minibuffer-frame
      (modify-frame-parameters 1on1-minibuffer-frame 1on1-minibuffer-frame-alist)
    (setq 1on1-minibuffer-frame
          (let ((after-make-frame-functions nil)) ; E.g. inhibit `fit-frame'.
            (make-frame 1on1-minibuffer-frame-alist))))
  (1on1-set-minibuffer-frame-width)
  (1on1-set-minibuffer-frame-top/bottom)
  (setq minibuffer-auto-raise t)
  (setq w32-grab-focus-on-raise    nil
        win32-grab-focus-on-raise  nil)) ; older name

(defun 1on1-display-*Completions*-frame (buf &optional args)
  "Display *Completions* buffer in its own frame.
`special-display-function' is used to do the actual displaying.
Completion input events are redirected to `1on1-minibuffer-frame'.
BUF and ARGS are the arguments to `special-display-function'."
  (let (return-window)
    (setq return-window (select-window
                         (funcall special-display-function buf args)))
    (raise-frame)
    (redirect-frame-focus (selected-frame) 1on1-minibuffer-frame)
    return-window))

(defun 1on1-set-minibuffer-frame-top/bottom ()
  "Set position of minibuffer frame.
Use `1on1-minibuffer-frame-top/bottom' if non-nil.
Else, place minibuffer at bottom of display."
  (condition-case nil
      (redisplay t)
    (error nil))                        ; Ignore e.g., killed buffers.
  (modify-frame-parameters
   1on1-minibuffer-frame
   `((top ,@ (- (* 2 (frame-char-height 1on1-minibuffer-frame)))))))

(defun 1on1-set-minibuffer-frame-width ()
  "Set width of minibuffer frame, in chars.
Set relative to `1on1-minibuffer-frame' char size and display size."
  (set-frame-width
   1on1-minibuffer-frame
   (/ (* 100 (x-display-pixel-width))
      (* 100 (frame-char-width 1on1-minibuffer-frame)))))

;; Last part of recipe for bug #8856:
(load-file "c:/drews-lisp-20/window-2011-06-19a-MARTIN.el")
(setq special-display-regexps '("[ ]?[*][^*]+[*]"))