Need help with eshell hack

Need help with eshell hack

[Mathias Dahl]

Inspired by `eev' I wanted to write a command that executes the current
line as a command in eshell. This is what I have:

(defun my-eshell-execute-current-line ()
  "Insert text of current line in eshell and execute."
  (interactive)
  (let ((command (buffer-substring
                  (save-excursion
                    (beginning-of-line)
                    (point))
                  (save-excursion
                    (end-of-line)
                    (point)))))
    (save-excursion
      (unless (get-buffer eshell-buffer-name)
        (eshell))
      (display-buffer eshell-buffer-name t)
      (set-buffer eshell-buffer-name)
      (end-of-buffer)
      (eshell-kill-input)
      (insert command)
      (eshell-send-input))))

It almost works. The problem is that when output from the command
reaches the bottom of the visible part of the eshell window, the window
isn't scrolled down to show the output.

Any idea on how to achieve this?

/Mathias

Re: Need help with eshell hack

[Mathias Dahl]

Mathias Dahl <mathias.dahl@gmail.com> writes:

> It almost works. The problem is that when output from the command
> reaches the bottom of the visible part of the eshell window, the
> window isn't scrolled down to show the output.

I let go of the `save-excursion' + `set-buffer' approach, in other words
being a bad boy, and got this that seems to work for me:

(defun my-eshell-execute-current-line ()
  "Insert text of current line in eshell and execute."
  (interactive)
  (let ((command (buffer-substring
                  (save-excursion
                    (beginning-of-line)
                    (point))
                  (save-excursion
                    (end-of-line)
                    (point)))))
    (let ((buf (current-buffer)))
      (unless (get-buffer eshell-buffer-name)
        (eshell))
      (display-buffer eshell-buffer-name t)
      (switch-to-buffer-other-window eshell-buffer-name)
      (end-of-buffer)
      (eshell-kill-input)
      (insert command)
      (eshell-send-input)
      (end-of-buffer)
      (switch-to-buffer-other-window buf))))

It annoys be however that I could not get it working without using
switch-to-buffer... The docstring says to avoid use it.

Oh well,

/Mathias

Re: Need help with eshell hack

[Kevin Rodgers]

Mathias Dahl wrote:
> Mathias Dahl <mathias.dahl@gmail.com> writes:
> 
>> It almost works. The problem is that when output from the command
>> reaches the bottom of the visible part of the eshell window, the
>> window isn't scrolled down to show the output.
> 
> I let go of the `save-excursion' + `set-buffer' approach, in other words
> being a bad boy, and got this that seems to work for me:
> 
> (defun my-eshell-execute-current-line ()
>   "Insert text of current line in eshell and execute."
>   (interactive)
>   (let ((command (buffer-substring
>                   (save-excursion
>                     (beginning-of-line)
>                     (point))
>                   (save-excursion
>                     (end-of-line)
>                     (point)))))

(buffer-substring (line-beginning-position) (line-end-position))

>     (let ((buf (current-buffer)))
>       (unless (get-buffer eshell-buffer-name)
>         (eshell))
>       (display-buffer eshell-buffer-name t)
>       (switch-to-buffer-other-window eshell-buffer-name)
>       (end-of-buffer)
>       (eshell-kill-input)
>       (insert command)
>       (eshell-send-input)
>       (end-of-buffer)
>       (switch-to-buffer-other-window buf))))
> 
> It annoys be however that I could not get it working without using
> switch-to-buffer... The docstring says to avoid use it.

(pop-to-buffer eshell-buffer-name)

-- 
Kevin Rodgers
Denver, Colorado, USA