Checking parameters

Checking parameters

[Cecil Westerhof]

I am new to Emacs and lisp.
What is the best way to check parameters and do error handling when they are
not correct?

I have the following function:
(defun getHours(time)
  (interactive "sHH:MM: ")
  (let ((timelist (split-string time ":")))
    (+
      (string-to-number (car timelist))
      (/
        (string-to-number (cadr timelist))
        60.0
      )
    )
  )
)

How do I check that there is exactly one parameter? And how do I check the
format and give an error that works in interactive and normal mode?
For example when I give
    (getHours "0:120")
I get
    2.0
How should I generate an error/exception?

Re: Checking parameters

[Lennart Borgman (gmail)]

Cecil Westerhof wrote:
> I am new to Emacs and lisp.
> What is the best way to check parameters and do error handling when they are
> not correct?
> 
> I have the following function:
> (defun getHours(time)
>   (interactive "sHH:MM: ")
>   (let ((timelist (split-string time ":")))
>     (+
>       (string-to-number (car timelist))
>       (/
>         (string-to-number (cadr timelist))
>         60.0
>       )
>     )
>   )
> )
> 
> How do I check that there is exactly one parameter? And how do I check the
> format and give an error that works in interactive and normal mode?
> For example when I give
>     (getHours "0:120")
> I get
>     2.0
> How should I generate an error/exception?


You probably want to use the most simple way, something like

(defun get-hours(time)
   (interactive "sHH:MM: ")
   (let ((timelist (split-string time ":"))
         (errmsg "Time format error"))
     (unless (= (length (nth 1 timelist)) 2)
       (error errmsg))
     (+
       (string-to-number (nth 0 timelist))
       (/
         (string-to-number (nth 1 timelist))
         60.0))))

Re: Checking parameters

[Lennart Borgman (gmail)]

Lennart Borgman (gmail) wrote:
> You probably want to use the most simple way, something like
> 
> (defun get-hours(time)
>   (interactive "sHH:MM: ")
>   (let ((timelist (split-string time ":"))
>         (errmsg "Time format error"))
>     (unless (= (length (nth 1 timelist)) 2)
>       (error errmsg))
>     (+
>       (string-to-number (nth 0 timelist))
>       (/
>         (string-to-number (nth 1 timelist))
>         60.0))))

And this is better:

(defun get-hours(time)
   (interactive "sHH:MM: ")
   (let ((timelist (split-string time ":"))
         (errmsg "Time format error"))
     (save-match-data
       (unless (string-match "\\`[0-9]+:[0-9]\\{2\\}\\'" time)
         (error errmsg)))
     (+
      (string-to-number (nth 0 timelist))
      (/
       (string-to-number (nth 1 timelist))
       60.0))))

Re: Checking parameters

[Tim X]

Cecil Westerhof <dummy@dummy.nl> writes:

> I am new to Emacs and lisp.
> What is the best way to check parameters and do error handling when they are
> not correct?
>
> I have the following function:
> (defun getHours(time)
>   (interactive "sHH:MM: ")
>   (let ((timelist (split-string time ":")))
>     (+
>       (string-to-number (car timelist))
>       (/
>         (string-to-number (cadr timelist))
>         60.0
>       )
>     )
>   )
> )
>
> How do I check that there is exactly one parameter? And how do I check the
> format and give an error that works in interactive and normal mode?
> For example when I give
>     (getHours "0:120")
> I get
>     2.0
> How should I generate an error/exception?
>

Emacs will throw an error if the function is called with the wrong number of
arguments. 

There is already a reply that shows a simple way to check for the correct
string format using a regexp. However, if you want to get a bit more
adventurous and you would like a function that can tell the user the arguement
is invalid and give them another opportunity to enter a correctly formatted
argument, you might want to use a function instead of the prompt sring. This
function can then prompt the user for input, check that it is valid and if it
is, just returns the values as a list (which may only have one element if thats
all that is required). If the value the user entered was not a valid format,
the function can print an error message, possibly explaining why the users
input was no good and then prompt again to give the user another go. 

While this may take more work, it can be nicer for the end user. It can
sometimes also make your code look a bit cleaner as you can put the arguement
error checking off in its own function, rather than have it cluttering up the
main body of your function. 

for example (untested)

(defun time-prompt ()
  "Prompt for a valid time string HH:MM."
  (let (prompt-str)
    (setq prompt-str (read-from-minibuffer "Time HH:MM: "))
    (while (not (string-match "^[0-9]+:[0-5][0-9]$" prompt-str))
      (message "Bad time format. Must be HH:MM")
      (setq prompt-str (read-from-minibuffer "Time HH:MM: ")))
    (list prompt-str)))

(defun getHours(time)
  (interactive time-prompt)
  ....

tim

-- 
tcross (at) rapttech dot com dot au

Re: Checking parameters

[Nikolaj Schumacher]

"Lennart Borgman (gmail)" <lennart.borgman@gmail.com> wrote:

> Cecil Westerhof wrote:
>> I am new to Emacs and lisp.
>> What is the best way to check parameters and do error handling when they are
>> not correct?
>
> You probably want to use the most simple way, something like

>       (error errmsg))

You should also add the error message to `debug-ignored-errors' if you
use the debugger.  Otherwise you start debugging every time you input
malformed data.


regards,
Nikolaj Schumacher

Re: Checking parameters

[Cecil Westerhof]

Lennart Borgman (gmail) wrote:
> (defunregulars(time)
>    (interactive "sHH:MM: ")
>    (let ((timelist (split-string time ":"))
>          (errmsg "Time format error"))
>      (save-match-data
>        (unless (string-match "\\`[0-9]+:[0-9]\\{2\\}\\'" time)
>          (error errmsg)))
>      (+
>       (string-to-number (nth 0 timelist))
>       (/
>        (string-to-number (nth 1 timelist))
>        60.0))))

Works like a charm. I only changed the regular expression to
        "\\`[0-9]\\{1,2\\}:[0-9]\\{2\\}\\'"

Re: Checking parameters

[Cecil Westerhof]

Tim X wrote:
>> I am new to Emacs and lisp.
>> What is the best way to check parameters and do error handling when they
>> are not correct?
> 
> Emacs will throw an error if the function is called with the wrong number
> of arguments.

Okay, I do not have to take care of that. ;-}


> However, if you want to get a bit more
> adventurous and you would like a function that can tell the user the
> arguement is invalid and give them another opportunity to enter a
> correctly formatted argument, you might want to use a function instead of
> the prompt sring. 

Not at the moment, I am just starting. Furthermore, the function shall
mostly be used non-interactively.
But thanks for the thought.

Re: Checking parameters

[don provan]

"Lennart Borgman (gmail)" <lennart.borgman@gmail.com> writes:

> And this is better:
>
> (defun get-hours(time)
>    (interactive "sHH:MM: ")
>    (let ((timelist (split-string time ":"))
>          (errmsg "Time format error"))
>      (save-match-data
>        (unless (string-match "\\`[0-9]+:[0-9]\\{2\\}\\'" time)
>          (error errmsg)))
>      (+
>       (string-to-number (nth 0 timelist))
>       (/
>        (string-to-number (nth 1 timelist))
>        60.0))))

Go all the way:

(defun get-hours(time)
   (interactive "sHH:MM: ")
   (save-match-data
     (unless (string-match "\\`\\([0-9]+\\):\\([0-9]\\{2\\}\\)\\'" time)
       (error "Time format error"))
     (+
      (string-to-number (match-string 1 time))
      (/
       (string-to-number (match-string 2 time))
       60.0))))

-don