How to bind mouse-1 to find-file in dired?

How to bind mouse-1 to find-file in dired?

[Arne Schmitz]

I want to get rid of dired-find-file-other-window. I tried the following in
my .emacs:

(eval-after-load "dired" '(progn (define-key dired-mode-map
(kbd "<mouse-1>") 'dired-find-file)))

But this does not seem to work. What should I do?

Arne

-- 
[--- PGP key FD05BED7 --- http://www.root42.de/ ---]

Re: How to bind mouse-1 to find-file in dired?

[Johan Bockgård]

Arne Schmitz <arne.schmitz@gmx.net> writes:

> I want to get rid of dired-find-file-other-window. I tried the following in
> my .emacs:
>
> (eval-after-load "dired" '(progn (define-key dired-mode-map
> (kbd "<mouse-1>") 'dired-find-file)))
>
> But this does not seem to work. What should I do?

Use "<mouse-2>".

-- 
Johan Bockgård

Re: How to bind mouse-1 to find-file in dired?

[Arne Schmitz]

Johan Bockgård wrote:

>> I want to get rid of dired-find-file-other-window. I tried the following
>> in my .emacs:
>>
>> (eval-after-load "dired" '(progn (define-key dired-mode-map
>> (kbd "<mouse-1>") 'dired-find-file)))
>>
>> But this does not seem to work. What should I do?
> 
> Use "<mouse-2>".

1. That does not work either.
2. I want to have it on mouse-1.

Arne

-- 
[--- PGP key FD05BED7 --- http://www.root42.de/ ---]

Re: How to bind mouse-1 to find-file in dired?

[Kevin Rodgers]

Arne Schmitz wrote:
> Johan Bockgård wrote:
> 
>>> I want to get rid of dired-find-file-other-window. I tried the following
>>> in my .emacs:
>>>
>>> (eval-after-load "dired" '(progn (define-key dired-mode-map
>>> (kbd "<mouse-1>") 'dired-find-file)))
>>>
>>> But this does not seem to work. What should I do?
>> Use "<mouse-2>".
> 
> 1. That does not work either.
> 2. I want to have it on mouse-1.

What does `C-h v mouse-1-click-follows-link' in the Dired buffer
display?

-- 
Kevin Rodgers
Denver, Colorado, USA

Re: How to bind mouse-1 to find-file in dired?

[Arne Schmitz]

Kevin Rodgers wrote:

>> 2. I want to have it on mouse-1.
> 
> What does `C-h v mouse-1-click-follows-link' in the Dired buffer
> display?

mouse-1-click-follows-link is a variable defined in `mouse.el'.
Its value is 450

Regards,

Arne

-- 
[--- PGP key FD05BED7 --- http://www.root42.de/ ---]

Re: How to bind mouse-1 to find-file in dired?

[Kevin Rodgers]

Arne Schmitz wrote:
> Kevin Rodgers wrote:
> 
>>> 2. I want to have it on mouse-1.
>> What does `C-h v mouse-1-click-follows-link' in the Dired buffer
>> display?
> 
> mouse-1-click-follows-link is a variable defined in `mouse.el'.
> Its value is 450

So what happens when you click on a file name in Dired with mouse-1?

-- 
Kevin Rodgers
Denver, Colorado, USA

Re: How to bind mouse-1 to find-file in dired?

[Piet van Oostrum]

>>>>> Arne Schmitz <arne.schmitz@gmx.net> (AS) wrote:

>AS> I want to get rid of dired-find-file-other-window. I tried the following in
>AS> my .emacs:

>AS> (eval-after-load "dired" '(progn (define-key dired-mode-map
>AS> (kbd "<mouse-1>") 'dired-find-file)))

>AS> But this does not seem to work. What should I do?

You can't just bind a mouse event to dired-find-file; you need a function
that  finds out where the mouse clicked.
I have just cut and pasted something from my .emacs. I hope I didn't forget
anything (actually I myself bind mouse-2 and then I have
mouse-1-click-follows-link set)

(defun dired-mouse-find-file (event)
  "In Dired, visit the file or directory name you click on."
  (interactive "e")
  (let (window pos file)
    (save-excursion
      (setq window (posn-window (event-end event))
	    pos (posn-point (event-end event)))
      (if (not (windowp window))
	  (error "No file chosen"))
      (set-buffer (window-buffer window))
      (goto-char pos)
      (setq file (dired-get-file-for-visit)))
    (if (file-directory-p file)
	(or (and (cdr dired-subdir-alist)
		 (dired-goto-subdir file))
	    (progn
	      (select-window window)
	      (dired file)))
      (select-window window)
      (find-file (file-name-sans-versions file t)))))

(defun set-my-dired-keys-hook ()
  "My favorite dired keys."
  (local-set-key [mouse-1] 'dired-mouse-find-file)
; other keybindings if desired
)

(add-hook 'dired-mode-hook 'set-my-dired-keys-hook)

-- 
Piet van Oostrum <piet@cs.uu.nl>
URL: http://pietvanoostrum.com [PGP 8DAE142BE17999C4]
Private email: piet@vanoostrum.org