colored fonts in batch mode

colored fonts in batch mode

[Carsten Dominik]

Hi,

I am trying to use emacs in batch mode to convert org-mode files to
HTML.  In the process, I would like to use font-lock to fontify some
snippets, and then use htmlize.el to convert the fontification into
HTML.

This works great in interactive work, when I actually have a window
system running.  However, in batch mode, Emacs seems to think that it
is displaying on a black-and-white device, so the fontification is much
poorer in this case.

Is there a way to run Emacs in batch mode (i.e. without any display at
all) and still make it use the fonts/colors for a full color display?

Thanks.

- Carsten

Re: colored fonts in batch mode

[Jason Rumney]

On May 8, 10:15 am, Carsten Dominik <domi...@science.uva.nl> wrote:

> This works great in interactive work, when I actually have a window
> system running.  However, in batch mode, Emacs seems to think that it
> is displaying on a black-and-white device, so the fontification is much
> poorer in this case.

Try putting the following in a file (batch-color.el) and loading it as
the first part of your batch operation:

(set-frame-parameter nil 'display-type 'color)
(defun display-color-cells (&optional display)
  "Fake hicolor display"
  65536)

Re: colored fonts in batch mode

[Carsten Dominik]

Jason Rumney <jasonrumney@gmail.com> writes:

> On May 8, 10:15 am, Carsten Dominik <domi...@science.uva.nl> wrote:
>
>> This works great in interactive work, when I actually have a window
>> system running.  However, in batch mode, Emacs seems to think that it
>> is displaying on a black-and-white device, so the fontification is much
>> poorer in this case.
>
> Try putting the following in a file (batch-color.el) and loading it as
> the first part of your batch operation:
>
> (set-frame-parameter nil 'display-type 'color)
> (defun display-color-cells (&optional display)
>   "Fake hicolor display"
>   65536)

Hmmm, I see where you are heading.  However, in batch mode,
set-frame-parameter does not seem to be defined as a function....  Also
a (require 'frame) does not seem to help.

Any further ideas?

Thanks!

- Carsten

Re: colored fonts in batch mode

[Eli Zaretskii]

> From: Carsten Dominik <dominik@science.uva.nl>
> Date: Thu, 08 May 2008 14:23:36 +0200
> Distribution: world
> 
> > (set-frame-parameter nil 'display-type 'color)
> > (defun display-color-cells (&optional display)
> >   "Fake hicolor display"
> >   65536)
> 
> Hmmm, I see where you are heading.  However, in batch mode,
> set-frame-parameter does not seem to be defined as a function....  Also
> a (require 'frame) does not seem to help.
> 
> Any further ideas?

How about using the --color=NUMBER command-line switch, does this
help in any way?  E.g., try with 8 as NUMBER.

I must say that what you are trying to do might simply be impossible
with Emacs, as Emacs uses frame-type specific methods to turn colors
on and off, so it needs to know what kind of frame is it dealing with.

IOW, you are trying to piggy-back on the Emacs display engine, so you
need to play by its rules.

Re: colored fonts in batch mode

[Dan Espen]

Eli Zaretskii <eliz@gnu.org> writes:

>> From: Carsten Dominik <dominik@science.uva.nl>
>> Date: Thu, 08 May 2008 14:23:36 +0200
>> Distribution: world
>> 
>> > (set-frame-parameter nil 'display-type 'color)
>> > (defun display-color-cells (&optional display)
>> >   "Fake hicolor display"
>> >   65536)
>> 
>> Hmmm, I see where you are heading.  However, in batch mode,
>> set-frame-parameter does not seem to be defined as a function....  Also
>> a (require 'frame) does not seem to help.
>> 
>> Any further ideas?
>
> How about using the --color=NUMBER command-line switch, does this
> help in any way?  E.g., try with 8 as NUMBER.
>
> I must say that what you are trying to do might simply be impossible
> with Emacs, as Emacs uses frame-type specific methods to turn colors
> on and off, so it needs to know what kind of frame is it dealing with.
>
> IOW, you are trying to piggy-back on the Emacs display engine, so you
> need to play by its rules.

I'm more familiar with XEmacs than emacs, but I think
the concept applies.

Rather using batch invocation wouldn't using the emacs
equivalent of "gnudoit" be a solution?
(gnudoit sends lisp commands to a running XEmacs.)

Re: colored fonts in batch mode

[Jason Rumney]

On May 8, 1:23 pm, Carsten Dominik <domi...@science.uva.nl> wrote:
> Jason Rumney <jasonrum...@gmail.com> writes:

> > (set-frame-parameter nil 'display-type 'color)
> > (defun display-color-cells (&optional display)
> >   "Fake hicolor display"
> >   65536)
>
> Hmmm, I see where you are heading.  However, in batch mode,
> set-frame-parameter does not seem to be defined as a function....  Also
> a (require 'frame) does not seem to help.

What version of Emacs are you using?

In both 22.2 and current CVS, set-frame-parameter works for me
(frame.el is dumped into Emacs, so functions it defines should always
be available).

I haven't actually tried htmlize with it to check that the faces are
defined as expected, but looking at face-spec-set-match-display, it
should cover the use of :class and :min-colors in face definitions.

Re: colored fonts in batch mode

[Johan Bockgård]

Carsten Dominik <dominik@science.uva.nl> writes:

> This works great in interactive work, when I actually have a window
> system running.  However, in batch mode, Emacs seems to think that it
> is displaying on a black-and-white device, so the fontification is
> much poorer in this case.

The easiest may be to define the faces explicitly:

  (set-face-attribute 'default nil :foreground "white" :background "blue")
  ;; etc.

-- 
Johan Bockgård

Re: colored fonts in batch mode

[Carsten Dominik]

Dan Espen <daneNO@MORE.mk.SPAMtelcordia.com> writes:

>
> I'm more familiar with XEmacs than emacs, but I think
> the concept applies.
>
> Rather using batch invocation wouldn't using the emacs
> equivalent of "gnudoit" be a solution?
> (gnudoit sends lisp commands to a running XEmacs.)

No, I don't think that would help.  This is an emacs progress on a
webserver that is updating our pages at orgmode.org.

OK, here is what I ended up doing:


- I created a CSS file that contains many emacs face definitions.  I
  grabbed these definitions during an interactive Emacs session, by
  creating a buffer that contained one letter with each available Emacs
  face.  Then I applied htmlize-region to this buffer, and copied the
  class definitions from the css file.  Pretty long list, but ok, I can
  clean it up if I need to.

   (with-temp-buffer
     (let ((fl (face-list))
   	(htmlize-css-name-prefix "org-")
   	(htmlize-output-type 'css)
   	f i)
       (while (setq f (pop fl)
   		 i (and f (face-attribute f :inherit)))
         (when (and (symbolp f) (or (not i) (not (listp i))))
   	(insert (org-add-props (copy-sequence "1") nil 'face f))))
       (htmlize-region (point-min) (point-max))))
   (switch-to-buffer "*html*")


- The batch process now runs htmlize not with inline-css as its method,
  but the css.  I can do this in any display, and even in batch mode,
  font-lock will still assign the correct face names to keywords in the
  buffer, and htmlize will pick up those font names rather than the
  display dependent specifications.


(defun org-export-htmlize-region-for-paste (beg end)
  "Convert the region to HTML, using htmlize.el.
This is much like `htmlize-region-for-paste', only that it uses
the settings define in the org-... variables."
  (let* ((htmlize-output-type 'css)
	 (htmlize-css-name-prefix
	  org-export-htmlize-css-font-prefix)
	 (htmlbuf (htmlize-region beg end)))
    (unwind-protect
	(with-current-buffer htmlbuf
	  (buffer-substring
	   (plist-get htmlize-buffer-places 'content-start)
	   (plist-get htmlize-buffer-places 'content-end)))
      (kill-buffer htmlbuf))))

- Now I can publish pages with source code with classes on all keywords,
  and because of the css file I have control over how things get
  displayed.  Pretty happy with that!

Thanks to everyone who replied, I did try a couple of the ideas, but in
the end the dependence in the current display is too deeply engraved in
the emacs internals, so this system is not easy to fool in a stable way.

- Carsten

Re: colored fonts in batch mode

[Carsten Dominik]

bojohan+news@dd.chalmers.se (Johan Bockgård) writes:

> Carsten Dominik <dominik@science.uva.nl> writes:
>
>> This works great in interactive work, when I actually have a window
>> system running.  However, in batch mode, Emacs seems to think that it
>> is displaying on a black-and-white device, so the fontification is
>> much poorer in this case.
>
> The easiest may be to define the faces explicitly:
>
>   (set-face-attribute 'default nil :foreground "white" :background "blue")
>   ;; etc.

Yes.  I ended up doing something in this direction, but differently.
See my other post.

Thanks.

- Carsten