Macro expansion containing ‘interactive’

Macro expansion containing ‘interactive’

[Marcus Harnisch]

In an attempt to create a compatibility wrapper for the new optional 
mode list parameter of ‘interactive’ I am facing difficulties. The 
definition looks like this:

   (defmacro foo--interactive (&optional arg-descriptor)
     "Compatibility wrapper to support `interactive' with additional
   MODE parameter (Emacs 28+)."
     ;; https://lars.ingebrigtsen.no/2021/02/16/command-discovery-in-emacs/
     (if (and (featurep 'emacs)
              (>= emacs-major-version 28))
         `(interactive ,arg-descriptor foo-mode)
       `(interactive ,arg-descriptor)))

According to ‘(macroexpand '(foo--interactive "bar"))’ the expansion 
itself seems to work. However, I still see all of foo-mode's interactive 
functions being completed with ‘M-x foo TAB’ from buffer ‘*scratch*’ 
(which is not in ‘foo-mode’).

The Emacs process itself is started with:

   emacs -l foo-mode.el -Q

Any ideas how to debug/fix this?

Thanks,
Marcus

Re: Macro expansion containing ‘interactive’

[Stefan Monnier via Users list for the GNU Emacs text editor]

> In an attempt to create a compatibility wrapper for the new optional mode
> list parameter of ‘interactive’ I am facing difficulties. The definition
> looks like this:

`interactive` is not a special form.  Just like docstrings, it's a part
of the syntax of `lambda`, so you need to define a `foo-lambda` if you
want it to work reliably.


        Stefan

Re: Macro expansion containing ‘interactive’

[Lars Ingebrigtsen]

Stefan Monnier via Users list for the GNU Emacs text editor
<help-gnu-emacs@gnu.org> writes:

>> In an attempt to create a compatibility wrapper for the new optional mode
>> list parameter of ‘interactive’ I am facing difficulties. The definition
>> looks like this:
>
> `interactive` is not a special form.  Just like docstrings, it's a part
> of the syntax of `lambda`, so you need to define a `foo-lambda` if you
> want it to work reliably.

Yup.  When doing code that needs to be backwards-compatible here, it's
better to use a declare form instead:

(defun foo ()
  (declare (modes dired-mode))
  (interactive)
  ...)

-- 
(domestic pets only, the antidote for overdose, milk.)
   bloggy blog: http://lars.ingebrigtsen.no

RE: [External] : Re: Macro expansion containing ‘interactive’

[Drew Adams]

> >> In an attempt to create a compatibility wrapper for the new optional mode
> >> list parameter of ‘interactive’ I am facing difficulties. The definition
> >> looks like this:
> >
> > `interactive` is not a special form.  Just like docstrings, it's a part
> > of the syntax of `lambda`, so you need to define a `foo-lambda` if you
> > want it to work reliably.
> 
> Yup.  When doing code that needs to be backwards-compatible here, it's
> better to use a declare form instead:
> 
> (defun foo ()
>   (declare (modes dired-mode))
>   (interactive)
>   ...)

Are you sure that that modes `declare' form is
backward-compatible with, say, Emacs 20?  This
is the only definition of `declare' in Emacs 20,
and it's in `cl-macs.el' - i.e., a (primitive)
emulation of Common Lisp's `declare':

(defmacro declare (&rest specs)
  (if (cl-compiling-file)
      (while specs
	(if (listp cl-declare-stack)
          (cl-push (car specs)
        cl-declare-stack))
	(cl-do-proclaim (cl-pop specs) nil)))
  nil)

Re: [External] : Re: Macro expansion containing ‘interactive’

[Stefan Monnier]

> Are you sure that that modes `declare' form is
> backward-compatible with, say, Emacs 20?

`declare` was added in Emacs-21, so I don't think that would work.
But packages which care a bout Emacs<21 are pretty rare nowadays.


        Stefan

Re: Macro expansion containing ‘interactive’

[Marcus Harnisch]

Hi Lars

On 19/08/2021 15.37, Lars Ingebrigtsen wrote:
> Yup.  When doing code that needs to be backwards-compatible here, it's
> better to use a declare form instead:

Indeed, the code has to be backwards-compatible to some not-too-distant 
past.

> (defun foo ()
>    (declare (modes dired-mode))
>    (interactive)
>    ...)

This, literally? Doesn't seem to work here. Steps to reproduce:

1. Start ‘emacs -Q’

2. In ‘*scratch*’ buffer eval

    (defun foo ()
      (declare (modes dired-mode))
      (interactive)
      (message "foo"))

3. Type ‘M-x fo TAB’ and notice that ‘foo’ gets listed among all other 
completion candidates.

4. The ‘eww’ example from you blog doesn't seem to work for me either. 
Before loading ‘eww.el’, only autoloaded functions are listed, and after 
loading the command ‘M-x eww TAB’ lists all sorts of different commands 
while in ‘*scratch*’.

Did I miss anything? Any special completion config needed?

Cheers,
Marcus

Re: Macro expansion containing ‘interactive’

[Lars Ingebrigtsen]

Marcus Harnisch <mh-gmane@online.de> writes:

> 3. Type ‘M-x fo TAB’ and notice that ‘foo’ gets listed among all other
> completion candidates.

You need

(setq read-extended-command-predicate 'command-completion-default-include-p)


-- 
(domestic pets only, the antidote for overdose, milk.)
   bloggy blog: http://lars.ingebrigtsen.no

Re: Macro expansion containing ‘interactive’

[Marcus Harnisch]

On 25/08/2021 13.06, Lars Ingebrigtsen wrote:
> (setq read-extended-command-predicate 'command-completion-default-include-p)

That did it, thanks!

Re: Macro expansion containing ‘interactive’

[Michael Heerdegen]

Stefan Monnier via Users list for the GNU Emacs text editor
<help-gnu-emacs@gnu.org> writes:

> `interactive` is not a special form.

C-h f says it is a special form.

Must be a special special form then ;-)

Michael.

Re: Macro expansion containing ‘interactive’

[Stefan Monnier via Users list for the GNU Emacs text editor]

Michael Heerdegen [2021-08-19 16:51:35] wrote:
> Stefan Monnier via Users list for the GNU Emacs text editor
> <help-gnu-emacs@gnu.org> writes:
>> `interactive` is not a special form.
> C-h f says it is a special form.
> Must be a special special form then ;-)

Well, it's *also* a special form, but one that just ignores its args and
returns nil.  It doesn't "store its arg in the surrounding function".


        Stefan