buffer-list and desktop

buffer-list and desktop

[Matthias]

Hi,

Is there a ready-made command, or package to list buffers that will be
saved by desktop.el?

Thank you for your attention.
-- 
Matthias

Re: buffer-list and desktop

[Kevin Rodgers]

Matthias wrote:
 > Is there a ready-made command, or package to list buffers that will be
 > saved by desktop.el?

Here's a start:

(defun desktop-list-buffers ()
   "Return the list of buffers that `desktop-save' would save."
   (nreverse
    (apply 'nconc
           (mapcar (lambda (buffer)
                     (save-excursion
                       (set-buffer buffer)
                       (if (desktop-save-buffer-p (buffer-file-name)
                                                  (buffer-name)
                                                  major-mode)
                           (list buffer))))
                   (buffer-list)))))

-- 
Kevin Rodgers

Re: buffer-list and desktop

[Kevin Rodgers]

Kevin Rodgers wrote:
 > Here's a start:

Gotta get used to using with-current-buffer:

(defun desktop-list-buffers ()
   "Return the list of buffers that `desktop-save' would save."
   (nreverse
    (apply 'nconc
           (mapcar (lambda (buffer)
                     (with-current-buffer buffer
                       (if (desktop-save-buffer-p (buffer-file-name)
                                                  (buffer-name)
                                                  major-mode)
                           (list buffer))))
                   (buffer-list)))))

-- 
Kevin Rodgers

Re: buffer-list and desktop

[David Kastrup]

Kevin Rodgers <ihs_4664@yahoo.com> writes:

> Kevin Rodgers wrote:
>  > Here's a start:
>
> Gotta get used to using with-current-buffer:
>
> (defun desktop-list-buffers ()
>    "Return the list of buffers that `desktop-save' would save."
>    (nreverse
>     (apply 'nconc
>            (mapcar (lambda (buffer)
>                      (with-current-buffer buffer
>                        (if (desktop-save-buffer-p (buffer-file-name)
>                                                   (buffer-name)
>                                                   major-mode)
>                            (list buffer))))
>                    (buffer-list)))))

Actually, you are trying too hard to be smart: the code is rather
inefficient.  You'll get by better with

(defun desktop-list-buffers ()
  "..."
  (let ((lst))
    (dolist (buffer (buffer-list) lst)
       (with-current-buffer buffer
          (when (desktop-save-buffer-p ...)
             (push buffer lst))))))

This only has two variable bindings (lst and the list for dolist), and
none in the loop.

In contrast, your version binds and unbinds buffer fresh for every
iteration, and it needs a (slow) call to apply/nconc with a large
number of arguments.

-- 
David Kastrup, Kriemhildstr. 15, 44793 Bochum

Re: buffer-list and desktop

[Jesper Harder]

Kevin Rodgers <ihs_4664@yahoo.com> writes:

> Gotta get used to using with-current-buffer:
>
> (defun desktop-list-buffers ()
>   "Return the list of buffers that `desktop-save' would save."
>   (nreverse
>    (apply 'nconc
>           (mapcar (lambda (buffer)
>                     (with-current-buffer buffer
>                       (if (desktop-save-buffer-p (buffer-file-name)
>                                                  (buffer-name)
>                                                  major-mode)
>                           (list buffer))))
>                   (buffer-list)))))

Or if you don't mind requiring cl:

(delete-if-not
   (lambda (buf)
     (desktop-save-buffer-p (buffer-file-name buf) (buffer-name buf) 
			    (buffer-local-value 'major-mode buf)))
   (buffer-list))

-- 
Jesper Harder                                <http://purl.org/harder/>

Re: buffer-list and desktop

[David Kastrup]

Jesper Harder <harder@myrealbox.com> writes:

> Kevin Rodgers <ihs_4664@yahoo.com> writes:
>
>> Gotta get used to using with-current-buffer:
>>
>> (defun desktop-list-buffers ()
>>   "Return the list of buffers that `desktop-save' would save."
>>   (nreverse
>>    (apply 'nconc
>>           (mapcar (lambda (buffer)
>>                     (with-current-buffer buffer
>>                       (if (desktop-save-buffer-p (buffer-file-name)
>>                                                  (buffer-name)
>>                                                  major-mode)
>>                           (list buffer))))
>>                   (buffer-list)))))
>
> Or if you don't mind requiring cl:
>
> (delete-if-not
>    (lambda (buf)
>      (desktop-save-buffer-p (buffer-file-name buf) (buffer-name buf) 
> 			    (buffer-local-value 'major-mode buf)))
>    (buffer-list))

Still slow because of one bind/unbind per iteration.  If you want to
do it that way, anyway, you could avoid cl by using

(delq nil
  (mapcar
    (lambda (buf)
      (and (desktop-save-buffer-p ...)
           buf))
    (buffer-list)))

with hardly more effort.

-- 
David Kastrup, Kriemhildstr. 15, 44793 Bochum

Re: buffer-list and desktop

[Kevin Rodgers]

David Kastrup wrote:
 > Jesper Harder <harder@myrealbox.com> writes:
 >>Or if you don't mind requiring cl:

I do mind.  :-)

 >>(delete-if-not
 >>   (lambda (buf)
 >>     (desktop-save-buffer-p (buffer-file-name buf) (buffer-name buf)
 >>			    (buffer-local-value 'major-mode buf)))
 >>   (buffer-list))

buffer-local-value is not defined in Emacs 21.3.  Too bad, because
passing the buffer as an argument should be faster than using
with-current-buffer.

 > Still slow because of one bind/unbind per iteration.  If you want to
 > do it that way, anyway, you could avoid cl by using
 >
 > (delq nil
 >   (mapcar
 >     (lambda (buf)
 >       (and (desktop-save-buffer-p ...)
 >            buf))
 >     (buffer-list)))
 >
 > with hardly more effort.

Your first idea to just push each buffer that satisifies the predicate
on to a result list is better.  And I don't share your aversion to
variable bindings.  :-)

So here's what I've come up with.  The real problem I see is that the
buffer browsing commands (list-buffers and electric-buffer-list) don't
take the list of buffers as an argument, so you can't write new
desktop-save- versions of those commands that use the result of this
function.

(defun desktop-save-buffer-list ()
   "Return the list of buffers that `desktop-save' would save."
   (let ((buffer-list '()))
     (mapc (lambda (buffer)
             (with-current-buffer buffer
               (when (desktop-save-buffer-p (buffer-file-name)
                                            (buffer-name)
                                            major-mode)
                 (setq buffer-list (cons buffer buffer-list)))))
           (buffer-list))
     (nreverse buffer-list)))

-- 
Kevin Rodgers

Re: buffer-list and desktop

[Matthias]

Kevin Rodgers <ihs_4664@yahoo.com> wrote:

> (...) The real problem I see is that the buffer browsing commands
> (list-buffers and electric-buffer-list) don't take the list of
> buffers as an argument, so you can't write new desktop-save-
> versions of those commands that use the result of this function.

Exactly! May be one should change `list-buffers' so that it accept a
second optional argument, a list of buffers!!

Thank you very much Kevin, David and Jesper.
-- 
Matthias