How to define a prefixed map for a minor mode?

How to define a prefixed map for a minor mode?

[Marcin Borkowski]

Hi all,

continuing my work on a (simplistic) Emacs CAT, I want to define a minor
mode.  However, I'm stuck on defining its keymap.  I want all the
commands prefixed by e.g. `C-c .', and here's what I have:

--8<---------------cut here---------------start------------->8---
(setq ecat-basic-map (make-sparse-keymap))

(define-key ecat-basic-map (kbd "p") #'ecat-highlight-previous-sentence)
(define-key ecat-basic-map (kbd "n") #'ecat-highlight-next-sentence)
(define-key ecat-basic-map (kbd ".") #'ecat-highlight-this-sentence)

(easy-mmode-defmap ecat-mode-map
  `(((kbd "C-c .") . ecat-basic-map))
  "Keymap for `ecat-mode'.")

(define-minor-mode ecat-mode
  "Toggle Emacs CAT mode."
  :lighter " CAT"
  :keymap ecat-mode-map
  (if ecat-mode
      (ecat-highlight-this-sentence)
    (delete-overlay ecat-sentence-overlay)))
--8<---------------cut here---------------end--------------->8---

Alas, this does not seem to work - after pressing `C-c .' (when the mode
is one!) I get "C-c . is undefined".

What am I doing wrong?  Is there a "canonical" method of defining
a minor mode whose bindings start with some prefix?

TIA,

-- 
Marcin Borkowski
http://mbork.pl

Re: How to define a prefixed map for a minor mode?

[Jamie Beardslee]

> (easy-mmode-defmap ecat-mode-map
>   `(((kbd "C-c .") . ecat-basic-map))
>   "Keymap for `ecat-mode'.")

You're missing a couple of unquotes there -- that should be:

`((,(kbd "C-c .") . ,ecat-basic-map))

Smerge-mode uses a prefix key (C-c ^) for all commands and this is done
in pretty much the same way:

(easy-mmode-defmap smerge-basic-map
  `(("n" . smerge-next)
    ("p" . smerge-prev)
    [...])
  "The base keymap for `smerge-mode'.")

(defcustom smerge-command-prefix "\C-c^"
  "Prefix for `smerge-mode' commands."
  [...])

(easy-mmode-defmap smerge-mode-map
  `((,smerge-command-prefix . ,smerge-basic-map))
  "Keymap for `smerge-mode'.")

Re: How to define a prefixed map for a minor mode?

[Marcin Borkowski]

On 2020-06-07, at 09:54, Jamie Beardslee <beardsleejamie@gmail.com> wrote:

>> (easy-mmode-defmap ecat-mode-map
>>   `(((kbd "C-c .") . ecat-basic-map))
>>   "Keymap for `ecat-mode'.")
>
> You're missing a couple of unquotes there -- that should be:
>
> `((,(kbd "C-c .") . ,ecat-basic-map))

As I said a minute ago - you're obviously right, that helped.

> Smerge-mode uses a prefix key (C-c ^) for all commands and this is done
> in pretty much the same way:

Yep, indeed I tried to mimick it, but forgot about unquoting.

Thanks,

-- 
Marcin Borkowski
http://mbork.pl

Re: How to define a prefixed map for a minor mode?

[Michael Heerdegen]

Marcin Borkowski <mbork@mbork.pl> writes:

> (easy-mmode-defmap ecat-mode-map
>   `(((kbd "C-c .") . ecat-basic-map))
>   "Keymap for `ecat-mode'.")

I don't know much about this but passing an unevaluated `kbd' expression
doesn't look right to me.

Michael.

Re: How to define a prefixed map for a minor mode?

[Michael Heerdegen]

Michael Heerdegen <michael_heerdegen@web.de> writes:

> > (easy-mmode-defmap ecat-mode-map
> >   `(((kbd "C-c .") . ecat-basic-map))
> >   "Keymap for `ecat-mode'.")
>
> I don't know much about this but passing an unevaluated `kbd' expression
> doesn't look right to me.

AFAIR I use to do this kind of thing like this:

(define-minor-mode ecat-mode
  "Toggle Emacs CAT mode."
  :lighter " CAT"
  :keymap (let ((map (make-sparse-keymap)))
            (define-key map (kbd "C-c .") ecat-basic-map)
            map))

Michael.

Re: How to define a prefixed map for a minor mode?

[Marcin Borkowski]

On 2020-06-07, at 10:16, Michael Heerdegen <michael_heerdegen@web.de> wrote:

> Michael Heerdegen <michael_heerdegen@web.de> writes:
>
>> > (easy-mmode-defmap ecat-mode-map
>> >   `(((kbd "C-c .") . ecat-basic-map))
>> >   "Keymap for `ecat-mode'.")
>>
>> I don't know much about this but passing an unevaluated `kbd' expression
>> doesn't look right to me.
>
> AFAIR I use to do this kind of thing like this:
>
> (define-minor-mode ecat-mode
>   "Toggle Emacs CAT mode."
>   :lighter " CAT"
>   :keymap (let ((map (make-sparse-keymap)))
>             (define-key map (kbd "C-c .") ecat-basic-map)
>             map))

Thanks, that seems to make sense to me.

Still, I'd love to see the "canonical" way...

Best,

-- 
Marcin Borkowski
http://mbork.pl

Re: How to define a prefixed map for a minor mode?

[Michael Heerdegen]

Marcin Borkowski <mbork@mbork.pl> writes:

> Still, I'd love to see the "canonical" way...

I doubt there is anything more canonical.

Michael.

Re: How to define a prefixed map for a minor mode?

[Marcin Borkowski]

On 2020-06-07, at 09:59, Michael Heerdegen <michael_heerdegen@web.de> wrote:

> Marcin Borkowski <mbork@mbork.pl> writes:
>
>> (easy-mmode-defmap ecat-mode-map
>>   `(((kbd "C-c .") . ecat-basic-map))
>>   "Keymap for `ecat-mode'.")
>
> I don't know much about this but passing an unevaluated `kbd' expression
> doesn't look right to me.

Stupid me, you're right, of course.

Best,

-- 
Marcin Borkowski
http://mbork.pl

Re: How to define a prefixed map for a minor mode?

[Joost Kremers]

On Sun, Jun 07 2020, Marcin Borkowski wrote:
> Hi all,
>
> continuing my work on a (simplistic) Emacs CAT, I want to define 
> a minor
> mode.  However, I'm stuck on defining its keymap.  I want all 
> the
> commands prefixed by e.g. `C-c .', and here's what I have:
>
> --8<---------------cut 
> here---------------start------------->8---
> (setq ecat-basic-map (make-sparse-keymap))
>
> (define-key ecat-basic-map (kbd "p") 
> #'ecat-highlight-previous-sentence)
> (define-key ecat-basic-map (kbd "n") 
> #'ecat-highlight-next-sentence)
> (define-key ecat-basic-map (kbd ".") 
> #'ecat-highlight-this-sentence)
>
> (easy-mmode-defmap ecat-mode-map
>   `(((kbd "C-c .") . ecat-basic-map))
>   "Keymap for `ecat-mode'.")
>
> (define-minor-mode ecat-mode
>   "Toggle Emacs CAT mode."
>   :lighter " CAT"
>   :keymap ecat-mode-map
>   (if ecat-mode
>       (ecat-highlight-this-sentence)
>     (delete-overlay ecat-sentence-overlay)))
> --8<---------------cut 
> here---------------end--------------->8---
>
> Alas, this does not seem to work - after pressing `C-c .' (when 
> the mode
> is one!) I get "C-c . is undefined".
>
> What am I doing wrong?  Is there a "canonical" method of 
> defining
> a minor mode whose bindings start with some prefix?
>
> TIA,

In one package of mine, I do this:

```
(eval-and-compile
  (define-prefix-command 'ebib-slave-map)
  (suppress-keymap 'ebib-slave-map 'no-digits)
  (define-key ebib-slave-map "c" #'ebib-slave-create-slave)
  (define-key ebib-slave-map "a" #'ebib-slave-add-entry)
  (define-key ebib-slave-map "d" #'ebib-slave-delete-entry)
  (define-key ebib-slave-map "m" #'ebib-slave-switch-to-master))
```

and in the major mode's map:

```
(defvar ebib-index-mode-map
  (let ((map (make-keymap)))
    (suppress-keymap map 'no-digits)
    ;; [...]
    (define-key map "M" 'ebib-slave-map)
    ;; [...]
    map)
  "Keymap for the ebib index buffer.")
```

I'm not sure if that's what you're looking for, though, because 
`ebib-slave-map` isn't tied to a minor mode. But perhaps you can 
adapt it to your needs.

-- 
Joost Kremers
Life has its moments