Re: help reading assembly code

[pmlists@free.fr (Peter Münster)]

On Mon, Oct 24 2011, Andrea Crotti wrote:

> For example it would be nice to have some function which shows me a
> reference documentation given the operator.

Hello,

If you know how to build the right url to the documentation of a given
operator, you can just replace the google url with the right one in the
following code:

--8<---------------cut here---------------start------------->8---
(defun pm/region-or-word (prompt)
  "Read a string from the minibuffer, prompting with PROMPT.
If `transient-mark-mode' is non-nil and the mark is active,
it defaults to the current region, else to the word at or before
point. This function returns a list (string) for use in `interactive'."
  (list (read-string prompt (or (and transient-mark-mode mark-active
                                     (buffer-substring-no-properties
                                      (region-beginning) (region-end)))
				(current-word)))))

(defun pm/google (string)
  "Ask a WWW browser to google string.
Prompts for a string, defaulting to the active region or the current word at
or before point."
  (interactive (pm/region-or-word "Google: "))
  (browse-url (concat "http://google.com/search?num=100&q=" string)))
--8<---------------cut here---------------end--------------->8---

-- 
           Peter