Displaying a string as another one

Displaying a string as another one

[Marcin Borkowski]

Hi all,

I have a buffer with long lines, containing many instances of strings
"\\n" and "\\t" (i.e., a literal backslash followed by "n" or "t").  I'd
like Emacs to display them as a newline and a tab, respectively.  These
instances occur inside strings (i.e., between quotes, which delimit
strings in JavaScript).

I tried
(setq prettify-symbols-alist '(("\\n" . ?\n) ("\\t" . ?\t)))
but this does not seem to work inside strings.

I suspect font-lock could do it, but I'm not sure how (and frankly,
I don't have time now to do many experiments).

Does anyone have a ready-made solution?

TIA,

-- 
Marcin Borkowski
http://mbork.pl

Re: Displaying a string as another one

[Stefan Monnier]

> Does anyone have a ready-made solution?

You could start with something like

    (defun my-decode-\n-\t ()
      (font-lock-add-keywords nil
        '(("\\\\[nt]"
           (0 (my-apply-decode (match-beginning 0) (match-end 0)))))))

    (defun my-apply-decode (beg end)
      (when (= 0 (mod (save-excursion (goto-char beg)
                                      (skip-chars-backward "\\\\"))
                      2))
        `(face nil
          display ,(string (if (eq (char-before end) ?n) ?\n ?\t)))))

    (add-hook 'foo-mode-hook #'my-decode-\n-\t)


-- Stefan

Re: Displaying a string as another one

[Marcin Borkowski]

On 2020-03-16, at 16:58, Stefan Monnier <monnier@iro.umontreal.ca> wrote:

>> Does anyone have a ready-made solution?
>
> You could start with something like
>
>     (defun my-decode-\n-\t ()
>       (font-lock-add-keywords nil
>         '(("\\\\[nt]"
>            (0 (my-apply-decode (match-beginning 0) (match-end 0)))))))
>
>     (defun my-apply-decode (beg end)
>       (when (= 0 (mod (save-excursion (goto-char beg)
>                                       (skip-chars-backward "\\\\"))
>                       2))
>         `(face nil
>           display ,(string (if (eq (char-before end) ?n) ?\n ?\t)))))
>
>     (add-hook 'foo-mode-hook #'my-decode-\n-\t)

Thanks a lot.  This looks more complicated than I expected...  I'll
experiment with this and see how it works.

Best,

-- 
Marcin Borkowski
http://mbork.pl