Adding font-lock keywords

Adding font-lock keywords

[Brendan Van Horn]

Greetings!  I spent some time reading FAQs and posts I could find and
I still seem to be missing something.  I'm trying to add some extra
keywords so that they are highlighted while editing.  Here is what I
came up with:

;; windows constants
(setq my-win32-constant-keywords
      (regexp-opt
       '("COINIT_MULTITHREADED" "ICC_COOL_CLASSES" "NULL"
"SW_SHOWDEFAULT"
	 "VT_BSTR" "VT_I4")))

(font-lock-add-keywords
 'c++-mode
 '((my-win32-constant-keywords . font-lock-constant-face)))

Where am I going wrong???

Thanks!
Brendan

Re: Adding font-lock keywords

[Glenn Morris]

Brendan Van Horn wrote:

> (setq my-win32-constant-keywords
>       (regexp-opt
>        '("COINIT_MULTITHREADED" "ICC_COOL_CLASSES" "NULL" "SW_SHOWDEFAULT"
> 	 "VT_BSTR" "VT_I4")))
>
> (font-lock-add-keywords
>  'c++-mode
>  '((my-win32-constant-keywords . font-lock-constant-face)))

Use of a single-quote ' prevents symbols from being evaluated.

Compare:

my-win32-constant-keywords

with

'my-win32-constant-keywords

by putting the cursor at the end of the line and using C-x C-e. What
you are doing is adding the symbol my-win32-constant-keywords to the
keywords list, rather than its value.

You could use

(font-lock-add-keywords
 'c++-mode
 `((,my-win32-constant-keywords . font-lock-constant-face)))

because ` acts like ' except that anything preceded by a comma gets
evaluated. Or you could use:

(font-lock-add-keywords
 'c++-mode
 (list
  (cons my-win32-constant-keywords font-lock-constant-face)))

Re: Adding font-lock keywords

[Brendan Van Horn]

Glenn Morris <gmorris+news@ast.cam.ac.uk> wrote...

> What you are doing is adding the symbol my-win32-constant-keywords
> to the keywords list, rather than its value.

Ahh...

> (font-lock-add-keywords
>  'c++-mode
>  `((,my-win32-constant-keywords . font-lock-constant-face)))

Just the ticket.  Here's is what I have that is (mostly) working:

(setq my-win32-constant-keywords
      (regexp-opt
       '("COINIT_MULTITHREADED" "ICC_COOL_CLASSES" "NULL"
	 "SW_SHOWDEFAULT" "VT_BSTR" "VT_ERROR" "VT_I4"
	 "vtEmpty" "vtError" "vtMissing")))

(defun my-add-keywords ()
  (font-lock-add-keywords 'c++-mode
   `(("@\\(?:TODO\\|todo\\)" . font-lock-warning-face)
     (,my-win32-constant-keywords . font-lock-constant-face))))
(add-hook 'c++-mode-hook 'my-add-keywords)
 
> because ` acts like ' except that anything preceded by a comma gets
> evaluated.

I see that now.  Thanks for the help!