Re: Waiting for 'compile' to finish

[Bruno Barbier <brubar.cs@gmail.com>]

Marco Antoniotti <marcoxa@gmail.com> writes:

> Yep.  That much I surmised.  It does not seem to be mentioned in the Info
> documentation.


Here is a function that compiles and do something when done using
`compilation-exit-message-function'.

(defun my-compile (cmd on-exit)
  "Compile using CMD. Return the buffer.
Call ON-EXIT when done."
  (let ((buffer (compile cmd)))
    (with-current-buffer buffer
      (add-function :around (local 'compilation-exit-message-function)
                    (lambda (old-fun process-status exit-status msg)
                      (let ((mm (funcall old-fun process-status exit-status msg)))
                        (funcall on-exit process-status exit-status msg)
                        mm))))
    buffer))


Here is an example about how to use it.

(defun my-compile-echo-result (process-status exit-status msg)
  "An ON-EXIT example that just displays OK or Failed."
  (message "Compilation: %s" (if (eq 0 exit-status) "OK." "Failed!")))

;; A compilation that succeeds.
(my-compile "sleep 1; echo ok" #'my-compile-echo-result)

;; A compilation that fails.
(my-compile "sleep 1; oops" #'my-compile-echo-result)

Hoping this may help you,

Bruno


> All the best
>
> MA
>
> On Thu, Jan 9, 2025 at 10:23 PM Bruno Barbier <brubar.cs@gmail.com> wrote:
>
>> Marco Antoniotti <marcoxa@gmail.com> writes:
>>
>> > Thanks, I'll check it out. But where is this documented?
>> >
>>
>> It seems that the only documentation is the variable definition itself:
>>
>>   C-h v compilation-exit-message-function
>>
>>
>> Bruno
>>
>
>
> -- 
> Marco Antoniotti
> Somewhere over the Rainbow