count char in string [The Emacs Challenge Competition - round 2, with fallout]

count char in string [The Emacs Challenge Competition - round 2, with fallout]

[Emanuel Berg via Users list for the GNU Emacs text editor]

round 1:

  https://lists.gnu.org/archive/html/help-gnu-emacs/2020-10/msg00524.html

fallout:
  1. Daniel Martín (1 point)
  2. Emanuel Berg  (-2)

Yes, your read it right, incorrect answers are "awarded" -2 points.
This is like the Russian or Cuban Olympic/Amateur boxing program -
only gold counts!

But: doesn't that mean that people will be afraid to post? Again, in
the Russian and Cuban Olympic/Amateur boxing programs, we are not
concerned with people who are afraid...

round 2:

Very simple: we are looking for a function that returns the number of
occurrences of a char in a string.

Emanuel Berg's solution:

(require 'cl-lib)
(defun count-char-in-string (the-char str)
  (let ((c  (if (characterp the-char) the-char (string-to-char the-char)))
        (cs (string-to-list str)) )
    (cl-count c cs) ))
;; (count-char-in-string ?a "Emacs skills kills") ; 1

-- 
underground experts united
http://user.it.uu.se/~embe8573
https://dataswamp.org/~incal

Re: count char in string [The Emacs Challenge Competition - round 2, with fallout]

[Corwin Brust]

We who are about to be educated salute you ;)

On Tue, Oct 27, 2020 at 7:42 PM Emanuel Berg via Users list for the
GNU Emacs text editor <help-gnu-emacs@gnu.org> wrote:
>
> round 2:
>
> Very simple: we are looking for a function that returns the number of
> occurrences of a char in a string.

(defun count-char-in-string (string char)
     "Return the number of occurances of CHAR in STRING."
     (seq-count (apply-partially 'eq char)
            (seq-into string 'list)))

(count-char-in-string "hii" ?I) ;; ⇒ 2

Cheers!
Corwin

Re: count char in string [The Emacs Challenge Competition - round 2, with fallout]

[Noam Postavsky]

On Wed, 28 Oct 2020 at 04:04, Corwin Brust <corwin@bru.st> wrote:

>      (seq-count (apply-partially 'eq char)
>             (seq-into string 'list)))

You don't need the seq-into, just pass string directly to seq-count.

Re: count char in string [The Emacs Challenge Competition - round 2, with fallout]

[Corwin Brust]

On Wed, Oct 28, 2020, 12:19 PM Noam Postavsky <npostavs@gmail.com> wrote:

> You don't need the seq-into, just pass string directly to seq-count.


Oh -- nice, thanks Noam!

Re: count char in string [The Emacs Challenge Competition - round 2, with fallout]

[Emanuel Berg via Users list for the GNU Emacs text editor]

Corwin Brust wrote:

>> You don't need the seq-into, just pass string directly to
>> seq-count.
>
> Oh -- nice, thanks Noam!

So this is the best solution, right?

(require 'seq)

(defun count-char-in-string (str char)
  (seq-count (lambda (c) (= c char)) str) )
  
;; (count-char-in-string "Emacs skills kills" ?a) ; 1
;; (count-char-in-string "Emacs skills kills" ?A) ; 0
;; (count-char-in-string "Emacs skills kills" ?l) ; 4


https://dataswamp.org/~incal/emacs-init/count.el

-- 
underground experts united
http://user.it.uu.se/~embe8573
https://dataswamp.org/~incal

Re: count char in string [The Emacs Challenge Competition - round 2, with fallout]

[Emanuel Berg via Users list for the GNU Emacs text editor]

Corwin Brust wrote:

> (defun count-char-in-string (string char)
>      "Return the number of occurances of CHAR in STRING."
>      (seq-count (apply-partially 'eq char)
>             (seq-into string 'list)))

OK, that looks better than mine so I take it. But you have to
require seq or the byte compiler will complain.

(require 'seq)

(defun count-char-in-string (string char)
  (seq-count (apply-partially 'eq char) (seq-into string 'list)) )

;; (count-char-in-string "Emacs skills kills" ?a) ; 1

> (count-char-in-string "hii" ?I) ;; ⇒ 2

That's 0 :) because it is case sensitive (as it should)

-- 
underground experts united
http://user.it.uu.se/~embe8573
https://dataswamp.org/~incal

Re: count char in string [The Emacs Challenge Competition - round 2, with fallout]

[Benjamín Buccianti]

Emanuel Berg via Users list for the GNU Emacs text editor <help-gnu-emacs@gnu.org> writes:

>
>> (count-char-in-string "hii" ?I) ;; ⇒ 2
>
> That's 0 :) because it is case sensitive (as it should)

Would be awesome to provide a few simple tests?

We can make this as a web similar to vim-golf?

Re: count char in string [The Emacs Challenge Competition - round 2, with fallout]

[Benjamín Buccianti]

> round 2:
>
> Very simple: we are looking for a function that returns the number of
> occurrences of a char in a string.
>
My solution!

(defun count-char-in-string (the-char str)
  (seq-reduce (lambda (counter next)
		(+ counter (if (eq the-char next) 1 0)))
	      str
	      0))

I really like this kind of things! Keep doing it! I learn a lot from other's answers.

Cheers!

Re: count char in string [The Emacs Challenge Competition - round 2, with fallout]

[Stephen Berman]

On Wed, 28 Oct 2020 01:42:13 +0100 Emanuel Berg via Users list for the GNU Emacs text editor <help-gnu-emacs@gnu.org> wrote:

> round 2:
>
> Very simple: we are looking for a function that returns the number of
> occurrences of a char in a string.

cl-count? seq-count? seq-reduce? KISS!

(defun count-char-in-string (char str)
  "Return number of occurrences of character CHAR in string STR."
  (let ((count 0))
    (dotimes (i (length str) count)
      (when (eq char (aref str i))
	(setq count (1+ count))))))

Steve Berman

RE: count char in string [The Emacs Challenge Competition - round 2, with fallout]

[Drew Adams]

> cl-count? seq-count? seq-reduce? KISS!
> 
> (defun count-char-in-string (char str)
>   "Return number of occurrences of character CHAR in string STR."
>   (let ((count 0))
>     (dotimes (i (length str) count)
>       (when (eq char (aref str i))
> 	(setq count (1+ count))))))

+1.

Or just (cl-incf count) at the end, if you're
loading `cl-lib.el' anyway, for other reasons.

Re: count char in string [The Emacs Challenge Competition - round 2, with fallout]

[Patrick McAllister]

On Wed, Oct 28 2020, Emanuel Berg via Users list for the GNU Emacs text editor wrote:

> round 2:
>
> Very simple: we are looking for a function that returns the number of
> occurrences of a char in a string.
>
> Emanuel Berg's solution:
>
> (require 'cl-lib)
> (defun count-char-in-string (the-char str)
>   (let ((c  (if (characterp the-char) the-char (string-to-char the-char)))
>         (cs (string-to-list str)) )
>     (cl-count c cs) ))
> ;; (count-char-in-string ?a "Emacs skills kills") ; 1

I had this lying around:

(defun count-char-in-string (char string)
  "Count CHARS in STRING (after normalizing it)."
  (length
   (cl-remove-if-not
    (lambda (x) (= char x))
    (append (ucs-normalize-NFKC-string string) nil))))

-- 
Patrick

Re: count char in string [The Emacs Challenge Competition - round 2, with fallout]

[Leo Butler]

Patrick McAllister <pma@rdorte.org> writes:

> ********************************************************
> Caution: This message was sent from outside the University of Manitoba.
> ********************************************************
>
> On Wed, Oct 28 2020, Emanuel Berg via Users list for the GNU Emacs text editor wrote:
>
>> round 2:
>>
>> Very simple: we are looking for a function that returns the number of
>> occurrences of a char in a string.
>>
>> Emanuel Berg's solution:
>>
>> (require 'cl-lib)
>> (defun count-char-in-string (the-char str)
>>   (let ((c  (if (characterp the-char) the-char (string-to-char the-char)))
>>         (cs (string-to-list str)) )
>>     (cl-count c cs) ))
>> ;; (count-char-in-string ?a "Emacs skills kills") ; 1

Here is a solution for interactive use that is far more flexible than
just counting characters.

I use the following a lot when editing documents with a maximum
character count:

M-< M-x replace-regexp [^[:space:]] \& RET

Or, since I bind replace-regexp to C-x a r,

M-< C-x a r [^[:space:]] \& RET

I just did that and the mini-buffer informed me there were 1232
non-space characters in the buffer. 

Leo

Re: count char in string [The Emacs Challenge Competition - round 2, with fallout]

[Jean Louis]

* Leo Butler <leo.butler@umanitoba.ca> [2020-10-29 21:08]:
> Patrick McAllister <pma@rdorte.org> writes:
> 
> > ********************************************************
> > Caution: This message was sent from outside the University of Manitoba.
> > ********************************************************
> >
> > On Wed, Oct 28 2020, Emanuel Berg via Users list for the GNU Emacs text editor wrote:
> >
> >> round 2:
> >>
> >> Very simple: we are looking for a function that returns the number of
> >> occurrences of a char in a string.
> >>
> >> Emanuel Berg's solution:
> >>
> >> (require 'cl-lib)
> >> (defun count-char-in-string (the-char str)
> >>   (let ((c  (if (characterp the-char) the-char (string-to-char the-char)))
> >>         (cs (string-to-list str)) )
> >>     (cl-count c cs) ))
> >> ;; (count-char-in-string ?a "Emacs skills kills") ; 1
> 
> Here is a solution for interactive use that is far more flexible than
> just counting characters.
> 
> I use the following a lot when editing documents with a maximum
> character count:
> 
> M-< M-x replace-regexp [^[:space:]] \& RET
> 
> Or, since I bind replace-regexp to C-x a r,
> 
> M-< C-x a r [^[:space:]] \& RET
> 
> I just did that and the mini-buffer informed me there were 1232
> non-space characters in the buffer. 
> 
> Leo
>

M-x how-many


-- 
Jean Louis

Re: count char in string [The Emacs Challenge Competition - round 2, with fallout]

[Leo Butler]

Jean Louis <bugs@gnu.support> writes:

> M-x how-many

Nice. Thank you. That beats all the solutions offered, imo.

Leo

Re: count char in string [The Emacs Challenge Competition - round 2, with fallout]

[Joost Kremers]

On Fri, Oct 30 2020, Leo Butler wrote:
> Jean Louis <bugs@gnu.support> writes:
>
>> M-x how-many
>
> Nice. Thank you. That beats all the solutions offered, imo.

Except that the original challenge was to count characters in a string, but
`how-many` counts occurrences in the current buffer. ;-)

-- 
Joost Kremers
Life has its moments

Re: count char in string [The Emacs Challenge Competition - round 2, with fallout]

[Jean Louis]

* Leo Butler <leo.butler@umanitoba.ca> [2020-10-30 14:10]:
> Jean Louis <bugs@gnu.support> writes:
> 
> > M-x how-many
> 
> Nice. Thank you. That beats all the solutions offered, imo.

It may look handy but in background it is very complex, so it does not
beat.

-- 
Jean Louis