Re: Putting == before and after selected text

[Andreas Politz <politza@fh-trier.de>]

Merciadri Luca <Luca.Merciadri@student.ulg.ac.be> writes:

> Hi,
>
> I would like some key to a command. This is not difficult, but this
> command should, once it is executed on some text, put `==' before the
> text (on the line before) and `==' after the text (on the line after).
>
> How could I do this?

How about this ?

(defun wrap-region-in-== (beg end)
  "Wrap lines contained in region with \"==\" marker.

Interactively, if region is not active, operate on prefix-arg
lines around point."
  (interactive
   (if (use-region-p)
       (list (region-beginning) (region-end))
     (let ((arg (prefix-numeric-value current-prefix-arg)))
       (save-excursion
         (if (< arg 0)
             (forward-line)
           (beginning-of-line))
         (sort (list (point) (progn (forward-line arg) (point)))
               '<)))))
  (save-excursion
    (goto-char beg)
    (beginning-of-line)
    (insert "==")
    (newline)
    (goto-char end)
    (or (bolp) (forward-line 1))
    (insert "==")
    (newline)))


-ap