New balance-windows (Was Re: Making the width of three windows equal)

["Ehud Karni" <ehud@unix.mvs.co.il>]

Following the recent discussion of `balance-windows' on help-gnu-emacs
I looked into it and wrote a replacement (new) function based on
somewhat different logic to achieve the balancing.

The logic is this: group all windows that has the same "left" (or "top"
for horizontal) edge, and balance their height (width).

The actual resizing is dependent on the window structure.
e.g. the two symmetrical window structures below will be balanced
differently (the diagrams are after vertical balancing):

       +-------+--------+             +-------+--------+
       |       |        |             |       |        |
       | 1 / 3 |        |             |       | 1 / 4  |
       |       |        |             | 1 / 2 +--------+
       +-------|  2 / 3 |             |       |        |
       |       |        |             |       | 1 / 4  |
       | 1 / 3 |        |             +-------+--------+
       |       |        |             |                |
       +-------+--------+             |                |
       |                |             |     1 / 2      |
       |     1 / 3      |             |                |
       |                |             |                |
       +-------+--------+             +-------+--------+

On the other hand if the windows are more "normally" built it works
fine (diagrams after horizontal balancing):

    +-----+-----+------+----+    +-------+-------+-------+
    | 1/4 | 1/4 | 1/4 | 1/4 |    | 1 / 3 | 1 / 3 | 1 / 3 |
    |     |     |     |     |    |       |       |       |
    +-----+-+---+---+-+-----+    +-----+-+---+---+-+-----+
    |       |       |       |    |     |     |     |     |
    | 1 / 3 | 1 / 3 | 1 / 3 |    | 1/4 | 1/4 | 1/4 | 1/4 |
    +-------+-------+-------+    +-----+-----+------+----+

To balance horizontally just add a prefix argument (i.e. C-u).

Note. I don't have CVS write permission, so if some of the developers
find this as adequate replacement to `balance-windows' please add it.


Ehud.


(defun balance-windows (&optional horizontally)
  "Make all visible windows on the current frame the same size (approximately).
If optional prefix arg is not given, \"same size\" is same height.
When prefix arg is given,  \"same size\" is same width."
  (interactive "P")
  (let* (count size w cmjr resize max rpt
         (edge (if horizontally 0 1))  ;; Minor field to sort by 0=LEFT, 1=TOP
         (mjr (- 1 edge))              ;; Major field to sort
         (far (+ 2 edge))              ;; far edge (right/bottom)
         (windows nil)                 ;; list of windows
         (ix 0)
         nwin                          ;; number of windows
         (pass 1)                      ;; pass number
         (curw (selected-window))      ;; selected window (to return to)
         )
    ;; Build and sort list of all windows on frame
       (save-window-excursion
           (walk-windows (function (lambda (w)
                               (let ((ltrb (window-edges w)))
                                   (setq windows (cons (list
                                       (nth mjr  ltrb)
                                       (nth edge ltrb)
                                       (nth far  ltrb)
                                       w) windows)))))
                         'nomini)
           (setq windows (sort windows (lambda (e1 e2)
                                         (if (< (nth 0 e1) (nth 0 e2))
                                               t
                                           (if (= (nth 0 e1) (nth 0 e2))
                                               (if (< (nth 1 e1) (nth 2 e2))
                                                   t)))))))
       (setq nwin (length windows))
       ;; add 1 extra entry (for while check)
       (setq windows (append windows '((-1 -1 -1 nil))))

       (while (< ix nwin)                      ; walk on all (sorted) windows
           (setq count 0)                      ; number of windows in 1 column (or row)
           (setq cmjr (car (nth ix windows)))  ; column / raw identification
           (while (= cmjr (car (nth (+ count ix) windows)))    ; same
               (setq count (1+ count)))        ; count them
           (if (= count 1)                     ; only one window in this column/row
               (setq ix (1+ ix))               ; skip it
             ; compute and resize windows
             (setq size (if (= pass 1)         ; on pass 1 the saved edges have not changed
                          (- (nth 2 (nth (1- (+ count ix)) windows))
                             (nth 1 (nth ix windows)))
                        ;; previous changes may changed the window edges
                        (- (nth far (window-edges (nth 3 (nth (1- (+ count ix)) windows))))
                           (nth edge (window-edges (nth 3 (nth ix windows)))))))
             (setq size (/ (+ size count -1) count)) ; average window size

             (setq max (+ ix count))           ; index of next column/row
             ;; the resizing loop must be done twice
             ;; because later change may resize previous window
             (setq rpt 2)
             (while (> rpt 0)
               (setq rpt (1- rpt))
               (while (< ix max)
                 (setq w (nth 3 (nth ix windows)))
                 (setq resize (- size (- (nth far (window-edges w))
                                         (nth edge (window-edges w)))))
                 ; don't resize by 1 character
                 (if (or (> resize 1)
                         (< resize -1))
                     (progn
                       (select-window w)       ; window to work on
                       (enlarge-window resize horizontally)))
                 (setq ix (1+ ix)))
               (setq ix (- max count)))
             (setq ix max)
             (setq pass 2)))
           (select-window curw)))



--
 Ehud Karni           Tel: +972-3-7966-561  /"\
 Mivtach - Simon      Fax: +972-3-7966-667  \ /  ASCII Ribbon Campaign
 Insurance agencies   (USA) voice mail and   X   Against   HTML   Mail
 http://www.mvs.co.il  FAX:  1-815-5509341  / \
 GnuPG: 98EA398D <http://www.keyserver.net/>    Better Safe Than Sorry