Defining minor mode with minor-mode condition

Defining minor mode with minor-mode condition

[Christopher Dimech]

Is it valid to define a minor mode "crucibulum-minor-mode" and then
have a "when" condition using crucibulum-minor-mode inside of it?

Regards
Christopher

;;;###autoload
(define-minor-mode crucibulum-minor-mode
  "Minor mode for assisting with superior & inferior typeface."
  :init-value nil
  :global nil
  :lighter " Crucibulum"

  (when crucibulum-minor-mode
    (enable-texcom-typeface)
    (enable-ricci-notation)) )


---------------------
Christopher Dimech
General Administrator - Naiad Informatics - GNU Project (Geocomputation)
- Geophysical Simulation
- Geological Subsurface Mapping
- Disaster Preparedness and Mitigation
- Natural Resource Exploration and Production
- Free Software Advocacy

Re: Defining minor mode with minor-mode condition

[Emanuel Berg via Users list for the GNU Emacs text editor]

Christopher Dimech wrote:

> Is it valid to define a minor mode "crucibulum-minor-mode"
> and then have a "when" condition using crucibulum-minor-mode
> inside of it?

Yes, you can have an `if' also if you need to disable stuff
when it is disabled...

-- 
underground experts united
https://dataswamp.org/~incal

Re: Defining minor mode with minor-mode condition

[Joost Kremers]

On Tue, May 04 2021, Christopher Dimech wrote:
> Is it valid to define a minor mode "crucibulum-minor-mode" and then
> have a "when" condition using crucibulum-minor-mode inside of it?
>
> Regards
> Christopher
>
> ;;;###autoload
> (define-minor-mode crucibulum-minor-mode
>   "Minor mode for assisting with superior & inferior typeface."
>   :init-value nil
>   :global nil
>   :lighter " Crucibulum"
>
>   (when crucibulum-minor-mode
>     (enable-texcom-typeface)
>     (enable-ricci-notation)) )

Yes, AFAIK it's the normal way of doing this. Note that what you're defining
with `define-minor-mode` is a function with the name `crucibulum-minor-mode`
*plus* a variable of the same name.

When executed, the function `crucibulum-minor-mode` runs the code in the body of
the `define-minor-mode`, but before that, it does some other stuff, among which
is setting the variable `crucibulum-minor-mode`. So that's why this code works.

Note that when `define-minor-mode` is executed, it does *not* run the code in
its body. It just uses it to construct the function `crucibulum-minor-mode`.

Note also that the normal form is not with a `when` but with an `if`, since
normally you'll also want to add code to disable the minor mode. So it would
look something like:

```
;;;###autoload
(define-minor-mode crucibulum-minor-mode
  "Minor mode for assisting with superior & inferior typeface."
  :init-value nil
  :global nil
  :lighter " Crucibulum"
  
  (if crucibulum-minor-mode
      (progn
        (enable-texcom-typeface)
        (enable-ricci-notation))
    (disable-texcom-typeface)
    (disable-ricci-notation)))
```



-- 
Joost Kremers
Life has its moments

Re: Defining minor mode with minor-mode condition

[Emanuel Berg via Users list for the GNU Emacs text editor]

Joost Kremers wrote:

> Note also that the normal form is not with a `when` but with
> an `if`, since normally you'll also want to add code to
> disable the minor mode

Right, the minor mode itself is actually disabled even without
it including the keymap and possibly some other things but yes
whatever isn't reset or deallocated or whatever should be put
there...

-- 
underground experts united
https://dataswamp.org/~incal

Re: Defining minor mode with minor-mode condition

[Stefan Monnier]

> ;;;###autoload
> (define-minor-mode crucibulum-minor-mode
>   "Minor mode for assisting with superior & inferior typeface."
>   :init-value nil
>   :global nil
>   :lighter " Crucibulum"
>   
>   (if crucibulum-minor-mode
>       (progn
>         (enable-texcom-typeface)
>         (enable-ricci-notation))
>     (disable-texcom-typeface)
>     (disable-ricci-notation)))

[ Of course those `:foo nil` keyword arguments are redundant.  ]
I actually often find it convenient to unconditionally "disable" first:

    (define-minor-mode crucibulum-minor-mode
      "Minor mode for assisting with superior & inferior typeface."
      :lighter " Crucibulum"
      (disable-texcom-typeface)
      (disable-ricci-notation)
      (when crucibulum-minor-mode
        (enable-texcom-typeface)
        (enable-ricci-notation)))

the advantage is to avoid problems where, say, `enable-texcom-typeface`
is not idempotent, so if you call (crucibulum-minor-mode 1) several times
you might end up with multiple copies of the same thing added to a list.


        Stefan

Re: Defining minor mode with minor-mode condition

[Emanuel Berg via Users list for the GNU Emacs text editor]

Stefan Monnier wrote:

> I actually often find it convenient to unconditionally
> "disable" first:
>
>     (define-minor-mode crucibulum-minor-mode
>       "Minor mode for assisting with superior & inferior typeface."
>       :lighter " Crucibulum"
>       (disable-texcom-typeface)
>       (disable-ricci-notation)
>       (when crucibulum-minor-mode
>         (enable-texcom-typeface)
>         (enable-ricci-notation)))
>
> the advantage is to avoid problems where, say,
> `enable-texcom-typeface` is not idempotent, so if you call
> (crucibulum-minor-mode 1) several times you might end up
> with multiple copies of the same thing added to a list.

Good!

What about one function to enable all and one to disable all?

No - then these functions can be called from the outside which
will/can add confusion, and worse, enable some of the minor
mode functionality but not actually enabling the minor
mode itself!

-- 
underground experts united
https://dataswamp.org/~incal

Re: Defining minor mode with minor-mode condition

[Christopher Dimech]

> Sent: Wednesday, May 05, 2021 at 12:52 AM
> From: "Stefan Monnier" <monnier@iro.umontreal.ca>
> To: help-gnu-emacs@gnu.org
> Subject: Re: Defining minor mode with minor-mode condition
>
> > ;;;###autoload
> > (define-minor-mode crucibulum-minor-mode
> >   "Minor mode for assisting with superior & inferior typeface."
> >   :init-value nil
> >   :global nil
> >   :lighter " Crucibulum"
> >
> >   (if crucibulum-minor-mode
> >       (progn
> >         (enable-texcom-typeface)
> >         (enable-ricci-notation))
> >     (disable-texcom-typeface)
> >     (disable-ricci-notation)))
>
> [ Of course those `:foo nil` keyword arguments are redundant.  ]
> I actually often find it convenient to unconditionally "disable" first:
>
>     (define-minor-mode crucibulum-minor-mode
>       "Minor mode for assisting with superior & inferior typeface."
>       :lighter " Crucibulum"
>       (disable-texcom-typeface)
>       (disable-ricci-notation)
>       (when crucibulum-minor-mode
>         (enable-texcom-typeface)
>         (enable-ricci-notation)))
>
> the advantage is to avoid problems where, say, `enable-texcom-typeface`
> is not idempotent, so if you call (crucibulum-minor-mode 1) several times
> you might end up with multiple copies of the same thing added to a list.
> - Stefan

You make a very good point

>
>
>