Form to store/recover buffer modified state?

Form to store/recover buffer modified state?

[Joakim Hove]

Hello,

I have some buffer manipulating[1] functions which are wrapped in a
construct like this:

(let ((modified (buffer-modified-p)))
  ;;
  (lots of code)
  ;;
  (if (not modified) (set-buffer-modifed-p nil)))

To ensure that the buffer is not marked as modified when the function
has finished executing.  Is there a special form, i.e. resembling
(save-excursion ) to achieve this?


regards Joakim


[1] The manipulations in question are typically text properties,
    i.e. manipulations which should not be saved.



-- 
  /--------------------------------------------------------------------\
 / Joakim Hove  / hove@bccs.no  /  (55 5) 84076       |                 \
 | Unifob AS, Avdeling for Beregningsvitenskap (BCCS) | Stabburveien 18 |
 | CMU                                                | 5231 Paradis    |
 \ Thormøhlensgt.55, 5020 Bergen.                     | 55 91 28 18     /
  \--------------------------------------------------------------------/

Re: Form to store/recover buffer modified state?

[Jesper Harder]

Joakim Hove <hove@bccs.no> writes:

> I have some buffer manipulating[1] functions which are wrapped in a
> construct like this:
>
> (let ((modified (buffer-modified-p)))
>   ;;
>   (lots of code)
>   ;;
>   (if (not modified) (set-buffer-modifed-p nil)))
>
> To ensure that the buffer is not marked as modified when the function
> has finished executing.  Is there a special form, i.e. resembling
> (save-excursion ) to achieve this?

I don't think there's an existing special form.  But you can always
create you own macro that works like a special form.  Something like:

(defmacro save-modified (&rest body)
  (let ((temp (make-symbol "modified")))
    `(let ((,temp (buffer-modified-p)))
       (unwind-protect
	   (progn
	     ,@body)
	 (unless ,temp
	   (set-buffer-modified-p nil))))))

Re: Form to store/recover buffer modified state?

[Joakim Hove]

Jesper Harder <harder@myrealbox.com> writes:


> (defmacro save-modified (&rest body)
>   (let ((temp (make-symbol "modified")))
>     `(let ((,temp (buffer-modified-p)))
>        (unwind-protect
> 	   (progn
> 	     ,@body)
> 	 (unless ,temp
> 	   (set-buffer-modified-p nil))))))

Thanks a lot, it works like intended, but (e)lisp code containing the
"magic" characters "@", "," and "`" is beyond me. I will try to
decipher it and see what I can learn!

Thanks again :-)

Joakim

-- 
  /--------------------------------------------------------------------\
 / Joakim Hove  / hove@bccs.no  /  (55 5) 84076       |                 \
 | Unifob AS, Avdeling for Beregningsvitenskap (BCCS) | Stabburveien 18 |
 | CMU                                                | 5231 Paradis    |
 \ Thormøhlensgt.55, 5020 Bergen.                     | 55 91 28 18     /
  \--------------------------------------------------------------------/

Re: Form to store/recover buffer modified state?

[Jesper Harder]

Joakim Hove <hove@bccs.no> writes:

> Jesper Harder <harder@myrealbox.com> writes:
>
>> (defmacro save-modified (&rest body)
>>   (let ((temp (make-symbol "modified")))
>>     `(let ((,temp (buffer-modified-p)))
>>        (unwind-protect
>> 	   (progn
>> 	     ,@body)
>> 	 (unless ,temp
>> 	   (set-buffer-modified-p nil))))))
>
> Thanks a lot, it works like intended, but (e)lisp code containing the
> "magic" characters "@", "," and "`" is beyond me.

The backquote constructs aren't essential to the macro.  They just
make it easier to write (and read, IMHO).

You could also write the macro this way without using backquote:

(defmacro save-modified (&rest body)
  (let ((temp (make-symbol "modified")))
    (list 'let (list (list temp (list 'buffer-modified-p)))
	  (list 'unwind-protect
		(append '(progn)
		      body)
		(list 'unless temp
		      (list 'set-buffer-modified-p nil))))))

Re: Form to store/recover buffer modified state?

[Stefan Monnier]

>> (let ((modified (buffer-modified-p)))
>> ;;
>> (lots of code)
>> ;;
>> (if (not modified) (set-buffer-modifed-p nil)))

Note that it's recommended to use restore-buffer-modified-p
in such a case.


        Stefan